[ITEMDEF i_staff_taming]
ID=i_staff_gnarled
NAME=taming staff
TYPE=t_weapon_mace_staff
VALUE=254
TWOHANDS=Y
LAYER=2
WEIGHT=10
DAM=5,10
On=@Create
attr attr_newbie
color 2001
more2 0
timer -1
hitpoints 5
On=@DClick
equip
if (<topobj.uid> != <src.uid>)
src.sysmessage @0845,1,1 Bunu kullanabilmeniz için çantanızda olmalıdır!
elseif (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @0845,1,1 Gizlenmis durumdayken bunu kullanamazsınız!
elseif (<src.targ.region.defname> == a_townZoo)
src.sysmessage @0845,1,1 Bu bölgede taming yasaktır!
elseif (<timer> == -1)
src.sysmessage @666,1,1 Hangi hayvanı ehlileştirmek istiyorsunuz?
target
endif
return 1
On=@UnEquip
more2 0
timer -1
link -1
On=@Timer
if (<link.distance <cont>> > 4)
cont.sysmessage @0845,1,1 Tame sırasında hayvandan uzaklaştınız!
more2 0
link -1
timer -1
return 1
endif
if (<more2> < 6)
dorand 8
cont.sayua 666,0,0,trk Gel <link.name>
cont.sayua 666,0,0,trk Sana zarar vermeyeceğim
cont.sayua 666,0,0,trk Sakin ol, <link.name>
cont.sayua 666,0,0,trk Her zaman senin gibi bir <link.name> sahibi olmak istemiştim
cont.sayua 666,0,0,trk Çok tatlısın, <link.name>
cont.sayua 666,0,0,trk Seni inciltmeyeceğim
cont.sayua 666,0,0,trk Arkadaşın olmak istiyorum
cont.sayua 666,0,0,trk Gel <link.name>
enddo
dorand 2
cont.anim 17
cont.anim 19
enddo
timer 2
more2 (<more2> + 1)
return 1
endif
more2 0
if !(<link.npc> == 1)
cont.sysmessage @0845,1,1 Bunu ehlileştiremezsiniz!
return 1
endif
if (rand(100) < 75)
if (<link.memoryfindtype.memory_ispawned>)
link.memoryfindtype.memory_ispawned.remove
endif
link.food 50
link.karma -400
link.memorydel <cont.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <cont.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
cont.sysmessage @666,1,1 <link.name> sizi sahibi olarak kabul etti.
if ((<cont.skilllock[35]> == 0) && (<cont.skilltotal> < 700.0))
if (<cont.taming> < 30.0)
if (rand(1) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 50.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 75.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 100.0)
if (rand(3) == 1)
cont.taming (<cont.taming> + 1)
endif
endif
endif
if ((<cont.skilllock[2]> == 0) && (<cont.skilltotal> < 700.0))
if (<cont.animallore> < 30.0)
if (rand(1) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 50.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 75.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 100.0)
if (rand(3) == 1)
cont.animallore (<cont.animallore> + 1)
endif
endif
endif
if (<link.id>==c_cow_brown) || (<link.id>==c_cow_bw) || (<link.id>==c_pig) || (<link.id>==c_sheep_woolly) || (<link.id>==c_sheep_shorn) || (<link.id>==c_dog) || (<link.id>==c_cat) || (<link.id>==c_chicken) || (<link.id>==c_bull_brown_dk))
link.timerf 60 ,remove 1
endif
if (<link.id>==c_m_nightmare)
link.FAME=3000
link.KARMA=-5000
endif
link.tag.tamer <cont.uid>
link -1
else
cont.sysmessage @0845,1,1 Hayvanı ehlilleştirmeyi başaramadınız!
link -1
endif
return 1
On=@TargOn_Char
if !(<src.targ.region.defname> == a_townZoo)
if ((<src.targ.npc> == 1) && (<src.targ.id> != c_pv))
if !(<src.targ.canseelos>)
src.sysmessage @0845,1,1 Seçtiğiniz hayvan'a ulaşamıyorsunuz!
elseif (<src.targ.distance> > 3)
src.sysmessage @0845,1,1 Seçtiğiniz hayvan'a ulaşamıyorsunuz!
elseif (<src.targ.memoryfindtype.memory_ipet>)
if (<src.targ.memoryfindtype.(memory_ipet|memory_guard).link> == <src.uid>)
src.sysmessage @666,1,1 <src.targ.name> zaten size ait.
src.targ.flags <src.targ.flags>&statf_pet
else
src.sysmessage @0845,1,1 <src.targ.name> bir başkasina ait!
endif
elseif (<src.targ.memoryfindtype.memory_fight>)
src.sysmessage @0845,1,1 Bu hayvan şuan da müsait değil!
elseif (<src.targ.memoryfindtype.memory_war_targ.link> == <src.uid>)
src.sysmessage @0845,1,1 Bu hayvan size çok kızgın!
elseif (<src.targ.findid.i_rune_summon_creature>)
src.sysmessage @0845,1,1 Büyü ile yaratılmış hayvanları ehlileştiremezsiniz !
elseif (0<src.targ.tag.tamer> == 0<src.uid>)
src.sysmessage @0845,1,1 Hayvan artık sizi umursamıyor!
elseif (<src.taming> < <src.targ.taming>)
src.anim 19
src.sysmessage @0845,1,1 <src.targ.name> için taming skilliniz yeterli değil!
elseif (<src.animallore> < <src.targ.animallore>)
src.anim 19
src.sysmessage @0845,1,1 <src.targ.name> için animal lore skilliniz yeterli değil!
elseif (<src.targ.memoryfindtype.MEMORY_ISPAWNED.link.distance> > 3)
src.sysmessage @0845,1,1 Bu hayvanı sadece yuvasında tameleyebilirsiniz!
else
link <src.targ.uid>
src.anim 19
timer 2
endif
else
src.sysmessage @0845,1,1 Bunu ehlilleştiremezsiniz!
endif
else
src.sysmessage @0845,1,1 Bu bölgede taming yasaktır!
endif
return 1
On=@TargOn_Item
return 1
[function memorydel]
if (0<args>)
if (<findid.i_memory.link> == <args>)
findid.i_memory.remove
memorydel <args>
endif
endif
[EOF]
