[DEFNAME HORSES UPGRADE]
//ID BASEID,PETID,STR,DEX,COLOR
HORSE.1 LLAMA,C_LLAMA,I_PET_LLAMA,75,25,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.2 FOREST OSTARD,C_OSTARD_FOREST,I_PET_OSTARD_FOREST,100,25,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.3 DESERT OSTARD,C_OSTARD_DESERT,I_PET_OSTARD_DESERT,100,25,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.4 MID OSTARD,C_OSTARD_MID,I_PET_OSTARD_DESERT,150,30,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.5 ZOSTRICH OSTARD,C_OSTARD_ZOSTRICH,I_PET_OSTARD_ZOSTRICH,150,30,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.6 SHIRE,C_SHIRE,I_PET_HORSE_BROWN_LT,150,30,0455,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.7 MUSTANG,C_M_MUSTANG,I_PET_HORSE_BROWN_DK,150,30,01b6,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.8 KIRIN,C_KIRIN,I_PET_HORSE_BROWN_LT,200,35,02B,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.9 LBR KIRIN,C_M_KIRIN,I_PET_KIRIN,400,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.10 UNICORN,C_UNICORN,I_PET_HORSE_BROWN_DK,400,50,0481,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.11 SILVER STEED,C_M_SILVER,I_PET_HORSE_BROWN_LT,400,50,0482,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.12 FIRE STEED,C_STEED_FIRE,I_PET_HORSE_BROWN_LT,400,50,04EC,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.13 SWAMP DRAGON,C_SWAMP_DRAGON,I_PET_SWAMP_DRAGON,400,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.14 GIANT BEETLE,C_GIANT_BEETLE,I_PET_GIANT_BEETLE,400,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.15 RIDGEBACK,C_RIDGEBACK,I_PET_RIDGEBACK,400,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.16 HIRYU,C_HIRYU,I_PET_HIRYU,450,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.17 CU SIDHE,C_CU_SIDHE,I_PET_CU_SIDHE,500,50,0,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
HORSE.18 NIGHTMARE,C_M_NIGHTMARE,I_PET_HORSE_BROWN_DK,550,75,0455,I_GEM_STR,I_GEM_DEX,I_DEED_BINEK,1
[ITEMDEF I_GEM_STR]
ID = I_GEM_STAR_SAPPHIRE
NAME = Binek Str
WEIGHT = 0.1
TYPE = T_BINEKS
[ITEMDEF I_GEM_DEX]
ID = I_GEM_RUBY
NAME = Binek Dex
WEIGHT = 0.1
TYPE = T_BINEKS
[ITEMDEF I_DEED_BINEK]
ID = I_DEED
NAME = Binek Geliştirme
WEIGHT = 0.1
TYPE = T_BINEKS
ON=@CREATE
COLOR = 07F7
[TYPEDEF T_BINEKS]
ON=@CLICK
MESSAGE @,,1 <NAME>
MESSAGE @,,1 adet <amount>
RETURN 1
ON=@DCLICK
SRC.SYSMESSAGE @34,,1 Binek geliştirme sisteminde kullanılır.
RETURN 1
[TYPEDEF T_STONE_HORSES]
[ITEMDEF I_STONE_HORSES]
ID = I_GRAVE_STONE
NAME = Binek Geliştirme
TYPE = T_STONE_HORSES
ON=@CLICK
MESSAGE @,,1 <NAME>
RETURN 1
ON=@CREATE
COLOR = 0481
ATTR = ATTR_MOVE_NEVER
ON=@DCLICK
SDIALOG D_HORSES
RETURN 1
ON=@TARGON_ITEM
IF (<SRC.cTAG0.HORSES_ARGN> == 2) && !(<SRC.TARG.BASEID> == I_GEM_STR)
SRC.SYSMESSAGE @34,,1 Bu bir Binek Str elması değil.
SDIALOG D_HORSES
RETURN 1
ELIF (<SRC.cTAG0.HORSES_ARGN> == 3) && !(<SRC.TARG.BASEID> == I_GEM_DEX)
SRC.SYSMESSAGE @34,,1 Bu bir Binek Dex elması değil.
SDIALOG D_HORSES
RETURN 1
ELIF (<SRC.cTAG0.HORSES_ARGN> == 4) && !(<SRC.TARG.BASEID> == I_DEED_BINEK)
SRC.SYSMESSAGE @34,,1 Bu bir Binek Geliştirme parşomeni elması değil.
SDIALOG D_HORSES
RETURN 1
ENDIF
IF !(<SRC.cTAG0.MAT_SLOT_4>)
IF !(<ARGO.BASEID> == I_DEED_ANIMAL)
SRC.SYSMESSAGE @34,,1 Bu bir animal deed değil.
RETURN 1
ELIF !(<ARGO.TAG0.TRADE_ID>)
SRC.SYSMESSAGE @34,,1 Bu animal deed boş.
RETURN 1
ELIF !(<ARGO.TAG0.TRADE_ID> == <GETARGVX 2,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)
SRC.SYSMESSAGE @34,,1 Binek türleri bir birleri ile uyuşmuyor.
RETURN 1
ELIF (<ARGO.TAG0.TRADE_GELISTIRME> == 1)
SRC.SYSMESSAGE @34,,1 Bu binek daha önce geliştirilmiş.
RETURN 1
ENDIF
IF !(<ISNEARTYPE T_STONE_HORSES 3>)
SRC.SYSMESSAGE @34,,1 Binek geliştirme taşına biraz yaklaşmalısınız.
RETURN 1
ELSE
ARGO.ATTR = ATTR_INVIS|ATTR_NEWBIE
SRC.cTAG.MAT_SLOT_4 = <ARGO>
SDIALOG D_HORSES
RETURN 1
ENDIF
ENDIF
IF (<ARGO.BASEID> == I_GEM_STR)
IF (<ARGO.AMOUNT> == <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)
ARGO.ATTR = ATTR_INVIS|ATTR_NEWBIE
SRC.cTAG.MAT_SLOT_1 = <ARGO>
SDIALOG D_HORSES
ELSE
SRC.SYSMESSAGE @34,,1 Binek Str elması yeterli sayıda değil, tam <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>> olarak ayarlayın.
RETURN 1
ENDIF
ENDIF
IF (<ARGO.BASEID> == I_GEM_DEX)
IF (<ARGO.AMOUNT> == <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)
ARGO.ATTR = ATTR_INVIS|ATTR_NEWBIE
SRC.cTAG.MAT_SLOT_2 = <ARGO>
SDIALOG D_HORSES
ELSE
SRC.SYSMESSAGE @34,,1 Binek Dex elması yeterli sayıda değil, tam <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>> olarak ayarlayın.
RETURN 1
ENDIF
ENDIF
IF (<ARGO.BASEID> == I_DEED_BINEK)
ARGO.ATTR = ATTR_INVIS|ATTR_NEWBIE
SRC.cTAG.MAT_SLOT_3 = <ARGO>
SDIALOG D_HORSES
ENDIF
RETURN 1
ON=@TARGON_CANCEL
IF !(<SRC.ISNEARTYPE T_STONE_HORSES 3>)
SRC.SYSMESSAGE @34,,1 Binek geliştirme taşından uzaklaşmışsınız.
SRC.F_RESET_UPGRADED_STONE
SRC.SYSMESSAGE @34,,1 Tüm işlemleriniz iptal edildi.
ELSE
SDIALOG D_HORSES
ENDIF
RETURN 1
[DIALOG D_HORSES]
0,0
PAGE 0
BOZOBAG 200,100,420,450 // ARKAPLAN
DTEXT 350 120 040 Binek Geliştirme // BAŞLIK
PAGE 1
GUMPPICTILED 218 260 385 30 9204 // BINEK ISIM ARKAPLANI
dHTMLGUMP 225 160 370 85 0 0 <DEF.BFONT_YELLOW>Tüm bineklerin Str ve Dex değerleri 100'e sabitlenmiştir. Bu menüden dilediğiniz zaman istenilen malzemeler doğrultusun da aşağıda sergilediğiniz binek türüne göre maximum Str ve Dex geliştirmelerini yapabilirsiniz.
IF <SRC.dTAG0.HORSES> > 1
BUTTON 220 265 4014 4015 1 0 1000 // ILERI BUTTONU
ENDIF
IF <SRC.dTAG0.HORSES> < 18
BUTTON 570 265 4005 4006 1 0 1001 // GERI BUTTONU
ENDIF
TILEPICHUE 310 250 <SERV.ITEMDEF.<GETARGVX 3,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID> <EVAL <GETARGVX 6,<DEF.HORSE.<SRC.dTAG0.HORSES>>>> // ILERI GERI DEGISEN BINEK GUMPLARI
DTEXT 370 265 040 <GETARGVX 1,<DEF.HORSE.<SRC.dTAG0.HORSES>>> // ILERI GERI DEĞİŞEN BAŞLIK ISIMLERI
dTEXT 299 325 0481 MAX-STR MAX-DEX
RESIZEPIC 300 350 5054 50 25
RESIZEPIC 450 350 5054 50 25
DTEXT 310 353 044 <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>> <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
dTEXT 500 385 0481 MALZEMELER
RESIZEPIC 500 405 5054 50 25
dTEXT 440 406 0481 STR GEM <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
TILEPIC 495 415 <SERV.ITEMDEF.<GETARGVX 7,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID>
TILEPIC 500 410 <SERV.ITEMDEF.<GETARGVX 7,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID>
RESIZEPIC 500 435 5054 50 25
dTEXT 440 436 0481 DEX GEM <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
TILEPIC 510 440 <SERV.ITEMDEF.<GETARGVX 8,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID>
TILEPIC 515 445 <SERV.ITEMDEF.<GETARGVX 8,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID>
RESIZEPIC 500 465 5054 50 25
dTEXT 428 466 0481 GELISTIRME <GETARGVX 10,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
TILEPICHUE 510 465 <SERV.ITEMDEF.<GETARGVX 9,<DEF.HORSE.<SRC.dTAG0.HORSES>>>.ID> <EVAL 07F7>
dTEXT 235 385 0481 GELİŞTİRİLECEK BİNEK
RESIZEPIC 341 405 5054 50 25 // SLOT STR
BUTTON 395 406 <qVAL (<SRC.cTAG0.MAT_SLOT_1>)?4017 4018:4005 4006> 1 0 2
dTEXT 351 408 <qVAL (<UID.<SRC.dcTAG0.MAT_SLOT_1>.AMOUNT> == <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)?044:38> <UID.<SRC.dcTAG0.MAT_SLOT_1>.AMOUNT>
RESIZEPIC 341 437 5054 50 25 // SLOT DEX
BUTTON 395 437 <qVAL (<SRC.cTAG0.MAT_SLOT_1>)?4017 4018:4005 4006> 1 0 3
dTEXT 351 440 <qVAL (<UID.<SRC.dcTAG0.MAT_SLOT_2>.AMOUNT> == <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)?044:38> <UID.<SRC.dcTAG0.MAT_SLOT_2>.AMOUNT>
RESIZEPIC 341 468 5054 50 25 // SLOT GELISTIRME
BUTTON 395 468 <qVAL (<SRC.cTAG0.MAT_SLOT_1>)?4017 4018:4005 4006> 1 0 4
dTEXT 351 471 <qVAL (<UID.<SRC.dcTAG0.MAT_SLOT_3>.AMOUNT> == <GETARGVX 10,<DEF.HORSE.<SRC.dTAG0.HORSES>>>)?044:38> <UID.<SRC.dcTAG0.MAT_SLOT_3>.AMOUNT>
RESIZEPIC 240 405 5054 100 88
REF1=<SRC.cTAG.MAT_SLOT_4>
IF (<REF1>)
TILEPICHUE 260 425 <SERV.ITEMDEF.i_pet_<STRSUB 2 0 <REF1.TAG.TRADE_BODY>>.ID> <EVAL <REF1.COLOR>> // HATA BURANIN C_SHIRE OLMASINDAN DOLAYI KAYNAKLANIYOR PET KISMINI EKLEYECEĞİNİZ. DAHA SONRA.
IF !((<SRC.cTAG0.MAT_SLOT_1>) && (<SRC.cTAG0.MAT_SLOT_2>) && (<SRC.cTAG0.MAT_SLOT_3>))
BUTTON 242 468 4017 4018 1 0 1
dTEXT 274 468 0481 ÇIKART
ENDIF
ENDIF
IF !(<REF1>)
BUTTON 242 468 4005 4006 1 0 1
dTEXT 274 468 0481 EKLE
ENDIF
IF (<REF1>) && (<SRC.cTAG0.MAT_SLOT_1>) && (<SRC.cTAG0.MAT_SLOT_2>) && (<SRC.cTAG0.MAT_SLOT_3>)
BUTTON 242 468 4005 4006 1 0 1002
dTEXT 274 468 0481 GELİŞTİR
ENDIF
IF (<SRC.cTAG0.UPGRADED_HORSES>)
dHTMLGUMP 242 500 350 75 0 0 <DEF.bFONT_YELLOW>BILDIRI:<DEF.bFONT_WHITE> <SRC.cTAG.HORSES_MSG>
SRC.cTAG.UPGRADED_HORSES =
ENDIF
[DIALOG D_HORSES BUTTON]
ON=0
IF (<SRC.cTAG0.ADD_HORSE>)
SRC.SYSMESSAGE @34,,1 Tüm işlemleri iptal ettiniz.
ENDIF
SRC.F_RESET_UPGRADED_STONE
ON=1
IF (<SRC.cTAG0.MAT_SLOT_4>)
SRC.F_RESET_UPGRADED_STONE
SDIALOG D_HORSES
ELSE
TARGET @,,1 Eklenecek binek ?
ENDIF
ON=2 4
SRC.cTAG.HORSES_ARGN = <dARGN>
IF (<SRC.cTAG0.MAT_SLOT_<EVAL <dARGN>-1>>)
SRC.cTAG.MAT_SLOT_<EVAL <dARGN>-1> =
SDIALOG D_HORSES
RETURN 1
ENDIF
IF !(<SRC.cTAG0.MAT_SLOT_4>)
SRC.SYSMESSAGE @34,,1 Ilk önce ana slot olan binek bölümünü doldurmalısınız.
SDIALOG D_HORSES
RETURN 1
ENDIF
TARGET @,,1 Eklenecek eşyayı belirtin.
ON=1000
SRC.F_RESET_UPGRADED_STONE
SRC.TAG0.HORSES -= 1
DIALOG D_HORSES
ON=1001
SRC.F_RESET_UPGRADED_STONE
SRC.TAG0.HORSES +=1
DIALOG D_HORSES
ON=1002
IF !(<SRC.ISNEARTYPE T_STONE_HORSES 3>)
SRC.SYSMESSAGE @34,,1 Geliştirme taşına yaklaşın.
SDIALOG D_HORSES
RETURN 1
ENDIF
REF1 = <SRC.cTAG.MAT_SLOT_4>
REF1.TAG.TRADE_STR = <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
REF1.TAG.TRADE_DEX = <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>>
REF1.TAG.TRADE_GELISTIRME = 1
SRC.CONSUME <GETARGVX 4,<DEF.HORSE.<SRC.dTAG0.HORSES>>> I_GEM_STR
SRC.CONSUME <GETARGVX 5,<DEF.HORSE.<SRC.dTAG0.HORSES>>> I_GEM_DEX
SRC.CONSUME <GETARGVX 10,<DEF.HORSE.<SRC.dTAG0.HORSES>>> I_DEED_BINEK
REF1.ATTR =
SRC.DIALOGCLOSE D_HORSES
SRC.F_RESET_UPGRADED_STONE
SRC.cTAG.HORSES_MSG = <REF1.TAG.TRADE> Yeni değerler: STR <REF1.dTAG0.TRADE_STR>, DEX <REF1.dTAG0.TRADE_DEX>
SRC.cTAG.UPGRADED_HORSES = 1
SDIALOG D_HORSES
SRC.TIMERF 2,SRC.DIALOGCLOSE D_HORSES
[FUNCTION F_RESET_UPGRADED_STONE] // KISA YOL SLOT TEMİZLEME FONKSİYONU
FOR 4
REF<dLOCAL._FOR> = <SRC.cTAG.MAT_SLOT_<dLOCAL._FOR>>
IF (<REF<dLOCAL._FOR>>)
REF<dLOCAL._FOR>.ATTR =
SRC.cTAG.MAT_SLOT_<dLOCAL._FOR> =
SRC.cTAG.HORSES_ARGN =
ENDIF
ENDFOR
[EOF]
Açıklamalar: Menü görselliğinde pet iconlarında hatalar ile karşılaşmamak için tüm pet iconlarının idleri def kısmında yazıldığı gibi olmalıdır.
Animal deed küçültme bölümüne alt kısımdakiler eklenmeli.
tag.trade_body <src.targ.body>
tag.trade_gelistirme = <src.targ.tag.trade_gelistirme>
Animal deed çıkarma bölümüne eklenmesi gerekenler.
link.tag.trade_gelistirme = <tag.trade_gelistirme>
fonksiyonlar.
fonksiyonlar.
ARKA PLAN FONKSIYONUNU DEGIŞTIRMENIZI ÖNERIRIM.
RESZEPIC 200 100 5054 420 450 // ARKAPLAN
[FUNCTION GETARGVX]
IF <ARGV[0]> == -1
RETURN <EVAL <ARGV>-1>
ELSE
RETURN <ARGV[<ARGV[0]>]>
ENDIF
Binek pvp sini öldürmek amacıyla tüm bineklerin str ve dex değerlerini sabit kıldım kendi sunucum üzerinde böylelikle binekler için biraz daha uğraşılıp çaba sarf edilmiş olup binek değerleri biraz daha tavan yapar diye.
Ana Slot bölümü Animal Deed ile doldurulmaktadır.
Geliştirilen binek bir daha geliştirilmek için slot'a eklenemez.
Ana slot'a binek eklenilmiş ise navigasyon hareketi sırasında tüm işlemler iptal edilir.
Tüm malzemelerin sırasıyla eklenilmesi zorunluluğu vardır.
Bu konu MirroR_ tarafından düzenlendi(2016-08-23 20:11, 7 yıl önce)
