Hesabına erişemeyen eski üyeler Discord üzerinden yardım alabilir.

[itemdef i_deed_otot]
id=i_deed
weight=0
name=
type=t_script

on=@Create
attr 010
color 0514

on=@Click
message @045 [Lutfen Dikkat]
message @1153,,1 <name>
return 1

on=@Dclick
src.sys_trk Deede tek tıklayabilirsiniz.
return 1

[ITEMDEF i_aile_belgesi]
id=i_deed
type=t_script
name=Aile Kurulum Belgesi
value=375000

on=@create
color 054a
attr 04

On=@Click
message @0722,,1 <name>
return 1

on=@dclick
IF (<topobj.uid> != <src.uid>)
src.sysh_trk Hata: Bunu kullanabilmeniz için çantanızda olmalıdır.
return 1
elseif (<src.tag0.ailem>)
src.sysh_trk Hata: Sizin zaten bir aileniz var.
return 1
endif
src.dialogclose d_ailekur
src.dialog d_ailekur
return 1

[DIALOG d_ailekur]
250,70
resizepic 0 0 9300 391 240
resizepic 12 12 9300 370 217
dtext 80 20 1153 Ailenizin soyadı ne olsun ?

resizepic 60 54 9300 200 25
dtextentry 62 58 195 35 600 1 - - -
dtext 20 80 455 Aile en az 6 en fazla 14 karakterden
dtext 20 100 455 oluşabilir. Sadece harf kullanabilirsiniz.
dtext 20 120 455 Kurulumunda türkçe karakter kullanamazsınız.
dtext 20 140 455 Sistemde boşluk çalışmamaktadır sadece ' ve $
dtext 20 160 455 sembolünü kullanabilirsiniz.
dtext 45 198 045 Aileyi Kur
dtext 185 198 045 Kurulumu Iptal Et
button 20 200 0151a 01519 1 0 1
button 330 200 0151a 01519 1 0 2


[DIALOG d_ailekur button]
on 1
if (strlen(<argtxt[1]>) > 14) || (strlen(<argtxt[1]>) < 2)
src.sysh_trk Hata: Soyadınız en az 2, en fazla 14 karakter olabilir.
return 1
elseif (<badchar <argtxt[1]>>)
src.sysh_trk Hata: Soyadınızda sadece harf, $ ve ' sembolleri bulunabilir.
return 1
elseif !(<src.findid.i_aile_belgesi>)
src.sysh_trk Hata: Çantanızda bir aile belgesi bulunmamaktadır.
return 1
endif

local.argtxt <argtxt[1]>
for 15
if (strmatch('<strsub <eval <local._for>> 1 <local.argtxt>>',' '))
src.sysh_trk Boşluk kullanamazsınız.
return 1
elseif (<isnum <strsub <eval <local._for>> 1 <local.argtxt>>>)
src.sysh_trk Rakam kullanamazsınız.
return 1
endif
endfor
if (<src.tag0.ailem>)
src.sysh_trk Hata: Sizin zaten bir aileniz var.
return 1
endif
forplayers 99999
obj <uid>
if (<obj.tag0.ailem>)
ref1 <obj.tag.ailem>
if (strmatch('<ref1.tag.aileisim>','<local.argtxt>'))
src.sysh_trk <local.argtxt> adında bir aile zaten mevcut.
return 1
endif
endif
endfor

serv.newitem i_aile_hafiza
new.equip
new.tag.aileisim <local.argtxt>
src.tag.ailem <new.uid>
src.tag.asilisim <src.name>
src.name <src.name> <local.argtxt>
new.tag.reis <src.uid>
new.tag0.uyesayisi += 1
new.tag0.uye<dnew.tag0.uyesayisi> <src.uid>
src.sys_trk Ailenizi başarıyla kurdunuz. .aile komutu ile işlemler yapabilirsiniz.
src.s Aile kuruldu deedi her zamanki yere fıraltıldı. =p
serv.newitem i_deed_oto
new.name Aile ismi: <local.argtxt> || Eğer aile isminde sorun varsa .aileboz ile deedi seçiniz.
new.color 07b2
new.p 52<R57,65>,17<R69,59>
new.link <src.uid>
new.tag.aileuid <src.tag.ailem>
src.consume 1 i_aile_belgesi
return 1

on 2
src.sys_trk İşlem iptal edildi.
return 1

[Plevel 1]
aile

[function aile]
if !(<src.ispin>)
src.pin
return 1
endif
if !(<src.tag0.ailem>)
src.sysh_trk Hata: Sizin bir aileniz yok.
return 1
endif
src.dialogclose d_aile_islem
src.dialog d_aile_islem
return 1


[DIALOG d_aile_islem]
250,70
resizepic 0 0 9300 321 260
resizepic 12 12 9300 300 237
obj <src.tag.ailem>
dtext 80 20 1153 Aile Menüsü
dtext 70 60 455 Statünüz: <qval (<obj.tag.reis> == <src.uid>)?Kurucu:Üye>
dtext 20 90 099 Aile İsmi: <obj.tag.aileisim>

dtext 45 160 045 Üye listesi
button 20 160 0151a 01519 1 0 1
if (<obj.tag.reis> == <src.uid>)
dtext 45 190 045 Aileye üye al
dtext 45 220 045 Aileyi yık
button 20 190 0151a 01519 1 0 2
button 20 220 0151a 01519 1 0 3
else
dtext 45 200 045 Aileden ayrıl
button 20 200 0151a 01519 1 0 4
endif

[DIALOG d_aile_islem button]
onbutton=1
obj <src.tag.ailem>
if (<obj.tag0.uyesayisi>)
src.ctag.asayfa 1
src.dialogclose d_aileuyelist
src.dialog d_aileuyelist
return 1
endif
src.sysh_Trk Hata: Ailenizde üye bulunmamaktadır.
return 1

onbutton=2
obj <src.tag.ailem>
src.targetf f_uyeal
src.sys_trk Aileye almak istediğiniz kişiyi seçiniz.
return 1

onbutton=3
obj <src.tag.ailem>
ref1 <src.tag.ailem>
for <ref1.tag.uyesayisi>
obj <ref1.tag.uye<dlocal._for>>
obj.tag.ailem
obj.name <obj.tag.asilisim>
obj.tag.asilisim
obj.sys_trk <ref1.tag.aileisim> ailesi yıkılmıştır.
endfor
serv.allclients sysmessage @07d4,,1 <ref1.tag.aileisim> isimli aile yıkılmıştır.
ref1.remove
return 1

onbutton=4
obj <src.tag.ailem>
if !(<src.tag0.ailem> == <obj>)
src.sysh_trk Siz zaten bu ailede değilsiniz.
return 1
elif <src.findid.i_rune_incognito>
src.sys_trk Isminizi gizlemiş halde bir aileden ayrılamazsınız.
return 1
endif
for 1 <obj.tag.uyesayisi>
if (<obj.tag0.uye<dlocal._for>> == <src.uid>)
local.kacinciuye <dlocal._for>
endif
endfor
for <dlocal.kacinciuye> <obj.tag.uyesayisi>
if !(<dlocal._for> == <obj.tag.uyesayisi>)
obj.tag.uye<dlocal._for> <obj.tag.uye<eval <dlocal._for>+1>>
endif
endfor
try uid.<obj.tag.reis>.sys_trk <src.name> isimli oyuncu ailenizden ayrıldı.
src.sys_trk <obj.tag.aileisim> isimli aileden ayrıldınız.
obj.tag.uyesayisi -= 1
src.tag.ailem
src.name <src.tag.asilisim>
src.tag.asilisim
return 1

[function f_uyeal]
obj <argo>
ref1 <src.tag.ailem>
if (<obj.tag0.ailem>)
src.sysh_trk Bu kişi zaten bir aileye sahip.
return 1
elif !(<src.isplayer>)
src.sysh_trk Sadece playerleri ailenize dahil edebilirsiniz.
return 1
elif (<obj.findid.i_rune_incognito>)
obj.sys_trk Isminizi gizlemiş halde bir aileye dahil olamazsiniz.
return 1
endif
src.sys_trk <obj.name> isimli kişiye teklifiniz iletildi.
TRYSRC <obj.uid> dialogclose d_aile_teklif
TRYSRC <obj.uid> dialog d_aile_teklif
return 1

[DIALOG d_aile_teklif]
250,70
page 0
resizepic 0 0 9300 396 230
resizepic 12 12 9300 375 207
dtext 60 20 045 <obj.tag0.aileisim> isimli aileden davetiniz var!
dtext 20 40 1153 <name> sizi ailesine davet ediyor..
dtext 20 60 1153 Daveti kabul etmek istiyormusunuz?
dtext 30 110 099 Aileye katılım ücretsizdir
dtext 315 187 045 Evet
dtext 50 187 045 Hayır
button 350 190 0151a 01519 1 0 1
button 30 190 0151a 01519 1 0 2

[dialog d_aile_teklif button]
on 1
if (<src.tag0.ailem>)
src.sysh_trk Sizin zaten bir aileniz var.
sysh_trk <src.name> isimli kişinin zaten bir ailesi var.
return 1
elif <src.findid.i_rune_incognito>
src.sys_trk Isminizi gizlemiş halde bir aileye dahil olamazsınız.
return 1
endif
src.tag.ailem <tag.ailem>
ref1 <src.tag.ailem>
src.tag.asilisim <src.name>
src.name <src.name> <ref1.tag.aileisim>
ref1.tag0.uyesayisi += 1
ref1.tag0.uye<dref1.tag0.uyesayisi> <src.uid>
src.sys_trk Tebrikler.<ref1.tag.aileisim> isimli aileye üye oldunuz.
return 1

on 2
sysh_trk <src.name> teklifinizi kabul etmedi.
return 1


[dialog d_aileuyelist]
250,70
resizepic 0 0 9300 591 670
resizepic 12 12 9300 570 647
ref1 <src.tag.ailem>
dtext 40 20 1153 Aile İsmi: <ref1.tag.aileisim>
dtext 80 50 1153 Ailedeki Kişi Sayısı: <dref1.tag0.uyesayisi>
dtext 345 20 <eval 800> Sayfa: <dsrc.ctag.asayfa>

dtext 50 101 045 İsim
Dtext 250 100 099 Bulunduğu Yer

if !(<dsrc.ctag0.asayfa> == 1)
button 165 600 0151a 01519 1 0 112
endif
local.az <dref1.tag0.uyesayisi>
local.a <eval <dsrc.ctag.asayfa>*11>
if (<dlocal.az> > <dlocal.a>)
button 200 600 0151a 01519 1 0 111
local.te 1
endif

local.awe <eval <dsrc.ctag.asayfa> -1>
local.awe <eval <dlocal.awe>*11>
local.abc <eval <dlocal.az> - <dlocal.awe>>
local.satir 140

for <eval <qval (<dlocal.te> == 1)?11:<dlocal.abc>>>
local.aa <eval <dsrc.ctag0.asayfa> -1>
local.aa <eval <dlocal.aa>*11>
local.aa +=<dlocal._for>
obj=<dref1.tag0.uye<dlocal.aa>>
if !(<obj> == 00)
dtext 330 <eval <dlocal.satir>+1> <qval (<obj.isonline>)?<qval (<obj.region.guarded> == 1)?<eval 084a> <obj.region.name>:025 <obj.region.name>>:025 Offline>
dtext 60 <eval <dlocal.satir>+1> <qval (<obj.isonline> == 1)?050 <obj.name>:045 <obj.name>><qval (<ref1.tag0.reis> == <obj.uid>)?[Aile Reisi]>
button 20 <dlocal.satir> 0151a 01519 1 0 <dlocal._for>
local.satir +=40
endif
endfor


[dialog d_aileuyelist button]
on 111
src.dialogclose d_aileuyelist
src.ctag.asayfa +=1
src.sdialog d_aileuyelist

on 112
src.dialogclose d_aileuyelist
src.ctag.asayfa -=1
src.sdialog d_aileuyelist

on=1 11
local.aa <eval <dsrc.ctag.asayfa> -1>
local.aa <dlocal.aa>*11
local.aa +=<eval <argn>>
src.ctag0.hangiuye <dlocal.aa>
src.dialogclose d_aileuyelist_2
src.dialog d_aileuyelist_2

[dialog d_aileuyelist_2]
250,70
ref1=<src.tag.ailem>
obj=<dref1.tag0.uye<dsrc.ctag.hangiuye>>
resizepic 0 0 9300 421 470
resizepic 12 12 9300 400 447
if <obj.isplayer>
dtext 20 20 1153 <obj.name> Hakkındaki bilgiler;
dtext 20 60 045 Str/Hits: <obj.str>/<obj.hits>
dtext 20 80 045 Dex/Stam: <obj.dex>/<obj.stam>
dtext 20 100 045 İnt/Mana: <obj.int>/<obj.mana>
dtext 20 120 045 Toplamskill: <fval <obj.skilltotal>>
dtext 20 140 045 Fame/Karma/Kill: <obj.fame> / <obj.karma> / <obj.kills>
dtext 20 160 045 Ölüm sayısı: <obj.deaths>
dtext 20 180 045 Online Süre: <eval <obj.ACCOUNT.TOTALCONNECTTIME>/60> Saat
dtext 20 200 045 Kayıt Tarihi: <obj.ACCOUNT.FIRSTCONNECTDATE>
dtext 20 220 045 Son Online Tarihi: <obj.ACCOUNT.LASTCONNECTDATE>
dtext 20 250 045 Accountundaki karakterler;
local.satir 270
for 0 <eval <obj.account.chars>-1>
dtext 20 <dlocal.satir> 0455 <eval <dlocal._for>+1>-) <obj.account.char.<dlocal._for>.name>
local.satir +=20
endfor
endif

if (<ref1.tag.reis> == <src.uid>)
dtext 40 430 0455 Üyeyi aileden at
button 20 430 0151a 01519 1 0 1
endif


[dialog d_aileuyelist_2 button]
on 1
ref1=<src.tag.ailem>
if !(<obj.tag0.ailem> == <src.tag0.ailem>)
src.sysh_trk Bu kişi sizin ailenizde değil.
return 1
elseif (<ref1.tag.reis> == <obj.uid>)
src.sysh_trk Kendi kendinizi aileden atamazsınız.
return 1
endif

for <dsrc.ctag.hangiuye> <ref1.tag.uyesayisi>
if !(<dlocal._for> == <ref1.tag.uyesayisi>)
ref1.tag.uye<dlocal._for> <ref1.tag.uye<eval <dlocal._for>+1>>
endif
endfor
obj.tag.ailem
obj.name <obj.tag.asilisim>
obj.tag.asilisim
obj.sys_trk <ref1.tag.aileisim> ailesinden atıldınız.
src.sys_trk <obj.name> isimli kişiyi aileden atıldı.
ref1.tag.uyesayisi -= 1
return 1


[itemdef i_aile_hafiza]
name Aile hafiza
id i_memory
weight 0
type t_eq_script
layer layer_special

ON=@Create
ATTR=attr_invis|attr_decay

ON=@Equip
timer -1

ON=@timer
timer -1
return 1


[FUNCTION badchar]
if !(<EVAL STRLEN(<ARGS>)>) || (STRMATCH("*[[]*","<ARGS>")) || (STRMATCH("*]*","<ARGS>")) || (STRMATCH("*[(]*","<ARGS>")) || (STRMATCH("*-*","<ARGS>")) || (STRMATCH("*[*}`>?´;:^%¨!"<#.@_~|=+ğ&/æ{]*","<ARGS>"))
RETURN 1
ELSE
RETURN 0
ENDIF


[Plevel 5]
aileboz

[FUNCTION aileboz]
if (<src.account.plevel> < 5)
src.sysh_trk Hata: Buna yetkin yok.
return 1
endif
src.dialogclose d_aileboz_sorgu
src.dialog d_aileboz_sorgu
return 1


[DIALOG d_aileboz_sorgu]
250,70
page 0
resizepic 0 0 9300 601 170
resizepic 12 12 9300 580 147
dtext 20 20 1153 Yıkılan aileyi kuran kişiye deed tekrar iade edilsin mi?
dtext 20 100 045 Not: Kişi ikinci kez aile isim kurallarına uymuyorsa deedi iade etmeyin.
dtext 20 120 045 eğer ilk defa olduğunu düşünüyorsanız deedi iade edin.Küfür varsada iade etmeyin.
dtext 45 70 045 Evet
dtext 165 70 045 Hayır
button 20 70 0151a 01519 1 0 1
button 140 70 0151a 01519 1 0 2

[dialog d_aileboz_sorgu button]
on 1
src.targetf f_aileboz 2
src.sys_trk Yıkılmasını istediğiniz aileyi seçiniz.

on 2
src.targetf f_aileboz 1
src.sys_trk Yıkılmasını istediğiniz aileyi seçiniz.


[FUNCTION f_aileboz]
if !(<argo.tag0.aileuid>)
src.sysh_trk Sadece ailenin deedine bunu yapabilirsiniz.
return 1
endif
obj <argo.link>
ref1 <argo.tag.aileuid>
if (<ref1.topobj.uid> != <obj.uid>)
src.sysh_trk Bu aile yıkılmış.
argo.remove
return 1
endif
if (<dargs> == 2)
serv.newitem i_aile_belgesi
new.cont <obj.findlayer.21>
obj.sys_trk Aile kurulum belgeniz çantanızdadır.Ailenizin ismini kurallara uygun şekilde giriniz.
endif
for <ref1.tag.uyesayisi>
obj <ref1.tag.uye<dlocal._for>>
obj.tag.ailem
obj.name <obj.tag.asilisim>
obj.tag.asilisim
obj.sysh_trk <ref1.tag.aileisim> ailesinin ismi <src.name> isimli staff tarafından hatalı bulunmuş, aile yıkılmıştır.
endfor
serv.allclients sysmessage @07d4,,1 <ref1.tag.aileisim> ailesinin ismi <src.name> isimli staff tarafından hatalı bulunmuş, aile yıkılmıştır.
serv.writefile C:\Sphere\scripts\Staff\<src.account>.txt Yıkılan aile: <ref1.tag.aileisim>
serv.writefile C:\Sphere\scripts\Staff\<src.account>.txt Tarih: <serv.rtime>    Deed geri <qval (<dargs> == 2)?verildi:verilmedi>.
serv.writefile C:\Sphere\scripts\Staff\<src.account>.txt ---------------------------------------------------------------------------
ref1.remove
argo.remove
return 1

[chardef c_aile_memuru]
id c_man
armor 60
dam 80,90
CATEGORY=Monsters
SUBSECTION=Miscellaneous
DESCRIPTION=Aile

on=@click
message @38,,1 [Aile Memuru]

on=@dclick
IF ( <DISTANCE> < 4 )
SRC.SFX 555
sDIALOG d_ailedeedsatisi
ELSE
SRC.sysmessage @38,,1 Uzaksin!
ENDIF
RETURN 1

on=@create
color 01
str 450
maxhits 1600
dex 400
int 500

itemnewbie i_baslangic_robee
attr 010
color 07a1
itemnewbie i_staff_black
attr 010
color 01

[dialog d_ailedeedsatisi]
50,100
nomove

resizepic 50 30 9300 400 100
resizepic 60 40 9300 380 80

resizepic 80 65 3000 340 30 //
button 100 69 4006 4005 1 0 1
dtext 138 70 049  Aile Deed (25000 Silver Pieces)
tilepic 376 65 <serv.itemdef.i_deed.id>


[dialog d_ailedeedsatisi button]
onbutton=1
if <src.restest 25000 i_bilet>
src.consume 25000 i_bilet
src.newitem i_aile_belgesi
src.act.bounce
return 1
else
src.sysmessage @38,,1 Aile Deed alabilmek icin cantanizda 25000 Silver Pieces olmalidir.
return 1
endif

[dialog d_isimdegistir1]
0,0
resizepic 200 175 9300 310 120
resizepic 210 185 9300 290 100

dhtmlgump 290 195 150 20 0 0 Yeni isim sistemi
dhtmlgump 445 247 300 20 0 0 Tamam
dhtmlgump 225 220 70 20 0 0 Yeni ismim:
dtextentry 300 220 330 35 1152 1 Isminiz buraya..
button 410 245 0151a 01519 1 0 1

[dialog d_isimdegistir1 button]
on 1
if (strmatch('<argtxt[1]>',''))
src.sys_trk Lutfen bir isim giriniz
return 1
endif

for 0 <eval strlen(<argtxt[1]>) -1>
if !strmatch('[a-z]','<strsub <eval <local._for>> 1 <argtxt[1]>>')
src.sys_trk Hatali kullanim.
src.sdialog d_isimdegistir1
return 1
endif
endfor

obj=<uid>
forplayers 6144
if (<obj.uid> != <uid>)
if (strmatch('<obj.name>', '<argtxt[1]>'))
src.dialog d_isimdegistirme
src.sys_trk Bu isimden sunucuda bulunmaktadir.
return 1
endif
endif
endfor

if ((strlen(<argtxt[1]>) > 10) || (strlen(<argtxt[1]>) < 4))
src.dialog d_isimdegistirme
src.sys_trk Isminiz az 4, en fazla 8 karakter olmalidir.
return 1
endif


local.argtxt <argtxt[1]>
for 15
if (strmatch('<strsub <eval <local._for>> 1 <local.argtxt>>',' '))
src.sysh_trk Boşluk kullanamazsınız.
return 1
elseif (<isnum <strsub <eval <local._for>> 1 <local.argtxt>>>)
src.sysh_trk Rakam kullanamazsınız.
return 1
endif
endfor

if !(<src.tag0.ailem>)
src.name <argtxt[1]>
src.tag.isim 1
src.isimdegistir
src.sysmessage @040,1,1 Isminiz <argtxt[1]> olarak degiştirilmiştir.
src.tag.aileisim 1
src.tag.aileisimdegisti 1
return 1
else
src.name <argtxt[1]> <tag.aileisim>
src.tag.isim 1
src.isimdegistir
src.sysmessage @040,1,1 Isminiz <argtxt[1]> <tag.aileisim> olarak degiştirilmiştir.
src.tag.aileisim 1
src.tag.aileisimdegisti 1
return 1
.aile'den üye listesi deyince kimseyi göstermiyor ve sphere şu hatayı veriyor:
22:00:ERROR:(aile.scp,284)Undefined keyword 'ref1'
22:00:ERROR:(aile.scp,285)Can't resolve <ref1.tag.aileisim>
22:00:ERROR:(aile.scp,286)Can't resolve <dref1.tag0.uyesayisi>
22:00:ERROR:(aile.scp,295)Can't resolve <dref1.tag0.uyesayisi>
22:00:ERROR:(aile.scp,311)Can't resolve <dref1.tag0.uye01>
22:00:ERROR:(aile.scp,311)Can't resolve <dref1.tag0.uye00>

.aile'den üye al button'una tıklayınca seçtiğim kişiye aile teklifi gitmiyor ama 0 isimli kişiye teklif yapıldı diyor spheredeki hata:
22:02:ERROR:(aile.scp,225)Can't resolve <argo>
22:02:ERROR:(aile.scp,226)Undefined keyword 'ref1'
22:02:ERROR:(aile.scp,237)Undefined keyword 'sys_trk'
22:02:ERROR:(aile.scp,237)Undefined keyword 'sys_trk'
22:02:ERROR:(aile.scp,238)Can't trysrc dialogclose d_aile_teklif object asdasda asd (0101f): invalid src uid 00
22:02:ERROR:(aile.scp,239)Can't trysrc dialog d_aile_teklif object asdasda asd (0101f): invalid src uid 00
Ve tekrar .aile'den Aileyi tık dediğimde aile tıkılmıyor spheredeki hata
22:03:ERROR:(aile.scp,185)Undefined keyword 'ref1'
22:03:ERROR:(aile.scp,186)Can't resolve <ref1.tag.uyesayisi>
22:03:ERROR:(aile.scp,187)Can't resolve <ref1.tag.uye01>
22:03:ERROR:(aile.scp,191)Can't resolve <ref1.tag.aileisim>
22:03:ERROR:(aile.scp,193)Can't resolve <ref1.tag.aileisim>
22:03:ERROR:(aile.scp,194)Undefined keyword 'ref1.remove'

Bir iki kişi çözüm yolu sundu ama onlardada aynı hatayı alıyorum
sorun sphereden olabilirmi

Şimdiden Teşekkür ederim ;)
Master
59.2997
ref1 görmediğine göre büyük ihtimalle eski bir release kullanıyorsun. güncel bir sürüm indirmelisin.
Sitedeki February Sürümü güncelleştirdim. Son sürümü bu değil mi ?
www.sphereserver.net (Y)
September 20 2009, 20:24 Son sürüm bu olması lazım dimi ?

Bunu güncenleştirdim aynı hataları veriyor ?

Bu konu OwNeR_ThreaT tarafından düzenlendi(2010-08-26 00:29, 13 yıl önce)

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.