https://img137.imageshack.us/img137/7310/dialogsskx8.jpg
/////////////////////////////////////////////////////////
///////////////////////Tüccar Muro///////////////////////
///////////yazar= |ZagoR| Namı Diyar ForumKusu :)/////////
///////////////mail= [email protected]///////////////
////dipnot= Noxier'in tüccar sistemi örnek alınmıştır////
/////////////////////////////////////////////////////////
//////Desteklen sphere sürümü 56b'dir. Sphere mysql//////
/////////bağlantısının aktif olması gereklidir. /////////
/////oyun içerisinde .seller_sistem_kurulum komutunu/////
///////göndermelisiniz. Npc'miz c_tuccar_muro 'dur///////
/////////////////////////////////////////////////////////
[function seller_sistem_kurulum]
ctag.serverpara 0
var.toppara 0
db.connect
db.execute "create table seller_sistem (id int unsigned not null auto_increment primary key,uid text,hesap text,isim text,aktifsure text,toplampara int);"
sysmessage @07ad Seller Vendor Sistemi Kuruldu...
[function guncelle]
ctag.aktifsure <eval (<account.totalconnecttime> / 60)>
db.connect
db.execute "update seller_sistem set toplampara=<eval <tag0.mypara>>, hesap='<account.name>', aktifsure=<eval <ctag0.aktifsure>>, isim='<name>' where uid='<uid>'"
[function seller]
if (<eval <tag0.tablogirdisi>==1>
src.seller_menu_ac
else
ctag.aktifsure <eval (<account.totalconnecttime> / 60)>
ctag.toplampara 0
db.connect
db.execute "insert into seller_sistem (id, uid, hesap, isim, aktifsure, toplampara) VALUES (NULL, '<uid>', '<account.name>', '<name>', '<eval <ctag0.aktifsure>>', '<eval <ctag0.toplampara>>');"
sysmessage @07ad Tuccar Muro Sistemine Kayit Edildiniz...
tag.tablogirdisi 1
src.seller_menu_ac
return 1
endif
[function seller_menu_ac]
if <isempty <ctag.listele>>
src.ctag.listele toplampara
endif
src.ctag.anasayfa 0
sdialog d_seller_menu
[dialog d_seller_menu]
50, 10
page 0
resizepic 0 0 5120 560 460
resizepic 10 10 3000 540 440
resizepic 110 50 5120 5 295
resizepic 300 50 5120 5 295
resizepic 420 50 5120 5 295
resizepic 30 50 5120 5 345
resizepic 520 50 5120 5 345
resizepic 30 85 5120 495 5
resizepic 30 50 5120 495 5
resizepic 30 340 5120 495 5
resizepic 30 365 5120 495 5
resizepic 30 390 5120 495 5
dtext 150 20 0b6 <serv.servname> Tuccar Muro Satis Listesi
dtext 60 60 09b Uid
dtext 180 60 09b Oyuncu
dtext 345 60 09b Satis
dtext 430 60 09b Aktif Sure
dtext 40 345 03a Tuccar Muro Toplamda <eval <var0.toppara> /1000> K Altinlik Alis Yapmistir.
dtext 40 370 03a Tuccar Muro Sizden <eval <tag0.mypara> /1000> K Altinlik Alis Yapmistir.
db.connect
db.query "select * from seller_sistem order by <ctag.listele> desc limit <eval <ctag.anasayfa>>,<eval <ctag.anasayfa>+15>";
for z 0 15
if <db.row.<dlocal.z>.uid>
local.x=((<dlocal.z>*15)+90)
dtext 40 <dlocal.x> 023a <db.row.<dlocal.z>.uid>
dtext 120 <dlocal.x> 023a <db.row.<dlocal.z>.isim>
dtext 310 <dlocal.x> 023a <eval <db.row.<dlocal.z>.toplampara> / 1000> K
dtext 430 <dlocal.x> 023a <db.row.<dlocal.z>.aktifsure> saat
ctag0.bakalim <eval <db.row.<dlocal.3>.toplampara>>
endif
endfor
//button 240 410 9909 9911 1 0 1
//button 290 410 9903 9905 1 0 2
//button 30 410 4006 4007 1 0 3
//dtext 310 410 09b Ileri
button 240 410 4015 4016 1 0 1
button 290 410 4006 4007 1 0 2
button 30 410 4012 4013 1 0 3
dtext 200 410 09b Geri
dtext 330 410 09b Ileri
dtext 65 410 09b Satis Yap
[dialog d_seller_menu button]
on=0
src.sysmessage @0810 Satis Menusu Kapandi...
on=1
if <ctag.anasayfa> > 0
ctag.anasayfa -=15
endif
sdialog d_seller_menu
return 1
on=2
ctag.anasayfa +=15
sdialog d_seller_menu
return 1
on=3
targetf=muro_satis
src.sysmessage @07ad Neyi Satacaksin?
[chardef c_tuccar_muro]
defname c_tuccar_muro
name Tuccar Muro
id c_man
desires=i_gold,t_wand,t_reagent,t_bone
tspeech=tuccarmuro
tspeech=spk_human_prime
tspeech=spk_human_default
on=@click
message @0812 <name>
return 1
on=@dclick
if (<distance><=3)
src.seller
return 1
else
src.sysmessage @07ad Biraz yakasin lutfen...
return 1
endif
return 1
On=@Create
npc 1
str 500
dex 0
int 0
stam 0
invul 1
color=0841c
speechcolor=0810
food=500
taming={1000.5 1000.6}
itemnewbie=i_robe
color=0812
itemnewbie=i_hair_short
color=01
itemnewbie=i_beard_short_med
color=01
itemnewbie=i_torch_lit
color=0812
[function muro_satis]
if !(<argo.topobj.uid> == <src.uid>
sysmessage @0810 Uzerinizde olan itemleri alabilirim...
elseif !(<argo.isitem>
sysmessage @0810 Alabilecegim turden bir esya degil...
elseif (<argo.type> == t_gold)
sysmessage @0810 Para karsiligi item satmiyorum.Item karsiligi para veriyorum...
elseif (<argo.baseid> == i_backpack)
sysmessage @0810 Cantanizi satarsaniz siz ne yapacaksiniz?
elseif (<argo.attr>&attr_newbie)
sysmessage @0810 Prensip geregi newbie esyalari alamiyorum...
elseif !(<argo.value>)
sysmessage @0810 Bes para etmez itemleri satmaya utanmiyormusun?..
elseif (<eval <argo.amount>> > 20000)
sysmessage @0810 Bir seferde 20.000 adet maldan fazlasini alamam...
elseif (<eval <argo.value>*<argo.amount>> > 4000000)
sysmessage @0810 Bir seferde 4m'den fazla tutan mal alislarini yapmiyorum...
return 1
else
paramiz <eval <argo.value>*<argo.amount>>
sysmessage @0810 Mallariniza <eval <argo.value>*<argo.amount>> altin verdim...
ctag.mipara <eval <argo.value>*<argo.amount>>
tag.mypara <eval <ctag0.mipara>+<tag0.mypara>>
var.toppara <eval <ctag0.mipara>+<var0.toppara>>
src.guncelle
targetf=muro_satis
obj=<argo.uid>
obj.remove
endif
[speech tuccarmuro]
on=*sell*
src.seller
On=*sat*
src.seller
On=*|EL-Kaide|*
say @0810 EL-Kaide Agam Hos Geldin
On=*Muro*
say @07ad Li li li li li li li
[FUNCTION paramiz]
if (<args> > 0)
serv.newitem i_gold
if (<args> > 65000)
new.amount=65000
new.bounce
paramiz <eval <args>-<new.amount>>
else
new.amount=<args>
new.bounce
endif
endif
Sunucuda seller vendoruna satış yapan playerların en çok satandan itibaren gösterebileceğiniz bir tüccar sistemidir.Ayrıca Tüccar Muro&裟nun Server toplamında nekadarlık alış yaptığını, sizden nekadarlık mal aldığını da göstermektedir.
oyun içerisinde;
.seller_sistem_kurulum komutunu göndermeniz
c_tuccar_muro npc&裟sini çıkartmanız kafidir. (istediğiniz kadar vendor koyabilirsiniz
)
(ileri, geri butonlarının gözükmemesi hatası giderildi)
Bu konu |ZagoR| tarafından düzenlendi(2008-05-19 19:58, 15 yıl önce)
