[comment binekspawnsys]
defnamelerden gerekli ayarlamaları yapabilirsiniz.
[defname binekspawnzamanlari] // saniye cinsinde
spawn_c_horse_tan 3600
spawn_c_horse_brown_dk 3600
spawn_c_horse_gray 3600
spawn_c_horse_brown_lt 3600
spawn_c_colour_llama 10800
spawn_c_colour_desert 14400
spawn_c_colour_forest 14400
spawn_c_colour_frenzied 18000
spawn_c_polar_bear 518400
//spawn_c_colour_mustang 86400
spawn_c_swamp_dragon 86400
spawn_c_armored_swamp_dragon 86400
spawn_c_giant_beetle 86400
spawn_c_ridgeback 86400
spawn_c_savage_ridgeback 86400
spawn_c_skeletal_mount 259200
spawn_c_steed_silver 86400
spawn_c_m_nightmare 518400
spawn_c_m_unicorn 518400
spawn_c_m_hiryu 518400
spawn_c_cu_sidhe 518400
spawn_c_m_armor_steed 86400
spawn_c_m_reptalon 518400
spawn_c_kirin 259200
[defname binekspawnadetleri]
spawna_c_horse_tan 5
spawna_c_horse_brown_dk 5
spawna_c_horse_gray 5
spawna_c_horse_brown_lt 5
spawna_c_colour_llama 8
spawna_c_colour_desert 6
spawna_c_colour_forest 8
spawna_c_colour_frenzied 2
spawna_c_polar_bear 1
//spawna_c_colour_mustang 5
spawna_c_swamp_dragon 2
spawna_c_armored_swamp_dragon 2
spawna_c_giant_beetle 2
spawna_c_ridgeback 2
spawna_c_savage_ridgeback 2
spawna_c_skeletal_mount 1
spawna_c_steed_silver 1
spawna_c_m_nightmare 1
spawna_c_m_unicorn 1
spawna_c_m_hiryu 1
spawna_c_cu_sidhe 1
spawna_c_m_armor_steed 1
spawna_c_m_reptalon 1
spawna_c_kirin 1
[function bineksyskur]
db.connect
db.execute "create table binek_spawn (id int unsigned not null auto_increment primary key,tarih datetime not null,binekismi varchar(20),binekid text,binekuid text,spawndurum text,spawnyeri text,tameleyen text,food int);"
[function f_binekkoy]
local.x <R7168>
local.y <R4096>
if <serv.map(<eval <local.x>>,<eval <local.y>>).type> == t_grass
if (<serv.map(<eval <local.x>>,<eval <local.y>>).region.flags>&04000) || (<serv.map(<eval <local.x>>,<eval <local.y>>).region.flags>&02000)
f_binekkoy <argv[0]>
else
if !strmatch('*britain*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>') && !strmatch('*Serpen*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>') && !strmatch('*occlo*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>') && !strmatch('*felucca*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>') && !strmatch('*dungeons*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>') && !strmatch('*moonglow*','<serv.map(<eval <local.x>>,<eval <local.y>>).region.name>')
serv.newnpc <argv[0]>
new.p <eval <local.x>>,<eval <local.y>>
new.fix
new.events +e_binek_spawn
new.food 20
new.update
db.connect
db.execute "insert into binek_spawn values (NULL, NOW(), '<addslashes <new.name>>', '<new.id>', '<new.uid>', '1', '<addslashes <serv.map(<eval <local.x>>,<eval <local.y>>).region.name>>', 0, '<new.food>');"
else
f_binekkoy <argv[0]>
endif
endif
else
f_binekkoy <argv[0]>
endif
[events e_binek_spawn]
on @death
db.connect
db.execute "update binek_spawn set spawndurum='3' where binekuid='<uid>'"
try uid.078ae8.tag.time <def.spawn_<src.id>>
try uid.078ae8.tag.id <src.id>
try uid.078ae8.f_spawnla
return 0
on @environchange
if <eval <food>> == 0
suicide
else
db.connect
db.execute "update binek_spawn set spawnyeri='<addslashes <region.name>>' where binekuid='<uid>'"
db.execute "update binek_spawn set food='<food>' where binekuid='<uid>'"
endif
[function f_spawnla]
db.connect
db.query "select * from binek_spawn where binekid='<argn1>' and spawndurum='1'";
if <db.row.numrows> < <def.spawna_<tag.id>>
timerf <tag.time>,f_binekkoy <tag.id>
else
return 1
endif
[function spawn_yonetim]
if <isempty <src.ctag.bineksirala>>
src.ctag.bineksirala binekismi
endif
src.ctag.binekgrup=where spawndurum = '1'
src.ctag.dialogindex 0
src.sdialog d_spawn_yonetim
return 1
[dialog d_spawn_yonetim]
0, 0
nomove
page 0
resizepic 550 90 3500 170 300
resizepic 0 0 3500 600 480
dtext 600 133 015D Sırala:
button 620 162 2117 2118 1 0 5
dtext 640 160 0 Binek
button 620 182 2117 2118 1 0 6
dtext 640 180 0 Food
button 620 202 2117 2118 1 0 7
dtext 640 200 0 Durum
dtext 600 230 015D Türüne Göre:
button 620 262 2117 2118 1 0 9
dtext 640 260 0 Tamelendi
button 620 282 2117 2118 1 0 10
dtext 640 280 0 Geziyor
button 620 302 2117 2118 1 0 11
dtext 640 300 0 Öldü
dtext 30 15 0A3 <serv.name> - Binek Spawn Yönetim Paneli
dtext 40 40 015D Tarih
dtext 200 40 015D Binek
dtext 450 40 015D Durum
dtext 500 40 015D Food
dtext 300 40 015D Yer
db.connect
db.query "select * from binek_spawn <ctag.binekgrup> order by <ctag.bineksirala> limit <eval <ctag.dialogindex>>,<eval <ctag.dialogindex>+18>";
for index 0 18
if <db.row.<dlocal.index>.binekuid>
local.y=((<dlocal.index>*20)+65)
button 20 <eval <dlocal.y>+2> 2117 2118 1 0 <eval (<db.row.<dlocal.index>.id>+20)>
dtext 40 <dlocal.y> 0 <db.row.<dlocal.index>.tarih>
dhtmlgump 200 <dlocal.y> 205 20 0 0 <addslashes <db.row.<dlocal.index>.binekismi>>
dtext 450 <dlocal.y> 0 <db.row.<dlocal.index>.spawndurum>
dtext 500 <dlocal.y> 0 <db.row.<dlocal.index>.food>
dtext 300 <dlocal.y> 0 <addslashes <db.row.<dlocal.index>.spawnyeri>>
endif
endfor
button 60 443 9909 9911 1 0 1
button 130 443 9903 9905 1 0 2
dtext 25 443 011D Geri
dtext 165 443 011D İleri
[dialog d_spawn_yonetim button]
on=0
ctag.dialogindex=0
ctag.bineksirala
return 1
on=1 //önceki sayfa
if <ctag.dialogindex> > 0
ctag.dialogindex -=18
endif
sdialog d_spawn_yonetim
return 1
on=2 //sonraki sayfa
ctag.dialogindex +=18
sdialog d_spawn_yonetim
return 1
on=3
return 1
on=5
ctag.bineksirala=binekismi
sdialog d_spawn_yonetim
return 1
on=6
ctag.bineksirala=food
sdialog d_spawn_yonetim
return 1
on=7
ctag.bineksirala=spawndurum
sdialog d_spawn_yonetim
return 1
on=9
ctag.binekgrup=where spawndurum = '2'
sdialog d_spawn_yonetim
return 1
on=10
ctag.binekgrup=where spawndurum = '1'
sdialog d_spawn_yonetim
return 1
on=11
ctag.binekgrup=where spawndurum = '3'
sdialog d_spawn_yonetim
return 1
on=4 9999
ctag.binekid=<eval (<argn1>-20)>
ctag.dialogindex=0
db.connect
db.query "select * from binek_spawn where id='<eval <ctag.binekid>>' limit 1"
gouid <db.row.0.binekuid>
return 1