Üye ol    Giriş
  1. Forumlar
  2. Oyunlar
  3. Ultima Online
  4. Sphere Scripting
  5. item id

item id

deadmage üyesi avatar
deadmage
Members
0
itemin id'sini nasil gosterebilirim <src.uid> ve <uid> yapinca stonedeki playerin id'si gecior. <act.uid> yapinca da can't resolve hatasi verior bir de benim vps'imin saati yavas işliyor 1 sn 3sn de gecior bu konu hakkinda da bilgi verebilirseniz sevinirim tesekkurler...
  • 2009-01-16 22:22
  • #1
Nexima
Nexima
Expert
6.3
amaçladığın şeyi anlayamadım. id mi uid mi ayrıca?
  • 2009-01-16 22:35
  • #2
deadmage üyesi avatar
deadmage
Members
0
itemin infosuna bakinca serailde yazan rakamlari elde etmeyi amacliorum :)
  • 2009-01-16 23:01
  • #3
Nexima
Nexima
Expert
6.3
peki. orasını anladım. şimdi sen bunu nerde kullanıcaksın, ne yapmak istiyorsun açıklarsan sorununu tam anlayacağım. :)
  • 2009-01-16 23:07
  • #4
deadmage üyesi avatar
deadmage
Members
0
mesala iteme tiklandiya yanda Bu item id'si xxx diye nasil yell geciririm?
  • 2009-01-17 15:07
  • #5
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
seriali id si diil ki... bide 1 snde 3sn geçme olayı biraz öcne konuda bulunamadı ama sende bir bak istersen :S

[itemdef i_katana_den]
defname=i_katana_den
id=i_katana
name=katana

On=@Click
src.sysmessage @0488 Bu itemin id si <baseid>.
return 1
  • 2009-01-17 15:26
  • #6
deadmage üyesi avatar
deadmage
Members
0
ya guild stonenin uid'si seriali olmuyor mu guild stone scp'm burda lutfen bi yardim edin :)
senin dedigin itemin gorunusunu yapior benim istedigim uid'si :S
[ITEMDEF 0edd]
//gravestone = Guildstone
DEFNAME=i_guildstone
TYPE=T_STONE_GUILD
VALUE=60000

On=@Create
attr 08010
dispid 0ed4
name *

On=@Click
message @790,3,0 Guild Stone
if !(strmatch('<abbrev>',''))
message @790,,1 Guildmaster: <master>
message @200,,1 <name>, [<abbrev>]
else
message @0790,,1 <name>
endif
if (<more1> == 1)
message @0bb2 [Order]
elseif (<more1> == 2)
message @0bb2 [Chaos]
elseif (<link> != 04fffffff)
message @0bb2 [<link.name>]
endif
return 1

On=@TargOn_Char
if (<morex> == 1) // recruiting
if (<src.targ.npc>)
src.sysmessage @38,,1 Hata: Sadece oyuncular guild uyesi olabilir.
elseif (<src.targ.distance> > 3)
src.sysmessage @38,,1 Hata: <src.targ.name> bu islem icin stone'a yeterince yakin degil.
elseif (<src.targ.memoryfindtype.memory_guild>)
if (<src.targ.memoryfindtype.memory_guild.link> != <uid>)
src.sysmessage @38,,1 Hata: <src.targ.name> uye olabilmek icin oncelikle <src.targ.memoryfindtype.memory_guild.link.name> uyeliginden cikmali.
elseif (<src.targ.memoryfindtype.memory_guild.link> == <uid>)
src.sysmessage @38,,1 Hata: <src.targ.name> zaten bir <name> uyesi.
endif
elseif (<src.targ.memoryfindtype.memory_town>) && (<src.targ.memoryfindtype.memory_town.link> != <link>)
src.sysmessage @38,,1 Hata: <src.targ.name> guild'in desteklemedigi <src.targ.memoryfindtype.memory_town.link.name> Ordu'sunda. Bir <name> uyesi olamaz.
elseif (<src.targ.findid.i_gs_recruit>)
src.sysmessage @38,,1 Hata: <src.targ.name> su an dusunme asamasinda.
else
src.newitem i_gs_recruit
src.act.cont <src.targ.uid>
src.act.more1 <src.uid>
src.act.more2 <uid>
src.act.timer 1
endif
elseif (<morex> == 2) // titling
if (<src.targ.memoryfindtype.memory_guild.link> != <uid>)
src.sysmessage @38,,1 Hata: Unvan vermeye calistiginiz kisi bir <name> uyesi degil.
menu menu_guild_masterfunc
elseif (<src.targ.distance> > 3)
src.sysmessage @38,,1 Hata: <src.targ.name> bu islem icin stone'a yeterince yakin degil.
else
src.act <src.targ.uid>
dialog d_gs_title
endif
endif
return 1

On=@TargOn_Ground
return 1

On=@TargOn_Item
return 1

On=@Timer
if (<morey> == 1)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 1
link 04fffffff
sayu Yeni destek yonu: Order.
elseif (<morey> == 2)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 2
link 04fffffff
sayu Yeni destek yonu: Chaos.
elseif (<morey> == 3)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 04fffffff
sayu <name> artik tarafsiz.
elseif (<morey> == 4)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 040051ec8
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
elseif (<morey> == 5)
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
morey 0
more1 0
link 040050d73
link.morex <eval (<link.morex> + 1)>
sayu Yeni destek yonu: <link.name>.
endif
timer -1
return 1

[dialog d_gs_title]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 290 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_title TEXT]
Vermek istediginiz unvani giriniz. (12 karakter)
Tamam
Vazgec
<src.act.tag.gs_title>

[dialog d_gs_title BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage @38,,1 Hata: Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif (<src.act.distance> > 3)
src.sysmessage @38,,1 Hata: <src.act.name> bu islem icin size yeterince yakin degil.
elseif ((strlen(<argtxt[0]>)) > 12)
src.sysmessage @38,,1 Hata: Bir unvan en fazla 12 karakterden olusabilir.
dialog d_gs_title
elseif (strmatch('<argtxt[0]>',''))
src.act.tag.gs_title
src.act.sysmessage @03b2,,1, Unvaniniz silindi.
if (<src.uid> != <src.act.uid>)
src.sysmessage @03b2,,1, <src.act.name>: Unvan silindi.
endif
menu menu_guild_masterfunc
else
src.act.tag.gs_title <argtxt[0]>
src.act.sysmessage @03b2,,1, Yeni unvan: <src.act.tag.gs_title>.
if (<src.uid> != <src.act.uid>)
src.sysmessage @03b2,,1, <src.act.name> yeni unvan: <src.act.tag.gs_title>.
endif
menu menu_guild_masterfunc
endif

[itemdef i_gs_recruit]
name guild recruiter
weight 0
id i_gold
type t_eq_script
layer layer_special

On=@UnEquip
try src.act <more2>
try src.dialog d_gs_recruit
return 1

On=@Timer
remove
return 1

[dialog d_gs_alignment]
-100,-100
nomove

resizepic 190 165 5120 275 275
resizepic 200 175 3000 255 255

text 220 185 2100 0
htmlgump 215 208 223 60 1 1 1

htmlgump 258 277 140 20 2 0 0
htmlgump 258 297 150 20 3 0 0
htmlgump 258 317 150 20 4 0 0
htmlgump 258 337 150 20 5 0 0
htmlgump 258 357 150 20 6 0 0
htmlgump 258 377 150 20 7 0 0
htmlgump 258 397 150 20 8 0 0
button 225 275 4006 4007 1 0 1
button 225 295 4006 4007 1 0 2
button 225 315 4006 4007 1 0 3
button 225 335 4006 4007 1 0 4
button 225 355 4006 4007 1 0 5
button 225 375 4006 4007 1 0 6
button 225 395 4006 4007 1 0 7

[dialog d_gs_alignment text]
<name>: <var.gs_align>
Dikkat! guild'in destek yonunu degistirdiginiz takdirde, eger tarafsiz bir guild degilse 24 saat boyunca bu menuyu kullanamayacak ve eski destek tarafinizda kalmaya devam edeceksiniz, 24 saat sonunda otomatik olarak desteginiz degisecektir. Tarafsiz guild'ler menuden islem yapildigi anda taraf degistirebilirler. Destek yonunuzu Order veya Chaos'a cevirdiginizde, tum guild uyeleri (candidate'ler haric) O/C'ye dahil olacaktir. Fakat destek yonunuzu ordulardan bir tanesine cevirirseniz sadece ordu savaslarinda bulunmak isteyen guild uyeleri ilgili ordu stone'dan ordu'a kayit olarak bu olusuma dahil olabileceklerdir.
British: Order
Blackthorn: Chaos
Tarafsiz
Faction: Venamar
Faction: Querala
Ordu: Bucaneer's Den
Ordu: Delucia

[dialog d_gs_alignment button]
On=0
menu menu_guild_masterfunc

On=1
if (<more1> == 1)
src.sysmessage @38 <name> zaten bir Order guildi.
else
morey 1
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi su anda order grubunun uyesi olmustur.
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=2
if (<more1> == 2)
src.sysmessage @38 <name> zaten bir Chaos guildi.
else
morey 2
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi su anda chaos grubunun uyesi olmustur.
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=3
if (<more1> == 0) && (<link> == 04fffffff)
src.sysmessage @30 <name> zaten tarafsiz bir guild.
else
morey 3
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi grubunu birakip tarafsiz olmustur.
sayu Tarafsizlik sureci baslamistir.
timer 86400
endif
menu menu_guild_masterfunc

On=4
if (<link> == 040051ec8)
src.sysmessage @38 <name> zaten bir Venamar guildi.
else
morey 4
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi su anda Venamar Faction grubunun uyesi olmustur.
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=5
if (<link> == 040050d73)
src.sysmessage @38 <name> zaten bir Querala guildi.
else
morey 5
if (<more1> == 0) && (<link> == 04fffffff)
timer 1
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi su anda Querala Faction grubunun uyesi olmustur.
else
sayu Taraf degistirme sureci baslamistir.
timer 86400
endif
endif
menu menu_guild_masterfunc

On=6
src.sysmessage @045,1,1 Bu Ozellik KAPATILMISTIR!
menu menu_guild_masterfunc

On=7
src.sysmessage @045,1,1 Bu Ozellik KAPATILMISTIR!
menu menu_guild_masterfunc

[dialog d_gs_recruit]
-100,-100
nomove

resizepic 190 165 3600 275 155

htmlgump 215 188 223 60 0 1 1
htmlgump 261 257 140 20 1 0 0
htmlgump 261 277 150 20 2 0 0
button 225 255 4006 4007 1 0 1
button 225 275 4018 4019 1 0 0

[dialog d_gs_recruit text]
<uid.<findid.i_gs_recruit.more1>.name> tarafindan <act.name> guild'ine davet edildiniz. Bu guild'e katilmak istiyor musunuz?
<var.font1>>Evet
<var.font1>>Hayir

[dialog d_gs_recruit button]
On=1
if (<act.distance> > 3)
sysmessage @38,,1 Hata: Guild stone'a yeterince yakin degilsiniz.
else
try tag.gs_title
try uid.<act.uid>.applytojoin
endif

// This is the guildmaster initial selection screen for guildstones
[MENU MENU_GUILD_MASTER]
<Name> (<Master>)
ON=0 Guild'e yeni uye al
morex 1
target @0790,,1 Guild'e almak istediginiz kisiyi seciniz.
ON=0 Guild uyeleri
VIEWROSTER
ON=0 Guild's charter.
VIEWCHARTER
ON=0 Guild uyelik adaylari.
VIEWCANDIDATES
ON=0 <Name> savas ilan ettigi guildler.
VIEWENEMYS
ON=0 <Name> guildine savas ilan eden guildler.
VIEWTHREATS
ON=0 Kime bagimlisiniz? (Master: <LoyalTo>)
DECLAREFEALTY
ON=0 Guild'den ayril
src.tag.gs_title
RESIGN
ON=0 Guild kalkani al.
if (<src.targ.more> == 1)
if (0<src.tag.sho> == 1)
src.sysmessage @38,,1 Lord British size daha once kalkan vermis.
return 1
endif
src.tag.sho 1
src.newitem i_shield_order
src.act.bounce
elseif (<src.targ.more> == 2)
if (0<src.tag.shc> == 1)
src.sysmessage @38,,1 Lord Blackthorne size daha once kalkan vermis.
return 1
endif
src.tag.shc 1
src.newitem i_shield_chaos
src.act.bounce
else
src.sysmessage @38,,1 Hata: Sadece Order ve Chaos guildleri kalkan alabilir.
endif
ON=0 Guild <MasterGenderTitle> menusu.
MASTERMENU

// This is the NON-guildmaster initial selection screen for guildstones
[MENU MENU_GUILD_MEMBER]
<Name> (<Master>)
ON=0 Guild uyeleri.
VIEWROSTER
ON=0 Guild's charter.
VIEWCHARTER
ON=0 Guild uyelik adaylari.
VIEWCANDIDATES
ON=0 <Name> savas ilan ettigi guildler.
VIEWENEMYS
ON=0 <Name> guildine savas ilan eden guildler.
VIEWTHREATS
ON=0 Kime bagimlisiniz? (Master: <LoyalTo>)
DECLAREFEALTY
ON=0 Guild'den ayril.
src.tag.gs_title
RESIGN
ON=0 Guild kalkani al.
if (<src.targ.more> == 1)
if (0<src.tag.sho> == 1)
src.sysmessage @38,,1 Lord British size daha once kalkan vermis.
return 1
endif
src.tag.sho 1
src.newitem i_shield_order
src.act.bounce
elseif (<src.targ.more> == 2)
if (0<src.tag.shc> == 1)
src.sysmessage @38,,1 Lord Blackthorne size daha once kalkan vermis.
return 1
endif
src.tag.shc 1
src.newitem i_shield_chaos
src.act.bounce
else
src.sysmessage @38,,1 Hata: Sadece Order ve Chaos guildleri kalkan alabilir.
endif

[dialog d_gs_abbrev]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 250 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_abbrev TEXT]
Yeni guild kisaltmasi giriniz. (3 karakter)
Tamam
Vazgec
<abbrev>

[dialog d_gs_abbrev BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage @38,,1 Hata: Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif ((strlen(<argtxt[0]>)) > 3)
src.sysmessage @38,,1 Hata: Guild kisaltmasi en fazla 3 karakterden olusabilir.
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>',''))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>',' '))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','-'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','!'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','$'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','.'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','_'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','='))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','+'))
src.sysmessage @38,,1 Hata: Bir kisaltma girmediniz?
dialog d_gs_abbrev
else
abbrev <argtxt[0]>
src.sysmessage @03b2,,1, Yeni kisaltma: <abbrev>
menu menu_guild_masterfunc
endif

[dialog d_gs_rename]
100,50
resizepic 190 175 5120 335 150
resizepic 200 185 3000 315 130
resizepic 220 235 3000 270 22

htmlgump 220 200 250 20 0 0 0 // ba$lik
htmlgump 255 277 100 20 1 0 0 // ok
button 220 275 4006 4007 1 0 1 // ok b
htmlgump 435 277 100 20 2 0 0 // cancel
button 400 275 4018 4019 1 0 0 // cancel b
textentry 225 237 253 25 0 0 3 // isim buraya

[dialog d_gs_rename TEXT]
Yeni guild kisaltmasi giriniz. (16 karakter)
Tamam
Vazgec
<name>

[dialog d_gs_rename BUTTON]
On=0
if (<distance> < 4)
menu menu_guild_masterfunc
endif

On=1
if (<distance> > 3)
src.sysmessage @38,,1 Hata: Bu islem icin guildstone'a yeterince yakin degilsiniz.
elseif ((strlen(<argtxt[0]>)) > 16)
src.sysmessage @38,,1 Hata: Guild ismi en fazla 16 karakterden olusabilir.
dialog d_gs_rename
elseif (strmatch('<argtxt[0]>',''))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>',' '))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','-'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','!'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','$'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','.'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','_'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','='))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
elseif (strmatch('<argtxt[0]>','+'))
src.sysmessage @38,,1 Hata: Bir isim girmediniz?
dialog d_gs_abbrev
else
name <argtxt[0]>
src.sysmessage @03b2,,1, Yeni isim: <name>
menu menu_guild_masterfunc
endif

// Guild master functions.
[MENU MENU_GUILD_MASTERFUNC]
<Name>, Guild <MasterGenderTitle> functions
ON=0 Guild'in adini degistir.
dialog d_gs_rename
ON=0 Guild'in kisaltmasini degistir.
dialog d_gs_abbrev
ON=0 Guild destegi. (Su anda <AlignType>)
if (<timer> > 0) && (<morey>)
if (<eval (<timer> / 3600)> < 1)
src.sysmessage @03b1,,1, Taraf degistirme surecindeyken bu menuyu kullanamazsiniz. (<eval (<timer> / 60)> dakika)
else
src.sysmessage @03b1,,1, Taraf degistirme surecindeyken bu menuyu kullanamazsiniz. (<eval (<timer> / 3600)> saat)
endif
menu menu_guild_masterfunc
return 1
endif
if (<more1> == 0) && (<link> == 04fffffff)
var.gs_align Tarafsiz
elseif (<more1> == 1)
var.gs_align Order
elseif (<more1> == 2)
var.gs_align Chaos
elseif (<link> == 040051ec8)
var.gs_align Venamar
elseif (<link> == 040050d73)
var.gs_align Querala
endif
dialog d_gs_alignment
ON=0 Set the guild's charter.
SETCHARTER
ON=0 Guild'e uyesine unvan ver.
if (strmatch('<abbrev>',''))
src.sysmessage @38,,1 Hata: Bir uyeye unvan verebilmek icin once guild kisaltmasi belirlemelisiniz.
menu menu_guild_masterfunc
else
morex 2
target @0790,,1 Unvan vermek istediginiz guild uyesini seciniz.
endif
ON=0 Guild'den uye at.
DISMISSMEMBER
ON=0 Savas ilan et.
DECLAREWAR
ON=0 Baris ilan et.
DECLAREPEACE
ON=0 Guild adayligini kabul et.
ACCEPTCANDIDATE
ON=0 Guild adayligini reddet.
REFUSECANDIDATE
ON=0 Guild'i 22.000gp yik.
if (<link> != 04fffffff)
link.morex <eval (<link.morex> - 1)>
endif
REMOVE
SRC.NEWITEM i_gold
SRC.ACT.AMOUNT=22000
SRC.ACT.BOUNCE
SERV.ALLCLIENTS sysmessage @066d,,1" * <serv.name> Guild Haberleri *
SERV.ALLCLIENTS sysmessage @0bb2,,1 <Name> guildi su anda yikilmistir.                                 
ON=0 Main menu'ye geri don
RETURNMAINMENU

// Non-member view.
[MENU MENU_GUILD_NON]
<Name> (<Master>)
ON=0 Guild uyeleri.
VIEWROSTER
ON=0 Guild uye adaylar.
VIEWCANDIDATES
ON=0 <Name> Guildinin Dusmanlari
VIEWENEMYS
ON=0 <Name> Guildine Savas Acanlar
VIEWTHREATS

[MENU MENU_GUILD_ALIGN]
Change the alignment of guild.
ON=0 British: Order
CHANGEALIGN 1
ON=0 Blackthorn: Chaos
CHANGEALIGN 2
ON=0 Neutral
CHANGEALIGN 0
ON=0 Ordu: Britain
sysmessage @027,1,1 Suan aktif degildir.
return 1
ON=0 Ordu: Moonglow
sysmessage @027,1,1 Suan aktif degildir.
return 1
ON=0 Ordu: Bucaneer's Den
sysmessage @027,1,1 Suan aktif degildir.
return 1
ON=0 Ordu: Delucia
sysmessage @027,1,1 Suan aktif degildir.
return 1
  • 2009-01-17 15:30
  • #7
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
xwerswoodx : seriali id si diil ki... bide 1 snde 3sn geçme olayı biraz öcne konuda bulunamadı ama sende bir bak istersen :S

[itemdef i_katana_den]
defname=i_katana_den
id=i_katana
name=katana

On=@Click
src.sysmessage @0488 Bu itemin id si <baseid>.
return 1

id sini istiyorsan bu scp yi kullan :) ben sounu tam anlamadım biraz daha genel anlatırsan en baştan bir kerede sevnecem :) bide scp de nereye ekleyeceğini belirtirsen :)
  • 2009-01-17 15:33
  • #8
deadmage üyesi avatar
deadmage
Members
0
scp'te
on=@click in altina tiklayinca bu itemin seri numarasi 0454635f3"" fln gibi yazmasini istiyorum :S
  • 2009-01-17 15:35
  • #9
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
ON=@Click
src.sysmessage @0488 Bu esyanin seri numarasi <serial>.
return 1



Bu konu xwerswoodx tarafından düzenlendi(2009-01-17 15:44, 15 yıl önce)
  • 2009-01-17 15:37
  • #10
deadmage üyesi avatar
deadmage
Members
0
tesekkurler..
  • 2009-01-17 16:57
  • #11
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
@ deadmage
önemli diil inş. yardımcı olabilmişimdir :)
  • 2009-01-17 17:58
  • #12

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.

Discord ile Bağlan
Twitch ile Bağlan
Steam ile Bağlan
Google ile Bağlan