Hesabına erişemeyen eski üyeler Discord üzerinden yardım alabilir.
Silindi
Simdi sorun su arkadaslar drojen factıondan sehrı secıyorum o sehırde factıon tası ısteıgım yerde cıkıyor uye oluyorum oluyor events ler yazıyor ama hemen uye sayısı gene sıfır ve evnts gene sılınıyor menuler dıaloglar calısıyor. topıctede hata basmıyor ama sorun var anlamadım bıse bırı akılversın plssss




[itemdef i_drojen_faction]
name Faction Stone
id 0116e
type t_script

on=@create
attr 010


on=@dclick
for 1 10
if (<tag0.sehir<eval <local._for>>>)
if !(<uid.<tag0.sehir<eval <local._for>>>.type>)
try tag.sehir<eval <local._for>>
endif
if !(<uid.<tag0.cgrv_vf_<eval <local._for>>>.type>)
try tag0.cgrv_vf_<eval <local._for>>
endif
endif
endfor
sdialog d_drojenfctn
return 1

on=@targon_item
if (<src.targ.baseid>==i_fctn_stone)
try tag.sehir<morex> <src.targ.uid>
src.targ.link <uid>
src.sysmessage @03b2,,1 Senkronize islemi tamamlandi!
return 1
endif
src.sysmessage @38 Bu bir faction stone degil.
return 1

on=@click
messageua 0481,6,6,enu Faction Kontrol Panel
return 1

[itemdef i_fctn_stone]
id i_grave_stone
name Faction Stone
type t_stone_town

on=@create
attr 050

on=@click
messageua 0481,6,6,enu [<member.count> Uye]
messageua 0481,6,6,enu <region.name> Faction Stone
return 1

on=@dclick
if (<src.account.plevel> >1)
if !(strmatch('<src.account>','memocan') || (strmatch('<src.account>','exor'))
return 1
else
sdialog d_fctnown
endif
else
if (<src.memoryfindtype.memory_town>)
if !(<src.memoryfindtype.memory_town.link>==<uid>)
src.sysmessage @38 Siz bu tasa bakamazsiniz!
return 1
endif
endif
sdialog d_fctn
endif
return 1

[dialog d_fctnown]
0,0
resizepic 100 60 5120 210 90
resizepic 110 70 3000 190 70

button 120 80 210 211 1 0 1
button 120 105 210 211 1 0 2
dhtmlgump 143 80 200 20 0 0 Owner Menu
dhtmlgump 143 105 200 20 0 0 Player Menu

[dialog d_fctnown button]
onbutton 1
MENU MENU_TOWN_MAYOR

onbutton 2
sdialog d_fctn

[dialog d_drojenfctn]
0,0
resizepic 60 60 5120 300 320
resizepic 70 70 3000 280 300

dhtmlgump 95 90 300 20 0 0 <serv.servname> Faction Sistemi

page 1
var.y 120
for 1 10
dhtmlgump 100 <eval <var.y>> 100 20 0 0 <def.fctnsehir<eval <local._for>>>
button 80 <eval <var.y>> 5601 5605 1 0 <eval <local._for>>
button 260 <eval <var.y>+5> 2362 2362 1 0 <eval <local._for>+50>
dhtmlgump 278 <eval <var.y>> 100 20 0 0 senkronize
gumppic 200 <eval <var.y>+5> <qval (<tag0.sehir<eval <local._for>>>) ? 2361:2360>
var.y +=20
endfor

//button 80 <eval <var.y>+10> 5601 5605 1 0 101
//dhtmlgump 100 <eval <var.y>+10> 100 20 0 0 Genel Siralama


if (<eval <def.cgrv_vf_sistemacik>>==1)
resizepic 380 60 5120 145 320
resizepic 390 70 3000 125 300

dtext 402 85 0 0 Faction Gorevleri
dtext 423 100 0 0 Eklentisi
var.y 120
for 1 10
dhtmlgump 420 <eval <var.y>> 100 20 0 0 <def.fctnsehir<eval <local._for>>>
button 403 <eval <var.y>+5> <qval (<tag0.cgrv_vf_<eval <local._for>>>) ? 2361:2360> <qval (<tag0.cgrv_vf_<eval <local._for>>>) ? 2360:2361> 1 0 <eval <local._for>+3000>
var.y +=20
endfor
endif


page 2
button 80 115 5603 5607 0 1
dhtmlgump 100 115 200 20 0 0 geri

if <eval <src.tag.fctnstone>>
dhtmlgump 90 150 200 20 0 0 Sehir : <def.fctnsehir<eval <src.tag.fctnstone>>>
dhtmlgump 90 170 200 20 0 0 Populasyon : <uid.<tag0.sehir<eval <src.tag.fctnstone>>>.member.count>
dhtmlgump 113 195 200 20 0 0 Rutbe 1 : <uid.<tag0.sehir<eval <src.tag.fctnstone>>>.tag0.rutbe1>
dhtmlgump 113 215 200 20 0 0 Rutbe 2 : <uid.<tag0.sehir<eval <src.tag.fctnstone>>>.tag0.rutbe2>
dhtmlgump 113 235 200 20 0 0 Rutbe 3 : <uid.<tag0.sehir<eval <src.tag.fctnstone>>>.tag0.rutbe3>
dhtmlgump 113 255 200 20 0 0 Rutbe 4 : <uid.<tag0.sehir<eval <src.tag.fctnstone>>>.tag0.rutbe4>
button 90 195 210 211 1 0 1002
button 90 215 210 211 1 0 1003
button 90 235 210 211 1 0 1004
button 90 255 210 211 1 0 1005

button 90 310 210 211 1 0 1006
dhtmlgump 113 310 200 20 0 0 Faction Stone Dialog
button 90 330 210 211 0 4
dhtmlgump 113 330 200 20 0 0 Faction Kaldir
endif

page 3
dhtmlgump 100 120 220 20 0 0 <def.fctnsehir<eval <src.tag.fctnstone>>> sehrine faction
dhtmlgump 100 138 220 20 0 0 eklemek istiyorsunuz.Bu isleme
dhtmlgump 100 156 220 20 0 0 devam etmek istiyormusunuz?
button 100 200 4023 4025 1 0 1001
dtext 133 200 0 Evet
button 100 225 4017 4019 0 1
dtext 133 225 0 Hayir
page 4
dhtmlgump 100 120 220 20 0 0 <def.fctnsehir<eval <src.tag.fctnstone>>> sehrindeki
dhtmlgump 100 138 220 20 0 0 facitonu kaldirmak
dhtmlgump 100 156 220 20 0 0 istediginize eminmisiz?
button 100 200 4023 4025 1 0 1007
dtext 133 200 0 Evet
button 100 225 4017 4019 0 1
dtext 133 225 0 Hayir

[dialog d_drojenfctn button]
on 1 10
src.tag.fctnstone <argn>
if (<tag0.sehir<argn>>)
sdialog d_drojenfctn 2
else
sdialog d_drojenfctn 3
endif

on 51 60
morex <argn> -50
src.sysmessage @03b2,,1, Senkronize,bu menude aktif olarak gorunmeyen tasi menuye yerlestirmeye yarar!
target @50 Senkronize edilecek tasi seciniz

onbutton 1007
if (<tag0.cgrv_vf_<eval <src.tag.fctnstone>>>)
src.sysmessage @38 oncelikle bu sehirdeki gorev sistemini kaldirin
return 1
endif
for 0 <eval <uid.<tag.sehir<eval <src.tag.fctnstone>>>.member.count>-1>
try uid.<uid.<tag.sehir<eval <src.tag.fctnstone>>>.member.<eval <local._for>>.uid>.events -e_fctn
try uid.<uid.<tag.sehir<eval <src.tag.fctnstone>>>.member.<eval <local._for>>.uid>.account.tag.faction
endfor
try uid.<tag.sehir<eval <src.tag.fctnstone>>>.remove
src.sysmessage @0481 Faction kaldirildi.
sdialog d_drojenfctn

onbutton 1001
serv.newitem i_fctn_stone
src.new.link <uid>
src.new.p <def.fctnsehirp<eval <src.tag.fctnstone>>>
src.new.name <def.fctnsehir<eval <src.tag.fctnstone>>>
try tag.sehir<eval <src.tag.fctnstone>> <src.new.uid>
src.sysmessage @0481 <def.fctnsehir<eval <src.tag.fctnstone>>> faction stone eklendi
sdialog d_drojenfctn

onbutton 1002
tryp 7 inpdlg uid.<tag.sehir<eval <src.tag.fctnstone>>>.tag.rutbe1 12
onbutton 1003
tryp 7 inpdlg uid.<tag.sehir<eval <src.tag.fctnstone>>>.tag.rutbe2 12
onbutton 1004
tryp 7 inpdlg uid.<tag.sehir<eval <src.tag.fctnstone>>>.tag.rutbe3 12
onbutton 1005
tryp 7 inpdlg uid.<tag.sehir<eval <src.tag.fctnstone>>>.tag.rutbe4 12

onbutton 1006
try uid.<tag.sehir<eval <src.tag.fctnstone>>>.sdialog d_fctnown

onbutton 101
allfctnlist
if (<eval <tag.member>> <1)
src.sysmessage @38 Factionda hic uye yok
return 1
endif
var.for1 0
var.for2 15
sdialog d_allfctnlist


on 3001 3010
if !(<tag0.sehir<eval <argn>-3000>>)
src.sysmessage @38 Oncelikle <def.fctnsehir<eval <argn>-3000>> sehrine faction kurmalisiniz
return 1
endif
if (<tag0.cgrv_vf_<eval <argn>-3000>>)
src.sysmessage @0481 <def.fctnsehir<eval <argn>-3000>> sehrinden gorev eklentisi kaldirildi.
try uid.<uid.<tag.cgrv_vf_<eval <argn>-3000>>>.cgrv_vf_kaldir
try tag.cgrv_vf_<eval <argn>-3000>
else
src.sysmessage @0481 <def.fctnsehir<eval <argn>-3000>> sehrine gorev eklentisi kuruldu.
cgrv_vf_kur <eval <argn>-3000>
endif
sdialog d_drojenfctn



[dialog d_fctn]
0,0
resizepic 60 60 5120 300 245
resizepic 70 70 3000 280 225
dhtmlgump 85 80 250 20 0 0 <def.center><serv.servname> Faction Sistemi

page 1
resizepic 85 100 3600 250 4
dhtmlgump 100 103 250 20 0 0 <def.bfont_size3>BILGI
dhtmlgump 85 110 250 20 0 0 <def.center><name> sehri
dhtmlgump 85 125 250 20 0 0 <def.center>Populasyon <def.h3><member.count>
resizepic 85 150 3600 250 1
dhtmlgump 100 153 70 20 0 0 <def.bfont_size3>SIRALAMA

dhtmlgump 150 177 100 20 0 0 <def.center><name>
button 190 157 210 211 1 0 1001
//dhtmlgump 250 177 100 20 0 0 <def.center>Hepsi
//button 290 157 210 211 1 0 1004

resizepic 85 200 3600 250 1
dhtmlgump 100 203 250 20 0 0 <def.bfont_size3>ISLEM

if (<src.memoryfindtype.memory_town>)
if (<src.memoryfindtype.memory_town.link>==<uid>)
dcroppedtext 113 230 200 20 026 Factiondan ayril
button 90 230 210 211 1 0 1002
endif
else
dhtmlgump 113 230 200 20 0 0 <def.bfont_size4>Factiona Gir
button 90 230 210 211 1 0 1003
endif

dhtmlgump 113 252 200 20 0 0 <def.bfont_size4><name> Market
button 90 252 210 211 0 2

resizepic 85 285 3600 250 2


page 2
resizepic 85 100 3600 250 4
dhtmlgump 100 103 250 20 0 0 <def.bfont_size3>MARKET

dhtmlgump 103 150 400 20 0 0 <def.bfont_size3>Normal Faction Robe [200 Silver Coin]
dhtmlgump 103 170 400 20 0 0<def.bfont_size3>Hits Regeneration Robe [2000 Silver Coin]
dhtmlgump 103 190 400 20 0 0 <def.bfont_size3>Mana Regeneration Robe [2000 Silver Coin]
button 80 150 5601 5605 1 0 1
button 80 170 5601 5605 1 0 2
button 80 190 5601 5605 1 0 3

[dialog d_fctn button]
onbutton 1
if (<src.restest 200 i_fctn_silvercoin>)
serv.newitem i_fctn_robe
src.new.link <src.memoryfindtype.memory_town.link>
src.new.bounce
src.consume 200 i_fctn_silvercoin
else
src.sysmessage @021 200 Silver Coininiz yok
endif

onbutton 2
if (<src.restest 2000 i_fctn_silvercoin>)
serv.newitem i_fctn_robe_hits
src.new.link <src.memoryfindtype.memory_town.link>
src.new.bounce
src.consume 2000 i_fctn_silvercoin
else
src.sysmessage @021 2000 Silver Coininiz yok
endif

onbutton 3
if (<src.restest 2000 i_fctn_silvercoin>)
serv.newitem i_fctn_robe_mana
src.new.link <src.memoryfindtype.memory_town.link>
src.new.bounce
src.consume 2000 i_fctn_silvercoin
else
src.sysmessage @021 2000 Silver Coininiz yok
endif

onbutton 1001
if (<member.count> <1)
	src.sysmessage @021 Hic uye yok
	return 1
endif
//fctnlist
var.for1 0
var.for2 15
sdialog d_fctnlist

onbutton 1002
if (<src.findid.i_fctnmemory>)
src.sysmessage @021 Zaten bu islemi yapmissiniz. 24 saat icinde ayrilacaksiniz.
return 1
endif
src.newitem i_fctnmemory
src.new.timer 3600*24
src.new.equip
src.sysmessage @03b2,,1, 24 saat sonra factiondan ayrilacaksiniz. (Faction ile ilgili tum bilgileriniz silinecek. Faction puan vs.)


onbutton 1003
if (<src.account.tag0.faction>)
	src.sysmessage @021 Baska bir karakterinizle zaten factiona uyesiniz
	return 1
elif (<src.skilltotal> <7000)
	src.sysmessage @021 Factiona girebilmek icin skilllerinizin toplami en az 700 olmali
	return 1
elif (<src.findid.i_fctnmemory>)
	src.sysmessage @021 Yakin zamanda bir factiondan ayrilmissiniz. 24 saat icinde tekrar uye olamazsiniz
	return 1
endif
if (<src.memoryfindtype.memory_guild>)
	if !(<src.memoryfindtype.memory_guild.link.align>==0)
		src.sysmessage @021 Factiona girebilmeniz icin guildinizin natural olmasi gerekir
		return 1
	endif
endif

applytojoin
message
message
message
say <name> yeni uye: <src.name>.
src.events +e_fctn
dclick
src.fctn_checklist
src.sysmessage <name>: hosgeldiniz.
src.update
src.account.tag.faction <uid>
src.tag.fctn_decaykill 10


onbutton 1004
//link.allfctnlist
if (<eval <link.tag.member>> <1)
	src.sysmessage @021 Factionda hic uye yok
	return 1
endif
var.for1 0
var.for2 15
//link.sdialog d_allfctnlist



[dialog d_allfctnlist]
0,0
resizepic 60 60 5120 600 400
resizepic 70 70 3000 580 380
dhtmlgump 135 90 300 20 0 0 <serv.servname> Faction Sistemi - Undeath Pvp

dhtmlgump 120 120 100 20 0 0 isim
dhtmlgump 250 120 100 20 0 0 puan
dhtmlgump 330 120 100 20 0 0 kill
dhtmlgump 390 120 100 20 0 0 death
dhtmlgump 460 120 100 20 0 0 rutbe
dhtmlgump 530 120 100 20 0 0 faction
resizepic 80 140 9350 0 0 2

if (<eval <var.for2>> > <eval <tag.member>-1>)
var.for2 <eval <tag.member>-1>
endif

var.y 145
for <eval <var.for1>> <eval <var.for2>>
if <uid.<tag.list<eval <local._for>>>>
dhtmlgump 90 <eval <var.y>> 200 20 0 0 <uid.<tag.list<eval <local._for>>>.name>
dhtmlgump 240 <eval <var.y>> 200 20 0 0 <eval <uid.<tag.list<eval <local._for>>>.tag.fctn_puan>>
dhtmlgump 330 <eval <var.y>> 200 20 0 0 <eval <uid.<tag.list<eval <local._for>>>.tag.fctn_kill>>
dhtmlgump 390 <eval <var.y>> 200 20 0 0 <eval <uid.<tag.list<eval <local._for>>>.tag.fctn_death>>
dhtmlgump 460 <eval <var.y>> 200 20 0 0 <uid.<tag.list<eval <local._for>>>.tag.rutbe>
dhtmlgump 530 <eval <var.y>> 200 20 0 0 <uid.<tag.list<eval <local._for>>>.memoryfindtype.memory_town.link.name>
var.y +=17
endif
endfor
var.y 

if (<eval <var.for2>> < <eval <tag.member>-1>)
button 500 425 5601 5605 1 0 1
endif
if (<eval <var.for1>> > 0)
button 470 425 5603 5607 1 0 2
endif

[dialog d_allfctnlist button]
onbutton 1
var.for1 <eval <var.for1>> +16
var.for2 <eval <var.for1>> +15
sdialog d_allfctnlist

onbutton 2
var.for1 <eval <var.for1>> -16
var.for2 <eval <var.for1>> +15
sdialog d_allfctnlist


[dialog d_fctnlist]
0,0
resizepic 60 60 5120 500 400
resizepic 70 70 3000 480 380
dhtmlgump 135 90 300 20 0 0 <serv.servname> Faction Sistemi

dhtmlgump 120 120 100 20 0 0 isim
dhtmlgump 250 120 100 20 0 0 puan
dhtmlgump 330 120 100 20 0 0 kill
dhtmlgump 390 120 100 20 0 0 death
dhtmlgump 460 120 100 20 0 0 rutbe
resizepic 80 140 9350 455 2

if (<eval <var.for2>> > <eval <member.count>-1>)
var.for2 <eval <member.count>-1>
endif

var.y 145
for <eval <var.for1>> <eval <var.for2>>
if <uid.<tag.listmember<eval <local._for>>>>
dcroppedtext 90 <eval <var.y>> 200 20 035 <uid.<tag.listmember<eval <local._for>>>.name>
dcroppedtext 240 <eval <var.y>> 200 20 555 <eval <uid.<tag.listmember<eval <local._for>>>.tag.fctn_puan>>
dcroppedtext 330 <eval <var.y>> 200 20 555 <eval <uid.<tag.listmember<eval <local._for>>>.tag.fctn_kill>>
dcroppedtext 390 <eval <var.y>> 200 20 555 <eval <uid.<tag.listmember<eval <local._for>>>.tag.fctn_death>>
dcroppedtext 460 <eval <var.y>> 200 20 555 <uid.<tag.listmember<eval <local._for>>>.tag.rutbe>
var.y +=17
endif
endfor
var.y 

if (<eval <var.for2>> < <eval <member.count>-1>)
button 400 425 5601 5605 1 0 1
endif
if (<eval <var.for1>> > 0)
button 370 425 5603 5607 1 0 2
endif

[dialog d_fctnlist button]
onbutton 1
var.for1 <eval <var.for1>> +16
var.for2 <eval <var.for1>> +15
sdialog d_fctnlist

onbutton 2
var.for1 <eval <var.for1>> -16
var.for2 <eval <var.for1>> +15
sdialog d_fctnlist


[itemdef i_fctnmemory]
id i_memory
type t_eq_script
name faction memory

on=@timer
cont.account.tag.faction
cont.tag.fctn_puan
cont.tag.fctn_kill
cont.tag.fctn_death
cont.events -e_fctn

trysrc <cont.uid> fctnayril
remove
return 1

[function fctnayril]
obj <src.memoryfindtype.memory_town.link>
obj.fctn_checklist3 <src.uid>
src.memoryfindtype.memory_town.link.resign

[itemdef i_fctn_silvercoin]
id 0ef0
type t_coin
name Ozel Coin
dupelist 0ef1,0ef2

on=@create
color 0455

on=@click
message @0481 <name>
return 1

[function checkrutbe]
var.rutbe1 <eval <memoryfindtype.memory_town.link.member.count>*10> / 13
var.rutbe2 <eval <memoryfindtype.memory_town.link.member.count>*10> / 40
var.rutbe3 <eval <memoryfindtype.memory_town.link.member.count>*10> / 80
var.rutbe4 <eval <memoryfindtype.memory_town.link.member.count>*10> / 200
if (<eval <tag.fctn_puan>> > <eval <uid.<uid.<memoryfindtype.memory_town.link>.tag.listmember<eval <var.rutbe4>>>.tag.fctn_puan>>) && (<eval <var.rutbe4>> >0)
tag.rutbe <memoryfindtype.memory_town.link.tag0.rutbe4>
elif (<eval <tag.fctn_puan>> > <eval <uid.<uid.<memoryfindtype.memory_town.link>.tag.listmember<eval <var.rutbe3>>>.tag.fctn_puan>>) && (<eval <var.rutbe3>> >0)
tag.rutbe <memoryfindtype.memory_town.link.tag0.rutbe3>
elif (<eval <tag.fctn_puan>> > <eval <uid.<uid.<memoryfindtype.memory_town.link>.tag.listmember<eval <var.rutbe2>>>.tag.fctn_puan>>) && (<eval <var.rutbe2>> >0)
tag.rutbe <memoryfindtype.memory_town.link.tag0.rutbe2>
else
tag.rutbe <memoryfindtype.memory_town.link.tag0.rutbe1>
endif

[events e_fctn]
on=@click
if !(<memoryfindtype.memory_town>)
events -e_fctn
account.tag.faction
tag.fctn_puan
tag.fctn_kill
tag.fctn_death
endif
if !(<findid.i_rune_incognito>)
checkrutbe
if (<memoryfindtype.memory_guild>) && !(strmatch('<memoryfindtype.memory_guild.link.abbrev>',''))
message @0790 [<memoryfindtype.memory_guild.link.abbrev>] [Puan :<eval <tag.fctn_puan>>, <memoryfindtype.memory_town.link.name>]
else
message @0481 [Puan :<eval <tag.fctn_puan>>, <memoryfindtype.memory_town.link.name>]
endif
endif

//on=@hit
//if (<src.memoryfindtype.memory_town>) && !(<act.isevent.e_cpvp>) && !(<act.isevent. e_cpvp_duello>)
//if (<memoryfindtype.memory_town.link>==<src.memoryfindtype.memory_town.link>)
//sysmessage @38,,1 Ayni factiondan birisine saldirmazsin
//action -1
//return 1
//endif
//endif
//on=@spellcast
//if (<src.memoryfindtype.memory_town>) && !(<act.isevent.e_cpvp>) && !(<act.isevent. e_cpvp_duello>)
//if (<argn>==1) || (<argn>==3) || (<argn>==5) || (<argn>==8) || (<argn>==10) || (<argn>==12) || (<argn>==18) || (<argn>==20) || (<argn>==30) || (<argn>==31) || (<argn>==37) || (<argn>==38) || (<argn>==43) || (<argn>==51)
//if (<act.memoryfindtype.memory_town.link>==<src.memoryfindtype.memory_town.link>)
//src.sysmessage @38,,1 Ayni factiondan birisine buyu atamazsin
//f_fizzle
//return 1
//endif
//endif
//endif

[function f_fctndeath]

if (<act.memoryfindtype.memory_town>)
  tag.fctn_death <eval <tag.fctn_death>> +1
  act.tag.fctn_kill <eval <tag.fctn_kill>> +1
   if (<eval <tag.fctn_puan>> <20)
   tag.fctn_puan 20
   endif

  if (<eval <tag.fctn_decaykill>> > 0)
  tag.fctn_decaykill <eval <tag.fctn_decaykill>> - 1
  tag.fctn_puan <eval <tag.fctn_puan>> - <eval <eval <tag.fctn_puan>*5>/100>
  sysmessage @0156 <eval <eval <tag.fctn_puan>*5>/100> faction puan kaybettiniz
  fctn_checklist
  if (<eval <tag.fctn_puan>> <10)
  tag.fctn_puan 10
  endif
  if (<eval <eval <tag.fctn_puan>*3>/100> >0)
  serv.newitem i_fctn_silvercoin
  new.amount <eval <eval <tag.fctn_puan>*3>/100>
  new.cont <act.findlayer.21>
  act.sysmessage @0481 <eval <eval <tag.fctn_puan>*3>/100> silver coin kazandiniz
  endif
  act.tag.fctn_decaykill <eval <act.tag.fctn_decaykill>> + 1
  act.tag.fctn_puan <eval <act.tag.fctn_puan>> + <eval <eval <tag.fctn_puan>*10>/100>
  act.sysmessage @035 <eval <eval <tag.fctn_puan>*10>/100> faction puan kazandiniz
  act.fctn_checklist
  else
  act.sysmessage @0156 <name> adli kisiden puan alamadiniz.
  endif

endif

[function fctn_checklist]
obj <memoryfindtype.memory_town.link>
obj.fctn_checklist3 <uid>
for 0 <eval <obj.member.count>-1>
if !(<uid.<obj.tag.listmember<eval <local._for>>>>)
try obj.tag.listmember<eval <local._for>> <uid>
return 1
elif (<eval <tag.fctn_puan>> > <eval <uid.<obj.tag.listmember<eval <local._for>>>.tag.fctn_puan>>)
obj.fctn_checklist2 <eval <local._for>>
try obj.tag.listmember<eval <local._for>> <uid>
return 1
endif
endfor

[function fctn_checklist2]
for <eval <member.count>-1> <eval <argn1>+1>
try tag.listmember<eval <local._for>> <tag.listmember<eval <local._for>-1>>
endfor

[function fctn_checklist3]
for 0 <eval <member.count>-1>
if (strmatch('<tag.listmember<eval <local._for>>>','<args>'))
fctn_checklist3_1 <eval <local._for>>
return 1
endif
endfor

[function fctn_checklist3_1]
for <argn1> <eval <member.count>-1>
try tag.listmember<eval <local._for>> <tag0.listmember<eval <local._for>+1>>
endfor

[function fctn_checklist4]
targetf fctn_checklist4f

[function fctn_checklist4f]
for 0 <eval <uid.<argo.uid>.member.count>-1>
obj <uid.<argo.uid>.member.<eval <local._for>>.uid>
obj.fctn_checklist
endfor

[function fctn_checklist5]
targetf fctn_checklist5f

[function fctn_checklist5f]
for 0 <eval <uid.<argo.uid>.member.count>-1>
try uid.<argo.uid>.tag.listmember<eval <local._for>> 
endfor

[function fctn_checklist6]
targetf fctn_checklist6f

[function fctn_checklist6f]
for 0 <eval <uid.<argo.uid>.member.count>-1>
obj <uid.<argo.uid>.member.<eval <local._for>>.uid>
obj.checkrutbe
endfor

[itemdef i_fctn_robe]
name faction robe
id i_robe
weight 1
type t_clothing
armor 22

On=@Create
attr 04
hitpoints 100
color 0481

On=@Equip
if !(<src.memoryfindtype.memory_town>) || !(<src.memoryfindtype.memory_town.link.uid>==<link>)
cont <src.findlayer(21).uid>
endif

On=@Click
color 0481
message @0 <name>
message @0492,,1 [<link.name>]
return 1


[itemdef i_fctn_robe_hits]
name faction robe hits
id i_robe
weight 1
type t_clothing
armor 22

On=@Create
attr 04
hitpoints 100

On=@Equip
serv.newitem i_regenmem
src.new.tag.stat hits
src.new.tag.stat2 str
src.new.timer 10
src.new.cont <src.uid>
if !(<src.memoryfindtype.memory_town>) || !(<src.memoryfindtype.memory_town.link.uid>==<link>)
unequip
endif

on=@unequip
cont.findid.i_regenmem.remove

On=@Click
message @0 Hits regeneration robe
message @0492,,1 [<link.name>]
return 1


[itemdef i_fctn_robe_mana]
name faction robe mana
id i_deathshroud
weight 1
type t_clothing
armor 22

On=@Create
attr 04
hitpoints 100

On=@Equip
serv.newitem i_regenmem
src.new.tag.stat mana
src.new.tag.stat2 int
src.new.timer 10
src.new.cont <src.uid>
if !(<src.memoryfindtype.memory_town>) || !(<src.memoryfindtype.memory_town.link.uid>==<link>)
unequip
endif

on=@unequip
cont.findid.i_regenmem.remove

On=@Click
message @0 Mana regeneration robe
message @0492,,1 [<link.name>]
return 1


[itemdef i_regenmem]
id i_memory
type t_eq_script
name regen memory

on=@timer
timer 10
if (<cont.<tag.stat>> < <cont.<tag.stat2>>)
if (strmatch('<cont.region.name>','<cont.memoryfindtype.memory_town.link.region.name>'))
try cont.<tag.stat> <cont.<tag.stat>> +4
cont.findlayer.22.message +4 <tag.stat>
return 1
else
try cont.<tag.stat> <cont.<tag.stat>> +2
cont.findlayer.22.message +2 <tag.stat>
return 1
endif
endif
return 1

[defname fctntowns]
fctnsehir1 Venamar
fctnsehir2 Moonglow
fctnsehir3 Minoc
fctnsehir4 Querala
fctnsehir5 Vesper
fctnsehir6 Cove
fctnsehir7 Yew
fctnsehir8 Jhelom
fctnsehir9 Trinsic
fctnsehir10 Buccaneer

[defname fctntowns_no]
fctnsehir_venamar 1
fctnsehir_moonglow 2
fctnsehir_minoc 3
fctnsehir_querala 4
fctnsehir_vesper 5
fctnsehir_cove 6
fctnsehir_yew 7
fctnsehir_jhelom 8
fctnsehir_trinsic 9
fctnsehir_buccaneer 10

[defname fctntownsp]
fctnsehirp1 1433,1619,20
fctnsehirp2 4448,1153,0
fctnsehirp3 2513,571,0
fctnsehirp4 5265,3989,37
fctnsehirp5 2889,688,0
fctnsehirp6 2263,1204,0
fctnsehirp7 540,993,0
fctnsehirp8 1337,3769,0
fctnsehirp9 1829,2823,0
fctnsehirp10 2702,2156,0

[eof]

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.