[ITEMDEF 0edd]
//gravestone = Guildstone
DEFNAME=i_guildstone
TYPE=T_STONE_GUILD
VALUE=60000

On=@Create
attr 08010
dispid 0ed4
name *

On=@Click
message a guild stone
if !(strmatch('<abbrev>',''))
message <name> [<abbrev>]
else
message <name>
endif
if (<more1> == 1)
message [Order]
elseif (<more1> == 2)
message [Chaos]
elseif (<link> != 04fffffff)
message [<link.name>]
endif
return 1

On=@TargOn_Char
if (<morex> == 1) // recruiting
if (<src.targ.npc>)
src.sysmessage Sadece oyuncular guild uyesi olabilir.
elseif (<src.targ.distance> > 3)
src.sysmessage <src.targ.name> bu islem icin stone'a yeterince yakin degil.
elseif (<src.targ.memoryfindtype.memory_guild>)
if (<src.targ.memoryfindtype.memory_guild.link> != <uid>)
src.sysmessage <src.targ.name> uye olabilmek icin oncelikle <src.targ.memoryfindtype.memory_guild.link.name> uyeliginden cikmali.
elseif (<src.targ.memoryfindtype.memory_guild.link> == <uid>)
src.sysmessage <src.targ.name> zaten bir <name> uyesi.
endif
elseif (<src.targ.memoryfindtype.memory_town>) && (<src.targ.memoryfindtype.memory_town.link> != <link>)
src.sysmessage <src.targ.name> guild'in desteklemedigi <src.targ.memoryfindtype.memory_town.link.name> faction'inda. Bir <name> uyesi olamaz.
elseif (<src.targ.findid.i_gs_recruit>)
src.sysmessage <src.targ.name> su an dusunme asamasinda.
else
src.newitem i_gs_recruit
src.act.cont <src.targ.uid>
src.act.more1 <src.uid>
src.act.more2 <uid>
src.act.timer 1
endif
elseif (<morex> == 2) // titling
if (<src.targ.memoryfindtype.memory_guild.link> != <uid>)
src.sysmessage Unvan vermeye calistiginiz kisi bir <name> uyesi degil.
menu menu_guild_masterfunc
elseif (<src.targ.distance> > 3)
src.sysmessage <src.targ.name> bu islem icin stone'a yeterince yakin degil.
else
src.act <src.targ.uid>
dialog d_gs_title
endif
endif
return 1

On=@TargOn_Ground
return 1

On=@TargOn_Item
return 1

On=@Timer
if (<morey> == 1)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 1
link 04fffffff
sayu Yeni destek yonu: Order.
elseif (<morey> == 2)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 2
link 04fffffff
sayu Yeni destek yonu: Chaos.
elseif (<morey> == 3)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 04fffffff
sayu <name> artik tarafsiz.
elseif (<morey> == 4)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 04009163d
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
elseif (<morey> == 5)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 04009149f
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
elseif (<morey> == 6)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 040091450
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
elseif (<morey> == 7)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 04009139c
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
endif
return 1

[dialog d_gs_title]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 290 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_title TEXT]
Vermek istediginiz unvani giriniz. (14 karakter)
Tamam
Vazgec
<src.act.tag.gs_title>

[dialog d_gs_title BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif (<src.act.distance> > 3)
src.sysmessage <src.act.name> bu islem icin size yeterince yakin degil.
elseif ((strlen(<argtxt[0]>)) > 14)
src.sysmessage Bir unvan en fazla 14 karakterden olusabilir.
dialog d_gs_title
elseif (strmatch('<argtxt[0]>',''))
src.act.tag.gs_title
src.act.sysmessage Unvaniniz silindi.
if (<src.uid> != <src.act.uid>)
src.sysmessage <src.act.name>: Unvan silindi.
endif
menu menu_guild_masterfunc
else
src.act.tag.gs_title <argtxt[0]>
src.act.sysmessage Yeni unvan: <src.act.tag.gs_title>.
if (<src.uid> != <src.act.uid>)
src.sysmessage <src.act.name> yeni unvan: <src.act.tag.gs_title>.
endif
menu menu_guild_masterfunc
endif

[itemdef i_gs_recruit]
name guild recruiter
weight 0
id i_gold
type t_eq_script
layer layer_special

On=@UnEquip
try src.act <more2>
try src.dialog d_gs_recruit
return 1

On=@Timer
remove
return 1

[dialog d_gs_alignment]
-100,-100
nomove

resizepic 190 165 5120 275 275
resizepic 200 175 3000 255 255

text 220 185 2100 0
htmlgump 215 208 223 60 1 1 1

htmlgump 258 277 140 20 2 0 0
htmlgump 258 297 150 20 3 0 0
htmlgump 258 317 150 20 4 0 0
htmlgump 258 337 150 20 5 0 0
htmlgump 258 357 150 20 6 0 0
htmlgump 258 377 150 20 7 0 0
htmlgump 258 397 150 20 8 0 0
button 225 275 4006 4007 1 0 1
button 225 295 4006 4007 1 0 2
button 225 315 4006 4007 1 0 3
button 225 335 4006 4007 1 0 4
button 225 355 4006 4007 1 0 5
button 225 375 4006 4007 1 0 6
button 225 395 4006 4007 1 0 7

[dialog d_gs_alignment text]
<name>: <var.gs_align>
Dikkat! guild'in destek yonunu degistirdiginiz takdirde, eger tarafsiz bir guild degilse 24 saat boyunca bu menuyu kullanamayacak ve eski destek tarafinizda kalmaya devam edeceksiniz, 24 saat sonunda otomatik olarak desteginiz degisecektir. Tarafsiz guild'ler menuden islem yapildigi anda taraf degistirebilirler. Destek yonunuzu Order veya Chaos'a cevirdiginizde, tum guild uyeleri (candidate'ler haric) O/C'ye dahil olacaktir. Fakat destek yonunuzu faction'lardan bir tanesine cevirirseniz sadece faction savaslarinda bulunmak isteyen guild uyeleri ilgili faction stone'dan faction'a kayit olarak bu olusuma dahil olabileceklerdir.
British: Order
Blackthorn: Chaos
Tarafsiz
Faction: Shamino
Faction: Jakama
Faction: Daxantec
Faction: Arcanum

[dialog d_gs_alignment button]
On=0
menu menu_guild_masterfunc

On=1
if (<more1> == 1)
src.sysmessage <name> zaten bir Order guildi.
else
morey 1
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=2
if (<more1> == 2)
src.sysmessage <name> zaten bir Chaos guildi.
else
morey 2
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=3
if (<more1> == 0) && (<link> == 04fffffff)
src.sysmessage <name> zaten tarafsiz bir guild.
else
morey 3
sayu Tarafsizlik sureci baslamistir.
timer 86400
endif
menu menu_guild_masterfunc

On=4
if (<link> == 04009163d)
src.sysmessage <name> zaten bir Shamino guildi.
else
morey 4
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=5
if (<link> == 04009149f)
src.sysmessage <name> zaten bir Jakama guildi.
else
morey 5
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=6
if (<link> == 040091450)
src.sysmessage <name> zaten bir Daxantec guildi.
else
morey 6
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=7
if (<link> == 04009139c)
src.sysmessage <name> zaten bir Arcanum guildi.
else
morey 7
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

[dialog d_gs_recruit]
-100,-100
nomove

resizepic 190 165 5120 275 155
resizepic 200 175 3000 255 135

htmlgump 215 188 223 60 0 1 1
htmlgump 258 257 140 20 1 0 0
htmlgump 258 277 150 20 2 0 0
button 225 255 4006 4007 1 0 1
button 225 275 4018 4019 1 0 0

[dialog d_gs_recruit text]
<uid.<findid.i_gs_recruit.more1>.name> tarafindan <act.name> guild'ine davet edildiniz. Bu guild'e katilmak istiyor musunuz?
Evet
Hayir

[dialog d_gs_recruit button]
On=1
if (<act.distance> > 3)
sysmessage Guild stone'a yeterince yakin degilsiniz.
else
try tag.gs_title
try uid.<act.uid>.applytojoin
endif

// This is the guildmaster initial selection screen for guildstones
[MENU MENU_GUILD_MASTER]
<Name> (<Master>)
ON=0 Recruit someone into the guild.
morex 1
target Guild'e almak istediginiz kisiyi seciniz.
ON=0 Current roster.
VIEWROSTER
ON=0 Guild's charter.
VIEWCHARTER
ON=0 List of candidates.
VIEWCANDIDATES
ON=0 Enemies of <Name>.
VIEWENEMYS
ON=0 Threats to <Name>.
VIEWTHREATS
ON=0 Declare your fealty. (loyal to <LoyalTo>)
DECLAREFEALTY
ON=0 Resign from the guild.
SAY <SRC.NAME> has been resigned from <NAME>
RESIGN
ON=0 Create guild shield.
if (<src.targ.more> == 1)
if (0<src.tag.sho> == 1)
src.sysmessage Yuce sahsiyetiniz daha once kalkan ile onurlandirilmis.
return 1
endif
src.tag.sho 1
src.newitem i_shield_order
src.act.bounce
elseif (<src.targ.more> == 2)
if (0<src.tag.shc> == 1)
src.sysmessage Yuce sahsiyetiniz daha once kalkan ile onurlandirilmis.
return 1
endif
src.tag.shc 1
src.newitem i_shield_chaos
src.act.bounce
else
src.sysmessage Sadece Order ve Chaos guildleri kendilerine ait bir shield'a sahip olabilirler.
endif
ON=0 Access Guild <MasterGenderTitle> functions.
MASTERMENU

// This is the NON-guildmaster initial selection screen for guildstones
[MENU MENU_GUILD_MEMBER]
<Name> (<Master>)
ON=0 Current roster.
VIEWROSTER
ON=0 Guild's charter.
VIEWCHARTER
ON=0 List of candidates.
VIEWCANDIDATES
ON=0 Enemies of <Name>.
VIEWENEMYS
ON=0 Threats to <Name>.
VIEWTHREATS
ON=0 Declare your fealty. (loyal to <LoyalTo>)
DECLAREFEALTY
ON=0 Resign from the guild.
SAY <SRC.NAME> has been resigned from <NAME>
RESIGN
ON=0 Create guild shield
if (<src.targ.more> == 1)
if (0<src.tag.sho> == 1)
src.sysmessage Yuce sahsiyetiniz daha once kalkan ile onurlandirilmis.
return 1
endif
src.tag.sho 1
src.newitem i_shield_order
src.act.bounce

elseif (<src.targ.more> == 2)
if (0<src.tag.shc> == 1)
src.sysmessage Yuce sahsiyetiniz daha once kalkan ile onurlandirilmis.
return 1
endif
src.tag.shc 1
src.newitem i_shield_chaos
src.act.bounce
else
src.sysmessage Sadece Order ve Chaos guildleri kendilerine ait bir shield'a sahip olabilirler.
endif

[dialog d_gs_abbrev]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 250 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_abbrev TEXT]
Yeni guild kisaltmasi giriniz. (3 karakter)
Tamam
Vazgec
<abbrev>

[dialog d_gs_abbrev BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif ((strlen(<argtxt[0]>)) > 3)
src.sysmessage Guild kisaltmasi en fazla 3 karakterden olusabilir.
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>',''))
src.sysmessage Bir kisaltma girmediniz?
dialog d_gs_abbrev
else
abbrev <argtxt[0]>
src.sysmessage Yeni kisaltma: <abbrev>
menu menu_guild_masterfunc
endif

[dialog d_gs_rename]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 250 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_rename TEXT]
Yeni guild kisaltmasi giriniz. (16 karakter)
Tamam
Vazgec
<name>

[dialog d_gs_rename BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif ((strlen(<argtxt[0]>)) > 16)
src.sysmessage Guild ismi en fazla 16 karakterden olusabilir.
dialog d_gs_rename
elseif (strmatch('<argtxt[0]>',''))
src.sysmessage Bir isim girmediniz?
dialog d_gs_rename
else
name <argtxt[0]>
src.sysmessage Yeni isim: <name>
menu menu_guild_masterfunc
endif

// Guild master functions.
[MENU MENU_GUILD_MASTERFUNC]
<Name>, Guild <MasterGenderTitle> functions
ON=0 Set the guild's name.
dialog d_gs_rename
ON=0 Set the guild's abbreviation.
dialog d_gs_abbrev
ON=0 Change the alignment of guild.
if (<timer> > 0) && (<morey>)
if (<eval (<timer> / 3600)> < 1)
src.sysmessage Taraf degistirme surecindeyken bu menuyu kullanamazsiniz. (<eval (<timer> / 60)> dakika)
else
src.sysmessage Taraf degistirme surecindeyken bu menuyu kullanamazsiniz. (<eval (<timer> / 3600)> saat)
endif
menu menu_guild_masterfunc
return 1
endif
if (<more1> == 0) && (<link> == 04fffffff)
var.gs_align Tarafsiz
elseif (<more1> == 1)
var.gs_align Order
elseif (<more1> == 2)
var.gs_align Chaos
elseif (<link> == 04009163d)
var.gs_align Shamino
elseif (<link> == 04009149f)
var.gs_align Jakama
elseif (<link> == 040091450)
var.gs_align Daxantec
elseif (<link> == 04009139c)
var.gs_align Arcanum
endif
dialog d_gs_alignment
ON=0 Set the guild's charter.
SETCHARTER
ON=0 Grant title to a member.
if (strmatch('<abbrev>',''))
src.sysmessage Bir uyeye unvan verebilmek icin once guild kisaltmasi belirlemelisiniz.
menu menu_guild_masterfunc
else
morex 2
target Unvan vermek istediginiz guild uyesini seciniz.
endif
ON=0 Dismiss a member.
DISMISSMEMBER
ON=0 Declare war.
DECLAREWAR
ON=0 Declare peace.
DECLAREPEACE
ON=0 Accept a candidate seeking membership.
ACCEPTCANDIDATE
ON=0 Refuse a candidate seeking membership.
REFUSECANDIDATE
ON=0 Sell the guildstone for 22.000 gold.
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
REMOVE
SRC.NEWITEM i_gold
SRC.ACT.AMOUNT=22000
SRC.ACT.BOUNCE
SERV.ALLCLIENTS SYSMESSAGE <Name> guild has been destroyed.                                 
ON=0 Return to main menu
RETURNMAINMENU

//ON=0 Issue Chaos Shields
//NEWITEM=i_shield_chaos
//SRC.ACT.LINK=<SERIAL>
//ON=0 Issue Order Shields
//NEWITEM=I_SHIELD_ORDER
//SRC.ACT.LINK=<SERIAL>
// Non-member view.

// Non-member view.
[MENU MENU_GUILD_NON]
<Name> (<Master>)
ON=0 Guild's roster.
VIEWROSTER
ON=0 List of candidates.
VIEWCANDIDATES
ON=0 Guild's charter.
VIEWCHARTER
ON=0 Enemies of <Name>.
VIEWENEMYS
ON=0 Threats to <Name>.
VIEWTHREATS

[MENU MENU_GUILD_ALIGN]
Change the alignment of guild.
ON=0 British: Order
CHANGEALIGN 1
ON=0 Blackthorn: Chaos
CHANGEALIGN 2
ON=0 Neutral
CHANGEALIGN 0
ON=0 Faction: Shamino
MORE1 0
MORE2 04009163d
ON=0 Faction: Jakama
MORE1 0
MORE2 04009149f
ON=0 Faction: Daxantec
MORE1 0
MORE2 040091450
ON=0 Faction: Arcanum
MORE1 0
MORE2 04009139c