Tezgah Sistemi

[ITEMDEF i_otur]
id=i_bench_wood_dark
TYPE=t_chair
FLIP=1
VALUE=32
WEIGHT=17.4
RESOURCES=17 i_board,4 i_nails
SKILLMAKE=Carpentry 52.6,t_carpentry
CATEGORY=Decoration - Furniture
SUBSECTION=Chairs
DESCRIPTION=Bench (Dark Wood)
DUPELIST=0b2d

on=@Timer
ref1 = <tag0.sahip>
if <ref1.maxhits> > <ref1.hits>
ref1.hits +=10
ref1.sysmessage @,,1 Hits değeriniz arttı.
endif
	if <ref1.hits> > <ref1.maxhits>
	ref1.hits <ref1.maxhits>
	endif
timer 10
return 1

[function otur]
serv.newitem i_otur
new.drop
new.attr attr_move_never
tag0.otur <new>
new.tag0.sahip <uid>
new.nudgedown
new.timer 10
	if (<dir> == 6)
	// new.move w
	elif (<dir> == 2)
	// new.move e
	elif (<dir> == 3)
	// new.move e
	elif (<dir> == 1)
	// new.move e
	elif (<dir> == 7)
	// new.move w
	elif (<dir> == 5)
	// new.move w
	elif (<dir> == 4)
	// new.move s
	new.flip 1
	elif (<dir> == 0)
	// new.move n
	new.flip 1
	endif
update



[dialog d_tezgah]
250,150
nomove
bozobag 10,10,400,300
// alphablack 25 35 370 270

dtext 70 12 0481 Eşya

dtext 180 12 0481 Birim Fiyat

dtext 310 12 0481 Adet

dorigin 0 20
for 1 8
ref1=<ctag0.tezgah<dlocal._for>>
	if (<ref1>)
	dtext 70 *25 0481 <cropgump 15,<basharfbuyuk <ref1.name>>>
	dtext 180 *0 70 <f_bolukayir <ref1.dtag.deger>> gp
	dtext 310 *0 70 <f_bolukayir <ref1.amount>>
	else
	dtext 70 *25 0845 Boş
	endif
button 30 *3 021 022 1 0 <dlocal._for>
endfor

if (<uid> == <src.uid>)
	if !(<ctag0.tezgahs>)
	dtext 70 275 0481 Tezgahı kur
	button 30 278 021 022 1 0 100
	else
	dtext 70 275 0481 Tezgahı boz
	button 30 278 021 022 1 0 100
	dtext 270 275 0481 Slogan
	button 230 278 021 022 1 0 101
endif

[dialog d_tezgah button]
on 0
// src.tag0.tezgahtar
// itemsifirlami
// src.sysmessage @,,1 Pazar kurulumu iptal edildi.

on 1 10
ref1=<ctag0.tezgah<dargn>>
if (<uid> == <src.uid>)
	if (<ref1>)
	try uid.<ref1>.dialog d_tezgah_fiyat_2
	ctag0.slota <dargn>
	else
	src.targetf itemekle <dargn>
	sdialog d_tezgah
	src.sysmessage @,,1 Ekleyeceğiniz eşyayı seçiniz.
	endif
else
try uid.<ref1>.dialog d_tezgah_fiyat
src.ctag0.esyaslot <dargn>
endif

on 100
if (<uid> == <src.uid>)
	if !(<ctag0.tezgahs>)
	otur
	events e_tezgahtar
	sysmessage @,,1 Tezgahınız başarıyla kurulmuştur.
	speedmode 4
	ctag0.tezgahs 1
	serv.newitem i_table_nightstand
	new.name <name> tezgah
	new.timer 10
	new.drop
	new.attr attr_move_never
	if (<dir> == 6)
	new.move w
	elif (<dir> == 2)
	new.move e
	elif (<dir> == 3)
	new.move e
	elif (<dir> == 1)
	new.move e
	elif (<dir> == 7)
	new.move w
	elif (<dir> == 5)
	new.move w
	elif (<dir> == 4)
	new.move s
	new.flip 1
	elif (<dir> == 0)
	new.move n
	new.flip 1
	endif
	new.tag0.sahip <uid>
	tag0.masa <new>
	else
	events -e_tezgahtar
	itemsifirlami
	ctag0.tezgahs
	speedmode 0
	if (<tag0.masa>)
	ref4=<tag0.masa>
	ref4.remove
	tag0.masa
	endif
	if (<tag0.otur>)
	ref3=<tag0.otur>
	ref3.remove
	tag0.otur
	update
	ctag0.tezgahs
	endif
	if (<findid.i_slogan>)
	findid.i_slogan.remove
	endif
	endif
endif

on 101
	sdialog d_slogan

[dialog d_tezgah_fiyat]
250,150
nomove
bozobag 10,10,400,300
// alphablack 20 20 380 280

dorigin 0 10
for 1 10
if !<isempty <serv.itemdef.<baseid>.tag.<def.o<dlocal._for>>>>
if <isnum <serv.itemdef.<baseid>.tag0.<def.o<dlocal._for>>>>
dtext 50 *25 0481 <def.o<dlocal._for>>: <eval <serv.itemdef.<baseid>.tag0.<def.o<dlocal._for>>>>
else
dtext 50 *25 0481 <def.o<dlocal._for>>: <basharfbuyuk <serv.itemdef.<baseid>.tag0.<def.o<dlocal._for>>>>
endif
endif
endfor

tilepichue 300 35 <serv.itemdef.<baseid>.id> <dcolor>// <serv.itemdef.<ctag0.itemdetay>.id> <serv.itemdef.<ctag0.itemdetay>.tag0.color> // 150 170 0481 Class: Priest <eval <serv.itemdef.<ctag0.itemdetay>.tag.mana>>
dtext 220 100 0481 Tezgah fiyatı: <dtag.deger>
dtext 220 120 0481 Adet: <amount>
dtext 220 140 0481 Satıcı: <topobj.name>
dtext 220 160 0481 Satın al:
dtextentrylimited 280 160  230 25 0481 1 3 <amount>
button 200 163 2117 2118 1 0 1

[dialog d_tezgah_fiyat button]
on 1
local.hesap <eval <dargtxt1>*<dtag.deger>>
ref1=<src.ctag0.tezgahtar>

if <topobj> != <ref1>
src.sysmessage @,,1 <name>, artık <ref1.name> üzerinde bulunmuyor.
return 1
elif (<dtag.deger> < 1)
src.sysmessage @,,1 <name> satışa sunulmamış.
return 1
elif (<src.tag0.param> < <dlocal.hesap>)
src.sysmessage @,,1 <name> alacak kadar paranız bulumuyor. Miktar: <dlocal.hesap>
return 1
elif !(<ref1.ctag0.tezgahs>)
src.sysmessage @,,1 <ref1.name> tezgahı kapatmış.
return 1
elif (<amount> < <dargtxt1>)
src.sysmessage @,,1 Girdiğiniz miktar kadar <name> bulumuyor.
return 1
else
	if (<amount> >= 2)
	ref1.consume <dargtxt1> <baseid>
	src.newitem <baseid>
	new.amount <dargtxt1>
	src.bounce <new>
	ref1.tag0.param += <dlocal.hesap>
	src.tag0.param -=<dlocal.hesap>
	ref1.sysmessage @,,1 <src.name>, <dargtxt1> adet <name> aldı.
	trysrc <ref1> uid.<ref1>.dialogclose d_tezgah
	trysrc <ref1> uid.<ref1>.dialog d_tezgah
	else
	src.bounce <uid>
	tag0.deger
	tag0.tezgahta
	ref1.tag0.tezgah<src.dctag.esyaslot>
	ref1.tag0.param += <dlocal.hesap>
	src.tag0.param -= <dlocal.hesap>
	ref1.sysmessage @,,1 <src.name>, <dargtxt1> adet <name> aldı.
	trysrc <ref1> uid.<ref1>.dialogclose d_tezgah
	trysrc <ref1> uid.<ref1>.dialog d_tezgah
	endif
	for 0 <eval <ref1.findlayer.21.rescount>-1>
	ref2=<uid.<ref1.findlayer.21>.findcont.<dlocal._for>>
		if !(<ref2.tag0.tezgahta>)
		local.ss ++
		endif
		endfor
		if <dlocal.ss> >= <ref1.findlayer.21.rescount>
		ref1.sysmessage @,,1 Satılacak eşyanız olmadığı için tezgahınız kaldırıldı.
		ref1.itemsifirlami
		if (<ref1.tag0.masa>)
		ref4=<ref1.tag0.masa>
		ref4.remove
		ref1.tag0.masa
		if (<ref1.tag0.otur>)
		ref3=<ref1.tag0.otur>
		ref3.remove
		ref1.tag0.otur
		ref1.update
		ref1.ctag0.tezgahs
		ref1.speedmode 0
		if (<ref1.findid.i_slogan>)
		ref1.findid.i_slogan.remove
		endif
		endif
		endif
endif

[dialog d_tezgah_fiyat_2]
250,150
nomove
bozobag 10,10,240,120
// alphablack 20 20 200 100

dtext 25 35 0481 Eşya: <name>
dtext 25 55 0481 Adet: <amount>
dtext 65 75 0481 Birim değeri:
dtextentrylimited 145 75  230 25 0481 1 9 ?
button 25 78 021 022 1 0 1

dtext 65 95 0481 Listeden kaldır
button 25 98 021 022 1 0 2

[dialog d_tezgah_fiyat_2 button]
on 0
	src.sdialog d_tezgah
on 1
if (<isempty <argtxt1>>)
src.sysmessage @,,1 Boş bırakamazsınız.
return 1
elif !(<isnumeric <argtxt1>>)
src.sysmessage @,,1 Sadece rakam girebilirsiniz.
return 1
endif
tag0.deger <dargtxt1>
src.sdialog d_tezgah

on 2
local.slota <src.dctag.slota>
tag0.deger
tag0.tezgahta
src.ctag0.tezgah<dlocal.slota>
src.sysmessage @,,1 <name> listeden kaldırıldı.
src.sdialog d_tezgah

ref2=<src.uid>
forplayers 3
if (<isplayer>)
	if (<tag0.tezgahtar>)
		if !(<uid> == <src.uid>)
		ref1=<tag0.tezgahtar>
			if (<ref1> == <ref2>)
			ref3=<uid>
			trysrc <ref3> uid.<ref2>.dialogclose d_tezgah
			trysrc <ref3> uid.<ref2>.dialog d_tezgah
			endif
		endif
	endif
endif
endfor

[dialog d_slogan]
250,150
nomove
bozobag 10,10,320,120
// alphablack 20 20 300 100

dtextentrylimited 40 40 230 45 0481 1 79 <ctag0.slogan>

dtext 70 80 0481 Onayla
button 30 83 021 022 1 0 1

[dialog d_slogan button]
on 1
if !(<ctag0.tezgahs>)
src.sysmessage @,,1 Kurulu tezgahınız yok
return 1
endif
if (<src.findid.i_slogan>)
src.findid.i_slogan.remove
endif
if !<isempty <argtxt[1]>>
ctag0.slogan <argtxt[1]>
src.sysmessage @,,1 <name> sloganı <argtxt[1]> olarak ayarlandı.
serv.newitem i_slogan
src.equip <new>
new.timer 20
	sdialog d_tezgah
return 1
else
src.sysmessage @,,1 Hata işlem yapıldı
return 1
endif

[itemdef i_slogan]
id i_gold
type=t_eq_script

on=@Timer
ref1=<cont>

ref1.say @,,1 <ref1.ctag.slogan>
timer 20
return 1


[function itemekle]
if (<argo.tag0.tezgahta>)
src.sysmessage @,,1 Tezgahta olanı tekrar ekleyemezsiniz.
	sdialog d_tezgah
return 1
elif !(<argo.topobj> == <src.uid>)
src.sysmessage @,,1 Sadece çantanızdaki eşyaları ekleye bilirsiniz.
	sdialog d_tezgah
return 1
elif (<argo.type> == t_gold)
src.sysmessage @,,1 Bunu ekleyemezsiniz.
	sdialog d_tezgah
return 1
elif (<argo.cont> == <src.uid>)
src.sysmessage @,,1 Sadece çantanızdaki eşyaları ekleye bilirsiniz.
	sdialog d_tezgah
return 1
endif

ctag0.tezgah<dargn> <argo.uid>
argo.tag0.tezgahta 1
src.sysmessage @,,1 <argo.name> başarıyla eklendi
	dialogclose d_tezgah
	sdialog d_tezgah
ref2=<src.uid>
forplayers 3
if (<isplayer>)
	if (<tag0.tezgahtar>)
		if !(<uid> == <src.uid>)
		ref1=<tag0.tezgahtar>
			if (<ref1> == <ref2>)
			ref3=<uid>
			trysrc <ref3> uid.<ref2>.dialogclose d_tezgah
			trysrc <ref3> uid.<ref2>.dialog d_tezgah
			endif
		endif
	endif
endif
endfor
	
[function itemsifirlami]
for 0 <eval <findlayer.21.rescount>-1>
ref1=<uid.<findlayer.21>.findcont.<dlocal._for>>
ref1.tag0.deger
ref1.tag0.tezgahta
endfor

for 1 10
ctag0.tezgah<dlocal._for>
endfor
events -e_tezgahtar
speedmode 0

[function tezgah]
src.sysmessage @,,1 Geçici süre pasif durumdadır.
return 1
	sdialog d_tezgah

[plevel 1]
tezgah

[events e_tezgahtar]
on=@Dclick
	sdialog d_tezgah
	src.ctag0.tezgahtar <uid>

on=@Click
message @,,1 ( Tezgah )

on=@LogOut
src.itemsifirlami
	if (<tag0.masa>)
	ref4=<tag0.masa>
	ref4.remove
	tag0.masa
	endif
events -e_tezgahtar
	if (<tag0.otur>)
	ref3=<tag0.otur>
	ref3.remove
	tag0.otur
	update
	ctag0.tezgahs
	endif
	if (<findid.i_slogan>)
	findid.i_slogan.remove
	endif

ON=@ITEMEQUIP
if (<act.tag0.tezgahta>)
src.sysmessage @,,1 Satışa sunduğunuz eşyaları giyemezsiniz.
act.bounce
return 1
endif

ON=@ITEMPICKUP_PACK
if (<act.tag0.tezgahta>)
src.sysmessage @,,1 Satışa sunduğunuz eşyaları oynatamazsınız.
return 1
endif