Hesabına erişemeyen eski üyeler Discord üzerinden yardım alabilir.
Evet arkadaşlar ne kadar ph açsamda skill gelmiyor sizce sorun nerden olabilir sphere 56b versiyonu kullanıyorum...
healing ve taming hardcoded olarak işlem yapmaz tamingin phı taming staff scriptinden ayarlanıyo. healingide bandajların scriptinden.

şöyle ayarlıyabilirsin biyere

if <R10>==1 //10da 1 demek %100 açıcaksan hiç bu ayarı yapma
src.skillgain (skillin numarası) 1 // bu numarayı sphere_skills den bulabilirsin. skill 1 2 gibi yazar.
endif
Aynen senin dediğin gibi ayarlı , bende zaten scripte hata yok normal şartlarda ancak 100 tanede bandaj atsam skill gelmiyor :S
Bandaj scriptini koyarmısın bir gözden geçireyim ?
[ITEMDEF 0e21]
DEFNAME=i_bandage 
RESOURCES=i_cloth 
TYPE=T_BANDAGE 
WEIGHT=0.2 
DUPELIST=0ee9 
CATEGORY=Items by Professions 
SUBSECTION=Healer 
DESCRIPTION=clean bandages 

On=@DClick
if !(<topobj.uid> == <src.uid>)
	src.sysmessage @037 Bandajlar cantanizda olmali.
	return 1
elseif (<src.findid.i_mem_healing.timer> < 0)
	src.findid.i_mem_healing.remove
	return 0
elseif (<src.findid.i_mem_healing>)
	src.sysmessage @037 Bandajlari su an kullanamazsiniz.
	return 1
else
	return 0
endif

On=@Targon_Char
src.skill fail
if !(<src.restest 1 i_bandage>)
	src.sysmessage @037 Bandajiniz yok.
	return 1
elseif (<src.targ.distance> > 3) || !(<src.targ.canseelos>)
	src.sysmessage @037 Hedefe ulasamiyorsunuz.
	return 1
elseif (<src.targ.npc> == 10) ||(<src.targ.npc> == 11) || (<src.targ.npc> == 12) || (<src.targ.npc> == 13)
	src.sysmessage @037 Bunu iyilestiremezsiniz.
	return 1
elseif (<src.targ.NPC> == brain_animal) && (<src.targ.hits> == 0)
	src.sysmessage @037 Olu yaratiklari tedavi edemezisiniz...
	return 1
elseif !(<src.targ.region.uid> == <src.region.uid>)
	src.sysmessage @037 Suanda bu kisiye tedavi uyguliyamazsiniz
	return 1
elseif (<src.targ.npc> == 1)
	if (<src.targ.id> == c_m_golem_tinker1) || (<src.targ.id> == c_m_golem_tinker2) || (<src.targ.id> == c_m_golem)
		src.sysmessage @037 Golem'leri bandajla iyilestiremezsiniz.
	elseif !((<src.targ.hits> < <src.targ.str>) || (<src.targ.findid.i_rune_poison>))
		src.smg <src.targ.name> tedaviye ihtiyac duymuyor.
		return 1
	elseif (<src.targ.findid.i_rune_poison>)
		if ((<src.veterinary> < 60.0) || (<src.animallore> < 60.0))
			src.sysmessage @037 Hayvan uzerindeki zehiri tedavi edecek kadar yetenekli degilsiniz.
			return 1
		endif
	else
		local.nx1 (<src.veterinary> / {20 50})
		local.nx2 (<src.animallore> / 50)
		local.nx3 <eval (<local.nx1> + <local.nx2> + {3 10})>
	endif
	src.sd 1
	src.hb 1 	//bandaj buyu engel sd ile aynı olacak.
	src.anim 17
	src.newitem i_mem_healing
	src.act.morey <eval <local.nx3>>
	src.act.morex 3
	src.act.link <src.targ.uid>
	src.act.equip
	src.face
	return 1
elseif (<src.targ.flags>&statf_dead)
	if ((<src.healing> < 80.0) || (<src.anatomy> < 80.0))
		src.sysmessage Henuz oluleri diriltecek kudrete sahip degilsiniz.
	elseif (<src.targ.findid.i_resurrection_timer>)
		src.sysmessage @037 Zaten reslenmek uzere...
		return 1
	elseif (<src.targ.isevent.e_house>)
		src.sysmessage @037 Evde olan kisileri resleyemezsiniz!!
		return 1
	elseif (<src.targ.region.flags>&040)
		src.sysmessage @037 Gemide olan kisileri resleyemezsiniz!!
		return 1
	elseif !(<src.restest 5 i_bandage>)
		src.sysmessage @037 Diriltme islemi icin 5 bandaja ihtiyaciniz var.
	else
		if (<src.targ.kills> > 6)
			src.criminal 1
			src.sayua 048,6,6,0 * <src.targ.name> isimli katili diriltir *
		elseif (<src.targ.flags>&statf_criminal)
			src.criminal 1
			src.sayua 048,6,6,0 * <src.targ.name> isimli sucluyu diriltir *
		elseif (<src.memoryfindtype.memory_town>) && (<src.targ.memoryfindtype.memory_town>) && (<src.memoryfindtype.memory_town.link> != <src.targ.memoryfindtype.memory_town.link>)
			src.criminal 1
		elseif (<src.memoryfindtype.memory_guild.link.align>) && (<src.targ.memoryfindtype.memory_guild.link.align>) && (<src.memoryfindtype.memory_guild.link.align> != <src.targ.memoryfindtype.memory_guild.link.align>)
			src.criminal 1
		endif
		src.sd 2
		src.hb 2
		src.face
		src.anim 17
		src.consume 5 i_bandage
		src.targ.spelleffect s_resurrection 1000
		src.targ.sayua 048,6,6,0 * <src.name> sayesinde hayata doner *
		src.checkhealing 2
		src.checkanatomy 2
	endif
	return 1
elseif (<src.targ.memoryfindtype.memory_town>) && !(<src.memoryfindtype.memory_town>)
	if (<src.memoryfindtype.memory_guild>) && (<src.targ.memoryfindtype.memory_guild>) && (<src.memoryfindtype.memory_guild.link.align> == <src.targ.memoryfindtype.memory_guild.link.align>)
	else
	src.sysmessage @037 Faction uyelerini iyilestiremezsiniz.
	return 1
	endif
elseif (<src.targ.memoryfindtype.memory_guild.link.align> > 0) && !(<src.memoryfindtype.memory_guild.link.align>)
	src.sysmessage @037 Order/Chaos uyelerini iyilestiremezsiniz.
	return 1
elseif !((<src.targ.hits> < <src.targ.str>) || (<src.targ.findid.i_rune_poison>))
	if !(<src.targ.uid> == <src.uid>)
		src.sysmessage @037 <src.targ.name> tedaviye ihtiyac duymuyor.
	else
		src.sysmessage @037 Tedaviye ihtiyaciniz yok.
	endif
	return 1
elseif (<src.targ.findid.i_rune_poison>)
	if ((<src.healing> < 60.0) || (<src.anatomy> < 60.0))
		src.sysmessage @037 Zehiri tedavi edecek kadar yetenekli degilsiniz.
		return 1
	endif
elseif (<src.targ.findid.i_bleeding3>)         ///Bleeding
	if ((<src.healing> < 70.0) || (<src.anatomy> < 70.0))
		src.sysmessage @037 Yarayi tedavi edecek kadar yetenekli degilsiniz.
		return 1
	endif
else
	var.nx1 (<src.healing> / {20 50})
	var.nx2 (<src.anatomy> / 50)
	var.nx3 <eval (<var.nx1> + <var.nx2> + {3 10})>
endif

src.sd 2
src.hb 2
src.anim 17
src.newitem i_mem_healing
src.act.morey <eval <var.nx3>>
if !(<src.targ.uid> == <src.uid>) // heal other
	src.act.morex 1
	src.act.link <src.targ.uid>
	src.face
endif
src.act.equip
return 1

[itemdef i_mem_healing]
ID=i_memory
TYPE=t_eq_script
NAME=healing mem

On=@Create
attr attr_decay|attr_newbie

On=@Equip
src.events +e_healing
timer 4

On=@UnEquip
cont.events -e_healing

On=@Timer
if (<morey>)
	if (<morex> == 3) // veterinary
		if !(<link.hits> < <link.str>) && !(<link.findid.i_rune_poison>)
			cont.smg <link.name> tedaviye ihtiyac duymuyor.
			remove
			return 1
		elseif (<link.findid.i_rune_poison>)
			if (<cont.veterinary> < 60.0) || (<cont.animallore> < 60.0)
				cont.sysmessage @037 Zehiri tedavi edecek kadar yetenekli degilsiniz.
				remove
				return 1
			endif
		elseif (<link.findid.i_bleeding3>)       ///////Hayvanlarda bleeding
			if (<cont.veterinary> < 70.0) || (<cont.animallore> < 70.0)
				cont.sysmessage @037 Yarayi tedavi edecek kadar yetenekli degilsiniz.
				remove
				return 1
			endif
		elseif !(<cont.restest 1 i_bandage>)
			cont.sysmessage @037 Bandajiniz yok.
			remove
			return 1
		endif
		cont.consume 1 i_bandage
		if (<link.findid.i_rune_poison>) // cure animal
			if !(rand(5) == 1)
				link.findid.i_rune_poison.remove
				link.effect 3,0376a,2,10,1
				link.sayu * iyilestirilir *
			else
				cont.sayua 020,6,6,0 * <link.name> uzerindeki zehiri iyilestiremez *
			endif
		elseif (<link.findid.i_bleeding3>) //hayvanlarda yara iyilestirme poff :D
			if !(rand(4) == 1)
				link.findid.i_bleeding3.remove
				link.effect 3,0376a,2,10,1
				link.sayu * yarasi iyilestirilir *
			else
				cont.sayua 020,6,6,0 * <link.name> uzerindeki yarayi iyilestiremez *
			endif
		else // heal animal
			link.hits <eval (<link.hits> + <morey>)>
			link.effect 3,0376a,2,10,1
			if (<link.hits> > <link.str>)
				link.hits <link.str>
			endif
			link.sayu * tedavi gorur *
			link.update
		endif
		cont.checkveterinary
		cont.checkanimallore
		if (<cont.dex> < 35)
			timer 6
		else
			timer 4
		endif
	elseif (<morex>) // others
		if !(<link.hits> < <link.str>) && !(<link.findid.i_rune_poison>)
			cont.smg <link.name> tedaviye ihtiyac duymuyor.
			remove
			return 1
		elseif (<link.hits> < 1)
			cont.sysmessage @037 <link.name> tedavi esnasinda hayatini kaybetti.
			remove
			return 1
		elseif (<link.findid.i_rune_poison>)
			if (<cont.healing> < 60.0) || (<cont.anatomy> < 60.0)
				cont.sysmessage @037 Zehiri tedavi edecek kadar yetenekli degilsiniz.
				remove
				return 1
			endif
		elseif !(<cont.restest 1 i_bandage>)
			cont.sysmessage @037 Bandajiniz yok.
			remove
			return 1
		endif
		cont.consume 1 i_bandage
		if (<link.findid.i_rune_poison>) // cure other
			if !(rand(5) == 1)
				link.findid.i_rune_poison.remove
				link.effect 3,0376a,2,10,1
				if (<link.kills> > 6)
					cont.criminal 1
					cont.sayua 048,6,6,0 * <link.name> isimli katili iyilestirir *
				elseif (<link.flags>&statf_criminal)
					cont.criminal 1
					cont.sayua 048,6,6,0 * <link.name> isimli sucluyu iyilestirir *
				else
					link.sayua 048,6,6,0 * <cont.name> tarafindan iyilestirilir *
					if (<link.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town.link> != <link.memoryfindtype.memory_town.link>)
						cont.criminal 1
					elseif (<link.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align> != <link.memoryfindtype.memory_guild.link.align>)
						cont.criminal 1
					endif
				endif
			else
				cont.sayua 020,6,6,0 * <link.name> uzerindeki zehiri iyilestiremez *
			endif
		elseif (<link.findid.i_bleeding3>)///////////////////////////Bleeding 
			if !(rand(4) == 1)
				link.findid.i_bleeding3.remove
				link.effect 3,0376a,2,10,1
				if (<link.kills> > 5)
					cont.criminal 1
					cont.sayua 048,6,6,0 * <link.name> yarasini iyilestirir.*
				elseif (<link.flags>&statf_criminal)
					cont.criminal 1
					cont.sayua 048,6,6,0 * <link.name> isimli suclunun yarasini iyilestirir. *
				else
					link.sayua 048,6,6,0 * <cont.name> tarafindan yarasi iyilestirilir. *
					if (<link.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town.link> != <link.memoryfindtype.memory_town.link>)
						cont.criminal 1
					elseif (<link.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align> != <link.memoryfindtype.memory_guild.link.align>)
						cont.criminal 1
					endif
				endif
			else
				cont.sayua 020,6,6,0 * <link.name> uzerindeki yarayi tedavi edemez *
			endif        ////////////////////////////////////////////////////////////
		else // heal other
			link.hits (<link.hits> + <morey>)
			link.effect 3,0376a,2,10,1
			if (<link.hits> > <link.str>)
				link.hits <link.str>
			endif
			if (<link.kills> > 6)
				cont.criminal 1
				cont.sayua 048,6,6,0 * <link.name> isimli katili tedavi eder *
			elseif (<link.flags>&statf_criminal)
				cont.criminal 1
				cont.sayua 048,6,6,0 * <link.name> isimli sucluyu tedavi eder *
			else
				link.sayua 048,6,6,0 * <cont.name> tarafindan tedavi edilir *
				if (<link.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town>) && (<cont.memoryfindtype.memory_town.link> != <link.memoryfindtype.memory_town.link>)
					cont.criminal 1
				elseif (<link.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align>) && (<cont.memoryfindtype.memory_guild.link.align> != <link.memoryfindtype.memory_guild.link.align>)
					cont.criminal 1
				endif
			endif
		endif
		cont.checkhealing 1
		cont.checkanatomy 1
		if (<cont.dex> < 50)
			timer 10
		elseif (<cont.dex> < 60)
			timer 9
		elseif (<cont.dex> < 70)
			timer 8
		elseif (<cont.dex> < 80)
			timer 7
		else
			timer 6
		endif
	else
		if !(<cont.hits> < <cont.str>) && !(<cont.findid.i_rune_poison>)
			cont.smg Tedaviye ihtiyac duymuyorsunuz.
			remove
			return 1
		elseif (<cont.hits> < 1)
			remove
			return 1
		elseif (<cont.findid.i_rune_poison>)
			if (<cont.healing> < 60.0) || (<cont.anatomy> < 60.0)
				cont.sysmessage @037 Zehiri tedavi edecek kadar yetenekli degilsiniz.
				remove
				return 1
			endif 
   		elseif !(<cont.restest 1 i_bandage>)
			cont.sysmessage @037 Bandajiniz yok.
			remove
			return 1
		endif
checkhealing functionunda sorun olmalıdır. herhalde burda sorun göremedim ben.
cont.consume 1 i_bandage
		if (<cont.findid.i_rune_poison>) // cure self
			if !(rand(5) == 1)
				cont.findid.i_rune_poison.remove
				cont.effect 3,0376a,2,10,1
				cont.sayua 048,6,6,0 * zehir etkisini iyilestirir *
			else
				cont.sayua 020,6,6,0 * zehiri iyilestiremez *
			endif
		elseif (<cont.findid.i_bleeding3>)/////////Bleeding bana bleed
			if !(rand(5) == 1)
				cont.findid.i_bleeding3.remove
				cont.effect 3,0376a,2,10,1
				cont.sayua 048,6,6,0 *yarayi tedavi eder*
			else
				cont.sayua 020,6,6,0  *yarayi tedavi edemez*
			endif
		else // heal self
			cont.hits (<cont.hits> + <morey>)
			cont.effect 3,0376a,2,10,1
			cont.sayua 048,6,6,0 * kendini tedavi eder *
			if (<cont.hits> > <cont.str>)
				cont.hits <cont.str>
			endif
		endif
		cont.checkhealing 1
		cont.checkanatomy 1
		if (<cont.dex> < 50)
			timer 14
		elseif (<cont.dex> < 60)
			timer 13
		elseif (<cont.dex> < 70)
			timer 12
		elseif (<cont.dex> < 80)
			timer 11
		else
			timer 10
		endif
	endif
	morey 0 // memory'yi etkisiz hale getir
	cont.events -e_healing // eventi kaldir artik gerek yok
	return 1
endif
remove
return 1

[function hb]		// bandaj atarken buyu engeli icin item, kontrolü fix.scp de..
if (<findid.i_bandage_buyu>)
findid.i_bandage_buyu.remove
endif
if !(<findid.i_bandage_buyu>)
serv.newitem i_bandage_buyu
new.more1 <args>
new.equip
endif

[itemdef i_bandage_buyu]
name=bandaj buyu engel
id=i_gold
type=t_eq_script
weight=0
layer=layer_special

On=@Equip
if (<more1>)
	timer <more1>
endif

On=@Timer
remove
return 1


/////////////Genel Fix
[events e_healing]
On=@GetHit
	if (<argn1> >4) && (rand(2) == 1)
	say
	say
	sayua 020,6,6,0 * bandajlari yirtilir *
	findid.i_mem_healing.remove
	findid.i_bandage_buyu.remove
	findid.i_spdelay_man.remove
	findid.i_spdelay_woman.remove
	findid.i_spdelay_unisex.remove
	endif



on=@death
	findid.i_mem_healing.remove
	findid.i_bandage_buyu.remove
	findid.i_spdelay_man.remove
	findid.i_spdelay_woman.remove
	findid.i_spdelay_unisex.remove

on=@logout
	findid.i_mem_healing.remove
	findid.i_bandage_buyu.remove
	findid.i_spdelay_man.remove
	findid.i_spdelay_woman.remove
	findid.i_spdelay_unisex.remove

[function checkhealing]
if (<args> == 1) && (<healing> >= 80.0) && (rand(3) == 1)
	return 0
endif

if ((<skilllock[17]> == 0) && (<skilltotal> < 150000.0))
	if (<healing> < 30.0)
		if (rand(1) == 1)
			healing (<healing> + 1)
		endif
	elseif (<healing> < 50.0)
		if (rand(1) == 1)
			healing (<healing> + 1)
		endif
	elseif (<healing> < 75.0)
		if (rand(1) == 1)
			healing (<healing> + 1)
		endif
	elseif (<healing> < 100.0)
		if (rand(1) == 1)
			healing (<healing> + 1)
		endif
	endif
endif

[function checkveterinary]
if ((<skilllock[39]> == 0) && (<skilltotal> < 150000.0))
	if (<veterinary> < 30.0)
		if (rand(1) == 1)
			veterinary (<veterinary> + 1)
		endif
	elseif (<veterinary> < 50.0)
		if (rand(1) == 1)
			veterinary (<veterinary> + 1)
		endif
	elseif (<veterinary> < 75.0)
		if (rand(1) == 1)
			veterinary (<veterinary> + 1)
		endif
	elseif (<veterinary> < 100.0)
		if (rand(1) == 1)
			veterinary (<veterinary> + 1)
		endif
	endif
endif


[function checkanatomy]
if (<args> == 1) && (<anatomy> >= 80.0) && (rand(3) == 1)
	return 0
endif

if ((<skilllock[1]> == 0) && (<skilltotal> < 150000.0))
	if (<anatomy> < 30.0)
		if (rand(1) == 1)
			anatomy (<anatomy> + 1)
		endif
	elseif (<anatomy> < 50.0)
		if (rand(1) == 1)
			anatomy (<anatomy> + 1)
		endif
	elseif (<anatomy> < 75.0)
		if (rand(1) == 1)
			anatomy (<anatomy> + 1)
		endif
	elseif (<anatomy> < 100.0)
		if (rand(1) == 1)
			anatomy (<anatomy> + 1)
		endif
	endif
endif
[function checkanimallore]
if ((<skilllock[2]> == 0) && (<skilltotal> < 150000.0))
	if (<animallore> < 30.0)
		if (rand(1) == 1)
			animallore (<animallore> + 1)
		endif
	elseif (<animallore> < 50.0)
		if (rand(1) == 1)
			animallore (<animallore> + 1)
		endif
	elseif (<animallore> < 75.0)
		if (rand(1) == 1)
			animallore (<animallore> + 1)
		endif
	elseif (<animallore> < 100.0)
		if (rand(2) == 1)
			animallore (<animallore> + 1)
		endif
	endif
endif


[DIALOG d_rescon]
0,375

nomove
page 0 
resizepic 30 10 5054 145 75
text 45 15 600 0
text 60 35 0 1
text 60 55 0 2
button 40 35 210 211 1 0 1
button 40 55 210 211 1 0 0 

[DIALOG d_rescon TEXT]   
Resurrect?
Evete.
Hayir.

[DIALOG d_rescon BUTTON]  
ONBUTTON=0

ONBUTTON=1
SRC.RESURRECT

[itemdef i_mageryfix]
ID=i_memory
TYPE=t_eq_script
NAME=magery FixXx

On=@Create
attr attr_newbie|attr_decay

On=@Equip
timer 3

On=@Timer
remove
return 1



[function olumlu]
sayua 044  <args>

[function olumsuz]
sayua 038  <args>

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.