56b Anket Sistemi

//-------------------------- /////
////Voting System - by ClouD /////
//--------------------------
////E-mail: [email protected] ////
//--------------------------
////ICQ: 133411911 ////
//--------------------------
////You can edit FUNCTIONs at the end of file
//--------------------------
////Please, do not take this header out  plz? ////
//-------------------------- /////

[COMMENT voting_explanations]
This is a nice voting stone, to get opinions from your players!

When you're with .GM on, just dclick the stone and see the menu to do what you want. You can lock the current topic, or make a new one.
You just have to set the topic and the answers at the menu, and the day when the topic is finished.
The stone will take care of the rest, when the day you've set comes, it will automatically broadcast a message with the most voted answer, or if it's a draw, a draw message. AND send the infos to a webpage (that comes with the script)
To the players, it shows the percentage of votes for each answer, and some other misc infos, like the last one that voted, how many topics have been made, and other things.
Each player can vote only ONE time for each topic.
GMs don't have to worry about anything, except for seting the topic. The stone will take care of the rest.
In-game type, .add i_enquete_stone, and dclick it whenever you want to make a topic (don't worry about dclicking it while a topic is running, it won't close the topic)

[DEFNAME voting_sys]
voting_locked_msg "@07ad Voting closed."
voting_finished_msg "@07ad,3 Voting System : Voting finished."

[ITEMDEF i_enquete_stone]
NAME=Enquete
ID=i_gravestone_7
TYPE=t_normal

ON=@Create
TAG.ENQUETE.UID=0
tag.ultimovoto="[nobody]"
TAG.ENQUETE.TRANCADA=1
TAG.ULTIMODIA=0
COLOR=07a0
ATTR=attr_static|attr_decay

ON=@Dclick
IF (<SRC.ISGM>)
SDIALOG d_votacao 1
ELSE
IF (<TAG0.ENQUETE.TRANCADA>)
SRC.SYSMESSAGE <def.voting_locked_msg>
ELIF (<SRC.TAG0.ENQUETE.UID>==<TAG0.ENQUETE.UID>)
SDIALOG d_votacao 4
ELSE
SDIALOG d_votacao 3
ENDIF
ENDIF
RETURN 1

ON=@TIMER
IF (<RTIME.DAY>==<TAG.ULTIMODIA>)
local.1=<EVAL <MORE1>*100>
local.2=<eval <MORE1>+<MORE2>>
local.3=<eval <MORE2>*100>
SERV.B <def.voting_finished_msg>
IF (<MORE1> > <MORE2>)
SERV.B @07ad,3 Winner : <TAG0.RESP1> (<EVAL <MORE1>> votes)
VAR.ENQUETE.PAGE1="Winner : <TAG0.RESP1> (<EVAL <MORE1>> [<EVAL <local.1>/<local.2>>%] votes)"
ELIF (<MORE2> > <MORE1>)
SERV.B @07ad,3 Winner : <TAG0.RESP2> (<EVAL <MORE2>> votes)"
VAR.ENQUETE.PAGE1="Winner : <TAG0.RESP2> (<EVAL <MORE2>> [<EVAL <local.3>/<local.2>>%] votes)"
ELIF (<MORE2>==<MORE1>)
SERV.B @07ad,3 Draw! Each one with <EVAL <MORE1>> votes.
VAR.ENQUETE.PAGE1="Draw! Each one with <EVAL <MORE1>> votes."
ENDIF
VAR.ENQUETE.PAGE2=<TAG0.ENQUETE>
TAG.RESP1=0
TAG.RESP2=0
TAG.ULTIMODIA=0
TAG.ENQUETE.TRANCADA=1
tag.ultimovoto="[nobody]"
MORE1=0
MORE2=0
ELSE
TIMER=10
ENDIF
RETURN 1

[DIALOG d_votacao]
200,120
PAGE 1
resizepic 20 0 3600 500 380
resizepic 40 20 2620 460 150
dhtmlgump 50 26 445 140 0 1 <DEF.BFONT_SIZE7><DEF.CENTER>Actual topic<DEF.CENTERE><DEF.BR><DEF.BFONT_SIZE4><DEF.BFONT_LGREEN>  <TAG0.ENQUETE><DEF.BRE><DEF.BFONTE><DEF.BFONTE><DEF.BFONTE>
local.1=<EVAL <MORE1>*100>
local.2=<eval <MORE1>+<MORE2>>
local.3=<eval <MORE2>*100>
IF (<MORE1>!=0)
dtext 40 200 1152 Answer 1 : <EVAL <local.1>/<local.2>>% (<EVAL <MORE1>>)
ELSE
dtext 40 200 1152 Answer 1 : 0% (<EVAL <MORE1>>)
ENDIF
IF (<MORE2>!=0)
dtext 40 220 1152 Answer 2 : <EVAL <local.3>/<local.2>>% (<EVAL <MORE2>>)
ELSE
dtext 40 220 1152 Answer 2 : 0% (<EVAL <MORE2>>)
ENDIF
dtext 210 200 1152 Last day of this topic : day <EVAL <TAG0.ULTIMODIA>>
resizepic 35 260 3500 460 40
button 58 275 093A 0939 1 0 1
dtextentry 76 270 390 20 88 0 Put the new topic here
button 40 320 093A 0939 1 0 2
IF !(<TAG0.ENQUETE.TRANCADA>)
dtext 55 315 88 Lock votes
ELSE
dtext 55 315 88 UNlock votes
ENDIF

PAGE 2
resizepic 20 0 3600 500 400
resizepic 40 20 2620 460 150
dhtmlgump 50 26 445 140 0 1 <DEF.BFONT_SIZE7><DEF.CENTER>Actual topic<DEF.CENTERE><DEF.BR><DEF.BFONT_SIZE4><DEF.BFONT_LGREEN>  <TAG0.ENQUETE><DEF.BRE><DEF.BFONTE><DEF.BFONTE><DEF.BFONTE>
resizepic 35 190 3500 460 40
dtextentry 65 200 390 20 88 1 Answer 1
resizepic 35 250 3500 460 40
dtextentry 65 260 390 20 88 2 Answer 2
resizepic 35 310 3500 460 40
dtextentry 65 320 390 20 88 3 When does the voting finish?
button 40 360 093A 0939 1 0 3
dtext 55 355 0ad Confirm

PAGE 3
resizepic 20 0 3600 500 380
resizepic 40 20 2620 460 150
dhtmlgump 50 26 445 140 0 1 <DEF.BFONT_SIZE7><DEF.CENTER>Actual topic<DEF.CENTERE><DEF.BR><DEF.BFONT_SIZE4><DEF.BFONT_LGREEN>  <TAG0.ENQUETE><DEF.BRE><DEF.BFONTE><DEF.BFONTE><DEF.BFONTE>
dhtmlgump 40 180 225 110 1 1 <DEF.BFONT_DGREEN><TAG0.RESP1><DEF.BFONTE>
dhtmlgump 275 180 225 110 1 1 <DEF.BFONT_DGREEN><TAG0.RESP2><DEF.BFONTE>
button 90 320 093A 0939 1 0 4
dtext 105 315 1152 Answer 1
button 340 320 093A 0939 1 0 5
dtext 355 315 1152 Answer 2

PAGE 4
resizepic 20 0 3600 500 300
resizepic 40 20 2620 460 150
dhtmlgump 50 26 445 140 0 1 <DEF.BFONT_SIZE7><DEF.CENTER>Actual topic<DEF.CENTERE><DEF.BR><DEF.BFONT_SIZE4><DEF.BFONT_LGREEN>  <TAG0.ENQUETE><DEF.BRE><DEF.BFONTE><DEF.BFONTE><DEF.BFONTE>
local.1=<EVAL <MORE1>*100>
local.2=<eval <MORE1>+<MORE2>>
local.3=<eval <MORE2>*100>
IF (<MORE1>!=0)
dtext 40 200 1152 Answer 1 : <EVAL <local.1>/<local.2>>% (<EVAL <MORE1>>)
ELSE
dtext 40 200 1152 Answer 1 : 0% (<EVAL <MORE1>>)
ENDIF
IF (<MORE2>!=0)
dtext 40 220 1152 Answer 2 : <EVAL <local.3>/<local.2>>% (<EVAL <MORE2>>)
ELSE
dtext 40 220 1152 Answer 2 : 0% (<EVAL <MORE2>>)
ENDIF
dtext 290 200 1152 Last day of this topic : day <EVAL <TAG0.ULTIMODIA>>
dtext 290 220 1152 Last vote by <tag0.ultimovoto>
dtext 40 240 1152 Total votes : <EVAL <MORE1>+<MORE2>>
dtext 290 240 1152 Total topics made : <eval <tag0.enquete.uid>>

[DIALOG d_votacao BUTTON]
ON=1
TAG.ENQUETE.TRANCADA=1
TAG.ENQUETE=<STRSUB 0 1500 <ARGTXT[0]>>
MORE1=0
MORE2=0
tag.ultimovoto="[nobody]"
var.enquete.lastvote="[nobody]"
TAG.RESP1=0
TAG.RESP2=0
SDIALOG d_votacao 2
VAR.ENQUETE.PAGE2=<TAG0.ENQUETE>

ON=2
IF !(<TAG0.ENQUETE.TRANCADA>)
TAG.ENQUETE.TRANCADA=1
ELSE
TAG.ENQUETE.TRANCADA=0
ENDIF

ON=3
IF !(<ISNUM <ARGTXT[3]>>) || (<ARGTXT[3]> > 31) || (<ARGTXT[3]>==<RTIME.DAY>)
SRC.SYSMESSAGE @07a1 You must write a valid number.
SDIALOG d_votacao 2
ELSE
TAG.RESP1=<STRSUB 0 1200 <ARGTXT[1]>>
TAG.RESP2=<STRSUB 0 1200 <ARGTXT[2]>>
TAG.ULTIMODIA=<STRSUB 0 2 <ARGTXT[3]>>
TAG.ENQUETE.UID += 1
TAG.ENQUETE.TRANCADA=0
MORE1=0
MORE2=0
TIMER=10
VAR.ENQUETE.RESP1="<TAG0.RESP1> (0) (0%)"
VAR.ENQUETE.RESP2="<TAG0.RESP2> (0) (0%)"
VAR.ENQUETE.LASTDAY="day <EVAL <TAG.ULTIMODIA>>"
ENDIF

ON=4
MORE1 += 1
local.1=<EVAL <MORE1>*100>
local.2=<eval <MORE1>+<MORE2>>
VAR.ENQUETE.RESP1="<TAG0.RESP1> (<EVAL <MORE1>>) (<EVAL <local.1>/<local.2>>%)"
TAG.ULTIMOVOTO=<SRC.NAME>
var.enquete.lastvote="<SRC.NAME>"
SRC.TAG.ENQUETE.UID=<TAG.ENQUETE.UID>

ON=5
MORE2 += 1
local.1=<EVAL <MORE2>*100>
local.2=<eval <MORE1>+<MORE2>>
VAR.ENQUETE.RESP2="<TAG0.RESP2> (<EVAL <MORE2>>) (<EVAL <local.1>/<local.2>>%)"
TAG.ULTIMOVOTO=<SRC.NAME>
var.enquete.lastvote="<SRC.NAME>"
SRC.TAG.ENQUETE.UID=<TAG.ENQUETE.UID>

/////////////////////////////////////

[FUNCTION rtime.year]
return <strsub 0 4 <serv.rtime>>

[FUNCTION rtime.month]
return <strsub 5 2 <serv.rtime>>

[FUNCTION rtime.day]
return <strsub 8 2 <serv.rtime>>

[FUNCTION rtime.hour]
return <strsub 10 3 <serv.rtime>>

[defname def_html] // useful with htmlgumps
BFONT_SIZE1 <basefont SIZE="1">
BFONT_SIZE2 <basefont SIZE="2">
BFONT_SIZE3 <basefont SIZE="3">
BFONT_SIZE4 <basefont SIZE="4">
BFONT_SIZE5 <basefont SIZE="5">
BFONT_SIZE7 <basefont SIZE="7">
BFONT_white <basefont color="#ffffff">
BFONT_LGRAY <basefont color="#aaaaaa">
BFONT_GRAY <basefont color="#888888">
BFONT_DGRAY <basefont color="#444444">
BFONT_BLACK <basefont color="#000011">
BFONT_LRED <basefont color="#ff0000">
BFONT_RED <basefont color="#880000">
Bfont_DRED <basefont color="#440000">
BFONT_LGREEN <basefont color="#00ff00">
BFONT_GREEN <basefont color="#008800">
BFONT_DGREEN <basefont color="#004400">
BFONT_LBLUE <basefont color="#0000ff">
BFONT_BLUE <basefont color="#000088">
BFONT_DBLUE <basefont color="#000044">
BFONT_LYELLOW <basefont color="#ffff88">
BFONT_YELLOW <basefont color="#ffff00">
BFONT_DYELLOW <basefont color="#888800">
BFONT_LPURPLE <basefont color="#ff88ff">
BFONT_PURPLE <basefont color="#ff00ff">
BFONT_DPURPLE <basefont color="#880088">
BFONT_LCYAN <basefont color="#88ffff">
BFONT_CYAN <basefont color="#00ffff">
BFONT_DCYAN <basefont color="#008888">
BFONT <BASEFONT
BFONTE </BASEFONT>

DIV_RIGHT <div align="right">
DIV_LEFT <div align="left">
DIV_END </DIV> 
CENTER <CENTER>
CENTERE </CENTER>
BR <BR>
BRE </BR>

L1 <
R1 >

B <B>
BE </B>
BIG <BIG>
BIGE </BIG>
SMALL <SMALL>
SMALLE </SMALL>
EM <EM>
EME </EM>
U <U>
UE </U>
H1 <H1>
H1E </H1>
H2 <H2>
H2E </H2>
H3 <H3>
H3E </H3>
H4 <H4>
H4E </H4>
H5 <H5>
H5E </H5>
H6 <H6>
H6E </H6>
A <a
AE </a>

[EOF]