Runebook Yapımı 56B Sorun

55
1.10 14 0

[function dialogcloseall]
if (<dialoglist.count> > 0)
  for 0 <eval(<dialoglist.count>-1)>
    try dialogclose <dialoglist.<dlocal._for>.id>
  endfor
endif
updatex

[itemdef i_spelldelay]
id=i_handr_1
name=spell delay
type=t_eq_script
weight=0
value=0

on=@create
color=025
attr=attr_invis|attr_newbie|attr_decay

on=@equip
timer=<dmore1>
topobj.flags <topobj.flags>|statf_freeze

on=@unequip
topobj.flags <topobj.flags>&~statf_freeze

on=@timer
remove
return 1

[itemdef i_runebook]
id=i_spellbook
name=Runebook
type=t_script
value=500
weight=5
skillmake=magery 90.0, inscription 75.0
resources=5 i_scroll_recall, 4 i_scroll_gate_travel, 40 i_scroll_blank

on=@create
color=38
attr=attr_newbie
//tag0.isim=
more2=5
more1=0

on=@click
if !<isempty <tag.isim>>
	messageua 0481,6,6,0 a <name> (<tag0.isim>)
else
	messageua 0481,6,6,0 a <name>
endif
return 1

on=@dclick
src.dialogcloseall
more1
if (<src.action>==skill_magery) || (<src.findid(i_spelldelay)>)
	src.sysmessage @34,,1 Büyü yaparken kullanamazsınız.
elif <src.findid(i_runebookdelay)>
	src.sysmessage @34,,1 Şu an zaten runebook'u kullanıyorsunuz.
elif <src.flags>&statf_dead
	src.sysmessage @34,,1 Ölüyken kullanamazsınız.
elif <src.flags>&statf_freeze
	src.sysmessage @34,,1 Şu anki durumunuzda kullanamazsınız.
elif (<cont>) && (<topobj>!=<src>)
	return 1
elif strmatch(*jail*,<src.region.name>)
	src.sysmessage @34,,1 Cezanız varken kullanamazsınız.
elif (<src.region.flags>®ion_flag_safe|region_flag_ship)
  	src.sysmessage @34,,1 Bu bölgede runebook kullanamazsınız.
else
	sdialog d_runebook
	src.sound 85
endif
return 1

on=@targon_item
if <more1>==1
	if <src.targ.topobj>!=<src>
		src.sysmessage @34,,1 Yalnızca üzerinizdeki scrolları ekleyebilirsiniz.
	elif <src.targ.baseid>!=i_scroll_recall
		src.sysmessage @34,,1 Şarj işleminde yalnızca recall scroll kullanabilirsiniz.
	elif <src.targ.amount> < 1
		return 1
	else
		more2=<eval <more2>+<src.targ.amount>>
		src.sysmessage @34,,1 <src.targ.amount> adet şarj eklediniz.
		src.targ.remove
		src.sysmessage @34,,1 Mevcut Şarj: <dmore2>
	endif
endif
if <more1>==2
	if <src.targ.topobj>!=<src>
		src.sysmessage @34,,1 Yalnızca üzerinizdeki rune'ları ekleyebilirsiniz.
	elif <src.targ.baseid>!=i_rune_marker
		src.sysmessage @34,,1 Yalnızca recall rune seçebilirsiniz.
	elif !<src.targ.morep>
		src.sysmessage @34,,1 Boş rune ekleyemezsiniz.
	else
		for 14 1
			if <isempty <tag.rune<dlocal._for>_p>>
				local.emptyrune=<dlocal._for>
			endif
		endfor
		if !<local.emptyrune>
			src.sysmessage @34,,1 Kitabınızda boş yer yok.
		else
			tag0.rune<dlocal.emptyrune>_p=<src.targ.morep>
			tag0.rune<dlocal.emptyrune>_name=<src.targ.name>
			tag0.rune<dlocal.emptyrune>_orjname=<src.targ.name>
			src.sysmessage @34,,1 <src.targ.name> isimli rune kitabınıza eklendi.
			src.targ.remove
		endif
	endif	
endif
return 1

on=@targon_char
return 1

on=@targon_ground
return 1

[dialog d_runebook]
0,0

page 0
gumppic 50 50 089a
button 76 65 2118 2117 1 0 200
dhtmlgump 96 64 60 20 0 0 <def.bfont_red>İsim:
dcroppedtext 125 63 110 20 0 <qval!(<isempty <tag.isim>>)?<tag0.isim>:isimsiz>
button 255 65 2118 2117 1 0 201
dhtmlgump 275 63 80 20 0 0 <def.bfont_red>Şarj: <def.bfont_black><qval(<dmore2>)? <dmore2>:yok>
button 255 233 2117 2117 1 0 202
dhtmlgump 275 231 90 20 0 0 <def.bfont_red>Rune Ekle

dhtmlgump 79 218 50 20 0 0 <def.bfont_red>|
dhtmlgump 79 233 50 20 0 0 <def.bfont_red>|__Recall
dhtmlgump 87 218 50 20 0 0 <def.bfont_red>|__Gate
dhtmlgump 165 218 50 20 0 0 <def.bfont_red>Çıkart_|
dhtmlgump 218 218 50 20 0 0 <def.bfont_red>|
dhtmlgump 161 233 60 20 0 0 <def.bfont_red>Rename__|
for 1 7
	button 73 <eval(<local._for>*18)+75> 2103 2104 1 0 <dlocal._for>		//recall
	button 83 <eval(<local._for>*18)+75> 2103 2104 1 0 <eval(<local._for>+20)>	//gate
	button 203 <eval(<local._for>*18)+75> 2103 2104 1 0 <eval(<local._for>+50)>	//çıkart
	button 213 <eval(<local._for>*18)+75> 2103 2104 1 0 <eval(<local._for>+80)>	//rename
	call f_rune_color <tag0.rune<dlocal._for>_p>
	if !(<isempty <tag.rune<dlocal._for>_p>>)
		dhtmlgump 98 <eval(<local._for>*18)+72> 105 20 0 0 <local.color><tag0.rune<dlocal._for>_name>
	endif
endfor
for 8 14
	button 230 <eval(<local._for>*18)-50> 2103 2104 1 0 <dlocal._for>
	button 240 <eval(<local._for>*18)-50> 2103 2104 1 0 <eval(<local._for>+20)>
	button 358 <eval(<local._for>*18)-50> 2103 2104 1 0 <eval(<local._for>+50)>
	button 368 <eval(<local._for>*18)-50> 2103 2104 1 0 <eval(<local._for>+80)>
	call f_rune_color <tag0.rune<dlocal._for>_p>
	if !(<isempty <tag.rune<dlocal._for>_p>>)
		dhtmlgump 253 <eval(<local._for>*18)-55> 115 20 0 0 <local.color><tag0.rune<dlocal._for>_name>
	endif
endfor

[dialog d_runebook button]
on=200
sdialog d_runebook_rename 1 <tag0.isim>

on=201
more1=1
target @042,,1 Eklemek istediğiniz recall scroll'u seçin.

on=202
more1=2
target @042,,1 Eklemek istediğiniz rune'u seçin.

on=1 14
if <isempty <tag.rune<dargn>_p>>
	src.sysmessage @34,,1 Bu kayıt boş.
	return 1
endif
if <src.flags>&statf_dead
	src.sysmessage @34,,1 Ölüyken kullanamazsınız.
elif <src.flags>&statf_freeze
	src.sysmessage @34,,1 Şu anki durumunuzda kullanamazsınız.
elif strmatch(*jail*,<region.name>)
	src.sysmessage @34,,1 Cezanız varken kullanamazsınız.
elif <src.findid(i_runebookdelay)>
	src.sysmessage @34,,1 Şu an zaten runebook'u kullanıyorsunuz.
elif (<src.region.flags>&02) || (<src.region.flags>&040)
	src.sysmessage @34,,1 Bu bölgede runebook kullanamazsınız.
else
	if <src.mana> < 10
		src.sysmessage @34,,1 Yeterli mananız yok.
	else
		if <more2>
			more2 --
			src.sayua 0481,6,6,0 Kal Ort Por
			src.sdelay 2
			src.mana -=15
			src.anim 17
		elif (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_blood_moss>) && (<src.restest 1 i_reag_mandrake_root>)
			src.consume 1 i_reag_black_pearl
			src.consume 1 i_reag_blood_moss
			src.consume 1 i_reag_mandrake_root
			src.sayua 0481,6,6,0 Kal Ort Por
			src.sdelay 2
			src.mana -=15
			src.anim 17
		else
			src.sysmessage @34,,1 Recall olabilecek kadar şarjınız ve malzemeniz yok.
			src.sound 92
		endif
		serv.newitem i_runebookdelay,1
		new.more1=1
		new.more2=3
		src.equip <new>
		new.morep=<tag0.rune<dargn>_p>
	endif
endif

on=21 45
local.argn <eval <argn>-20>
if <isempty <tag.rune<dlocal.argn>_p>>
	src.sysmessage @34,,1 Bu kayıt boş.
	return 1
endif
if <src.flags>&statf_dead
	src.sysmessage @34,,1 Ölüyken kullanamazsınız.
elif <src.flags>&statf_freeze
	src.sysmessage @34,,1 Şu anki durumunuzda kullanamazsınız.
elif strmatch(*jail*,<region.name>)
	src.sysmessage @34,,1 Cezanız varken kullanamazsınız.
elif <src.findid(i_runebookdelay)>
	src.sysmessage @34,,1 Şu an zaten runebook'u kullanıyorsunuz.
elif (<src.region.flags>&02) || (<src.region.flags>&040)
	src.sysmessage @34,,1 Bu bölgede runebook kullanamazsınız.
else
	if <src.magery> < 750
		src.sysmessage @34,,1 Yeterli beceriye sahip değilsiniz. (75.0 magery)
		src.sound 92
	elif <src.mana> < 40
		src.sysmessage @34,,1 Yeterli mananız yok.
		src.sound 92
	else
		if (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_sulfur_ash>) && (<src.restest 1 i_reag_mandrake_root>)
			src.consume 1 i_reag_black_pearl
			src.consume 1 i_reag_sulfur_ash
			src.consume 1 i_reag_mandrake_root
			src.sayua 0481,6,6,0 Vas Rel Por
			src.sdelay 3
			src.mana -=40
			src.anim 17
		else
			src.sysmessage @34,,1 Yeterli malzemeniz yok.
			src.sound 92
		endif
		serv.newitem i_runebookdelay,1,<src>,1
		new.more1=2
		new.more2=6
		new.morep=<tag0.rune<dlocal.argn>_p>
		src.equip <new>
	endif
endif

on=51 75
local.argn <eval <argn>-50>
if <isempty <tag.rune<dlocal.argn>_p>>
	src.sysmessage @34,,1 Bu kayıt boş.
	return 1
endif
serv.newitem i_rune_marker
new.morep=<tag0.rune<dlocal.argn>_p>
new.name=<tag0.rune<dlocal.argn>_orjname>
src.bounce <new>
tag0.rune<dlocal.argn>_p
tag0.rune<dlocal.argn>_name
tag0.rune<dlocal.argn>_orjname
src.sysmessage @34,,1 <new.name> isimli rune çıkartıldı.

on=81 105
local.argn <eval <argn>-80>
if <isempty <tag.rune<dlocal.argn>_p>>
	src.sysmessage @34,,1 Bu kayıt boş.
	return 1
endif
src.ctag0.num=<dlocal.argn>
sdialog d_runebook_rename 2 <tag0.rune<dlocal.argn>_name>

[dialog d_runebook_rename]
0,0
nomove

page 0
resizepic 110 150 5170 355 90
dhtmlgump 177 182 150 20 0 0 Yeniden isimlendir:
gumppic 290 180 09c5
dtextentrylimited 310 180 200 20 0 0 14 <argv[0]>
page 1
button 140 180 4005 4007 1 0 1
page 2
button 140 180 4005 4007 1 0 2
button 140 155 2117 2118 1 0 3
dtext 160 153 1152 Sıfırla

[dialog d_runebook_rename button]
on=0
sdialog d_runebook

on=1 2
if !((<isempty <argtxt[0]>>) || (strregex(^[a-zA-Z]+[:space:]+[a-zA-Z]+$,<argtxt[0]>)) || (strregex(^[a-zA-Z]+$,<argtxt[0]>)))
	src.sysmessage @34,,1 Hatalı isim girdiniz, yalnızca harf ve boşluk kullanabilirsiniz.
	return 1
endif
if <dargn>==1
tag0.isim=<argtxt[0]>
elif <dargn>==2
tag0.rune<src.dctag0.num>_name=<argtxt[0]>
endif
sdialog d_runebook

on=3
tag0.rune<src.dctag0.num>_name=<tag0.rune<src.dctag0.num>_orjname>
sdialog d_runebook

[function f_rune_color]
if (<serv.map(<args>,0).region.flags>®ion_flag_guarded)
	local.color = <def.bfont_blue>
elif (<serv.map(<args>,0).region.flags>®ion_flag_underground)
	local.color = <def.bfont_dgray>
else
	local.color = <def.bfont_red>
endif

[itemdef i_runebookdelay]
id=i_handr_1
type=t_eq_script
name=runebook delay
weight=0
value=0

on=@create
color=040
attr=attr_invis|attr_newbie|attr_decay

on=@equip
topobj.events +e_runebook
timer=1

on=@unequip
topobj.events -e_runebook

on=@timer
if <topobj>
	if <more2>
		if <more1>==2
			if <more2>==5
				serv.newitem i_moongate_blue_fx
				new.name=summoning gate
				new.p=<morep>
				new.morez=1
				new.color=0845
				new.attr=012
				new.timer=5
				new.sfx 526
			endif
		endif
		more2 --
	else
		if <more1>==1
			topobj.go <morep>
		elif <more1>==2
			serv.newitem i_rune_gate
			new.p=<morep>
			new.morep=<topobj.p>
			new.timer=30
			new.sfx 535
			local.gateuid=<new>
			serv.newitem i_rune_gate
			new.p=<topobj.p>
			new.morep=<morep>
			new.timer=30
			new.sfx 535
			new.link=<local.gateuid>
		endif
		remove
	endif
endif
timer=1
return 1

[events e_runebook]
on=@gethit
sound 92
f_fizzle
findid(i_runebookdelay).remove

on=@logout
src.f_fizzle
src.findid(i_runebookdelay).remove

on=@hit
sound 92
f_fizzle
findid(i_runebookdelay).remove

on=@skillstart
sound 92
f_fizzle
findid(i_runebookdelay).remove

on=@death
findid(i_runebookdelay).remove

on=@spellcast
sound 92
f_fizzle
findid(i_runebookdelay).remove

[itemdef i_rune_gate]
id=i_moongate_blue
type=t_moongate
name=rune gate

on=@create
color=0845
attr=attr_static|attr_decay

on=@dclick
if <src.distance <uid>> > 3
	src.sysmessage @34,,1 Yeterince yakın değilsiniz.
elif !<src.canseelos <uid>>
	src.sysmessage @34,,1 Gate'e ulaşamıyorsunuz.
else
	sdialog d_rune_gate
endif
return 1

on=@step
if <src.distance <uid>> > 3
	src.sysmessage @34,,1 Yeterince yakın değilsiniz.
elif !<src.canseelos <uid>>
	src.sysmessage @34,,1 Gate'e ulaşamıyorsunuz.
else
	sdialog d_rune_gate
endif
return 1

on=@click
message a runebook gate
message [<serv.map(<morep>,0).region.name>]
return 1

on=@timer
sfx 528
remove
return 1

[dialog d_rune_gate]
0,0
nomove

resizepic 135 135 5054 255 135
alphablack 145 145 235 115
dtext 180 165 040 <serv.map(<morep>,0).region.name> (<morep>)
dtext 205 190 040 Gitmek ister misiniz?
button 185 222 4005 4007 1 0 1
dtext 220 222 1152 Evet
button 280 222 4005 4007 1 0 2
dtext 315 222 1152 Hayır

[dialog d_rune_gate button]
on=1
if !<uid>
	src.sysmessage @34,,1 Gate kapanmış.
elif <src.distance <uid>> > 3
	src.sysmessage @34,,1 Yeterince yakın değilsiniz.
elif !<src.canseelos <uid>>
	src.sysmessage @34,,1 Gate'e ulaşamıyorsunuz.
else
	src.dialogclose d_rune_gate
	src.go <morep>
endif

[eof]

Merhabalar runebook yapımında inscription menüye girdiğimde hiç bir şey söylemiyor dialogda i_runebook olarak kayıtlı...Yapmıyor...
Normal kendim çıkarmaya çalıştığımda çıkarıyor nedeni ne olabilir ?

Legend

Novice

0.4

38 Ankara , Türkiye
78.95 296 1

İnscription menüsüne eklediğin yerin scp sini koy bide ordan bakalım

Kortez

Neophyte

3.8

41 Abhazya , Türkiye
49.99 292 2

sorun burda değil sorun menüde muhtemelen makeitem ile alakalıdır. Legend'ın söylediği gibi runebook butonundaki eylem kısmını koyarsan sorun daha netleşebilir.

Fanatikts

Banned

55
1.10 14 0



[FUNCTION Scribe_Scroll_Check]
Serv.Newitem=<Argv[0]>
Ref1=<New.Uid>
If <Ref1.Type>==t_scroll
If <Serv.Spell.<Ref1.Morex>.Manause>><Mana>
Ctag.Craft.Message=Bunu yapabilmek için <Serv.Spell.<Ref1.Morex>.Manause> mana'ya ihtiyacınız var.
Ref1.Remove
Return 1
Endif
Endif
Ref1.Remove
Return 0

[Function Scribe_None]

[FUNCTION Bonus_Inscription_books]
If <Type>==t_spellbook
More=0ffffffff

if <Baseid>==i_runebook
Tag.Charges.Max=<eval <Tag0.Charges.Max>+(<Src.Inscription>/100)>
morex=<eval <MOREX> + 6>
Endif

//[TYPEDEF e_inscription_bonus_int_5]


//ON=@Equip
//Src.Modint += 5

//ON=@UnEquip
//Src.Modint -= 5

[TYPEDEF e_inscription_bonus_int_10]

ON=@Equip
//Src.Modint += 10

ON=@UnEquip
//Src.Modint -= 10

[DEFNAME CraftSkills]

//General
Craft_Inscription_Title=Inscription
Craft_Inscription_Materials=1
Craft_Inscription_Repair=
Craft_Inscription_Marking=1
Craft_Inscription_Makelast=1
Craft_Inscription_Custom= //ENHANCE ITEM
Craft_Inscription_Custom_Function= //BS_ENHANCE


Craft_Inscription_Check=Scribe_Scroll_Check
Craft_Inscription_Check_Notice=Scroll'u yapabilmek için büyüyü yapabilecek mana gereklidir.
Craft_Inscriptionbooks_Check=Scribe_None
Craft_Inscriptionbooks_Check_Notice=

//Material
Craft_Inscription_Material_0=
Craft_Inscription_Material_0_NAME=SCROLLS
Craft_Inscription_Material_1=books
Craft_Inscription_Material_1_NAME=BOOKS

//Exceptional
Craft_Inscription_Exceptional=0
Craft_Inscription_Exceptional_Bonus=
Craft_Inscriptionbooks_Exceptional=0
Craft_Inscriptionbooks_Exceptional_Bonus= //Bonus_Inscription_books

//SideMenu
Craft_SideMenu_Inscription_1=1st Circle
Craft_SideMenu_Inscription_2=2nd Circle
Craft_SideMenu_Inscription_3=3rd Circle
Craft_SideMenu_Inscription_4=4th Circle
Craft_SideMenu_Inscription_5=5th Circle
Craft_SideMenu_Inscription_6=6th Circle
Craft_SideMenu_Inscription_7=7th Circle
Craft_SideMenu_Inscription_8=8th Circle

Craft_SideMenu_Inscriptionbooks_1=Spellbooks
craft_SideMenu_Inscriptionbooks_2=Runebooks

//First Circle
Craft_MainMenu_1_Inscription_1=i_scroll_reactive_armor
Craft_MainMenu_1_Inscription_2=i_scroll_clumsy
Craft_MainMenu_1_Inscription_3=i_scroll_create_food
Craft_MainMenu_1_Inscription_4=i_scroll_feeblemind
Craft_MainMenu_1_Inscription_5=i_scroll_heal
Craft_MainMenu_1_Inscription_6=i_scroll_magic_arrow
Craft_MainMenu_1_Inscription_7=i_scroll_night_sight
Craft_MainMenu_1_Inscription_8=i_scroll_weaken

//Second Circle
Craft_MainMenu_2_Inscription_1=i_scroll_agility
Craft_MainMenu_2_Inscription_2=i_scroll_cunning
Craft_MainMenu_2_Inscription_3=i_scroll_cure
Craft_MainMenu_2_Inscription_4=i_scroll_harm
Craft_MainMenu_2_Inscription_5=i_scroll_magic_trap
Craft_MainMenu_2_Inscription_6=i_scroll_magic_untrap
Craft_MainMenu_2_Inscription_7=i_scroll_protection
Craft_MainMenu_2_Inscription_8=i_scroll_strength

//Third Circle
Craft_MainMenu_3_Inscription_1=i_scroll_bless
Craft_MainMenu_3_Inscription_2=i_scroll_fireball
Craft_MainMenu_3_Inscription_3=i_scroll_magic_lock
Craft_MainMenu_3_Inscription_4=i_scroll_poison
Craft_MainMenu_3_Inscription_5=i_scroll_telekinesis
Craft_MainMenu_3_Inscription_6=i_scroll_teleport
Craft_MainMenu_3_Inscription_7=i_scroll_unlock
Craft_MainMenu_3_Inscription_8=i_scroll_wall_of_stone

//Fourth Circle
Craft_MainMenu_4_Inscription_1=i_scroll_archcure
Craft_MainMenu_4_Inscription_2=i_scroll_archprotection
Craft_MainMenu_4_Inscription_3=i_scroll_curse
Craft_MainMenu_4_Inscription_4=i_scroll_fire_field
Craft_MainMenu_4_Inscription_5=i_scroll_greater_heal
Craft_MainMenu_4_Inscription_6=i_scroll_lightning
Craft_MainMenu_4_Inscription_7=i_scroll_mana_drain
Craft_MainMenu_4_Inscription_8=i_scroll_recall

//Fifth Circle
Craft_MainMenu_5_Inscription_1=i_scroll_blade_spirits
Craft_MainMenu_5_Inscription_2=i_scroll_dispel_field
Craft_MainMenu_5_Inscription_3=i_scroll_incognito
Craft_MainMenu_5_Inscription_4=i_scroll_magic_reflection
Craft_MainMenu_5_Inscription_5=i_scroll_mind_blast
Craft_MainMenu_5_Inscription_6=i_scroll_paralyze
Craft_MainMenu_5_Inscription_7=i_scroll_poison_field
Craft_MainMenu_5_Inscription_8=i_scroll_summon_creature

//Sixth Circle
Craft_MainMenu_6_Inscription_1=i_scroll_dispel
Craft_MainMenu_6_Inscription_2=i_scroll_energy_bolt
Craft_MainMenu_6_Inscription_3=i_scroll_explosion
Craft_MainMenu_6_Inscription_4=i_scroll_invisibility
Craft_MainMenu_6_Inscription_5=i_scroll_mark
Craft_MainMenu_6_Inscription_6=i_scroll_mass_curse
Craft_MainMenu_6_Inscription_7=i_scroll_paralyze_field
Craft_MainMenu_6_Inscription_8=i_scroll_reveal

//Seventh Circle
Craft_MainMenu_7_Inscription_1=i_scroll_chain_lightning
Craft_MainMenu_7_Inscription_2=i_scroll_energy_field
Craft_MainMenu_7_Inscription_3=i_scroll_flamestrike
Craft_MainMenu_7_Inscription_4=i_scroll_gate_travel
Craft_MainMenu_7_Inscription_5=i_scroll_mana_vampire
Craft_MainMenu_7_Inscription_6=i_scroll_mass_dispel
Craft_MainMenu_7_Inscription_7=i_scroll_meteor_swarm
Craft_MainMenu_7_Inscription_8=i_scroll_polymorph

//Eighth Circle
Craft_MainMenu_8_Inscription_1=i_scroll_earthquake
Craft_MainMenu_8_Inscription_2=i_scroll_energy_vortex
Craft_MainMenu_8_Inscription_3=i_scroll_resurrection
Craft_MainMenu_8_Inscription_4=i_scroll_summon_elem_air
Craft_MainMenu_8_Inscription_5=i_scroll_summon_daemon
Craft_MainMenu_8_Inscription_6=i_scroll_summon_elem_earth
Craft_MainMenu_8_Inscription_7=i_scroll_summon_elem_fire
Craft_MainMenu_8_Inscription_8=i_scroll_summon_elem_water

//Spellbooks
Craft_MainMenu_1_Inscriptionbooks_1=i_spellbook

//Runebooks
Craft_MainMenu_2_Inscriptionbooks_1=i_runebook




[EOF]

Herşeyi yapabiliyor yanlız runebook harici

Bu konu Fanatikts tarafından düzenlendi(2013-01-19 15:57, 12 yıl önce)

Shovel

Members

2.2

33 Yalova , Türkiye
3.57 35 1

t_scroll

type kısmına runebook'un type'ide eklemelisin.

Fanatikts

Banned

55
1.10 14 0

Runebookun typesinimi değiştiricem anlamadım tam olarak nereye eklemem lazım.

Shovel

Members

2.2

33 Yalova , Türkiye
3.57 35 1

[typedef t_runebook]

runebook içine bu üsttekini ekle.

[itemdef i_runebook]
id=i_spellbook
name=Runebook
type=t_runebook
value=500
weight=5
skillmake=magery 90.0, inscription 75.0
resources=5 i_scroll_recall, 4 i_scroll_gate_travel, 40 i_scroll_blank

Bu üsttekinide seninkiyle güncelle.

[FUNCTION Scribe_Scroll_Check]
Serv.Newitem=<Argv[0]>
Ref1=<New.Uid>
If (<Ref1.Type>==t_scroll) || (<Ref1.Type>==t_runebook)
If <Serv.Spell.<Ref1.Morex>.Manause>><Mana>
Ctag.Craft.Message=Bunu yapabilmek için <Serv.Spell.<Ref1.Morex>.Manause> mana'ya ihtiyacınız var.
Ref1.Remove
Return 1
Endif
Endif
Ref1.Remove
Return 0

Buda senin scribe scroll fonksiyonun bunuda güncelle.

Fanatikts

Banned

55
1.10 14 0

Açıklaman için çok sağol kardeşim ama yine olmadı scroll yapıyorum runebook yapamıyorum.
Craft menüdeki t_scroll kısmını t_runebook yaptım yine olmadı.

Shovel

Members

2.2

33 Yalova , Türkiye
3.57 35 1

Pm ile bana iletişim adresini yollarmısın tw den bakayım bi.

Fanatikts

Banned

55
1.10 14 0

K.bakma böyle bir şey yapamam yardımın için sağol.
Yardımcı olabilicek yokmu ?

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.