Sen sagol slothere'ninde duzenledigi bir page sistemi var onuda eklersin gercekten yarari dokunur..
//////////////////////////////////////////////////////////////////////////
// Yazan: _Epiletico_
// Düzenleyen & Türkçe Çeviri: Slothere
//////////////////////////////////////////////////////////////////////////
[defname page_sys]
//Some options
delete_after_msg 1 //Pageler silinince mesaj versinmi? (1 = yes | 0 = no)
queue_message 1 //.pag yazinca kaç page olduğunu göstersinmi?
//Dialog texts
dlg_text_titlet <serv.name> Page Sistemi //Title of tweak page
dlg_text_reason Gelen: //Gelen Page
dlg_text_delete Sil //Pageyi sil
dlg_text_Go_p_p Playere Git//Playerin Bulunduğu yere gitme.
dlg_text_Go_p_o Pagenin atildigi yere git //Pagenin atıldığı yere git
dlg_text_Pre_re Cevap Yolla //Cevap yollama
dlg_text_pag_ls Page Listesi //Page Listesi
dlg_text_your_p Sizin Pageniz: //Page e cevap verilirken playerin attığı mesaj
dlg_text_was_as Cevap: //Page e gelen cevap
dlg_text_by_who Yazan: //Kim yazmış?
dlg_text_mi_dlg Mesaj //gelen mesaj
dlg_text_ti_ela Time elapsed: //Ne kadar sürede mesaj geldiği.
dlg_text_wipe_p Tum pageleri silmek istediginize eminmisiniz? //Tüm mesajları silmek.
dlg_text_wipe_t Tumunu Sil //Mesajların tümünü silmek
dlg_text_descri Sorununuzu yaziniz.
//Message texts
msg_text_Color 1153 //Mesaj renkleri
MSG_text_del_all Tum pageleri sildiniz // Tümü silinince verilecek mesaj
msg_text_Page_del Page Silindi //Mesaj silinince verilecek mesaj.
msg_text_msg_sent Cevap yollandi //Cevap yollanınca verilecek mesaj.
msg_text_and_dele ve mesajiniz silindi. //üsttekinin devami(def.delete_after_msg = 1 açık olmalı.)
msg_text_no_pages Page bulunmuyor //page olmayınca gelen mesaj
msg_text_xx_pag_1 Hata; //Page bulunmayinca gelen mesajın başlangıcı,
msg_text_xx_pag_2 page bulunmaktadir //Page bulunmayinca gelen mesaj
//Part1 xxPages part2
//look down to more info
[plevel 2]
pag
[function pag]
tag0.page=
if (<serv.gmpages>)
sdialog d_page
IF (<def.queue_message>)
sysmessage @<def.msg_text_Color> <def.msg_text_xx_pag_1> <eval <serv.gmpages>> <def.msg_text_xx_pag_2>
endif
Else
sysmessage @<def.msg_text_Color> <def.msg_text_no_pages>
endif
[dialog d_page]
200,50
local.b=0
nomove
resizepic 20 20 3600 370 420
for 0 3
IF (<ispage <tag0.page>+<local._for>>)
button 40 <eval 50+(<local._for>*90)> 4005 4006 1 0 <eval <local._for>+1>
dhtmlgump 75 <eval 50+(<local._for>*90)> 300 80 1 1 <serv.gmpage.<eval (<local._for>+<tag0.page>)>.account> <def.bfont_lred>[<def.u><uid.<STRARG <serv.gmpage.<eval (<local._for>+<tag0.page>)>.reason>>.name><def.ue>]<def.bfont_black> : <STREAT <serv.gmpage.<eval (<local._for>+<tag0.page>)>.reason>>
local.b += 1
endif
endfor
IF (<local.b> == 4) && (<serv.gmpages> >= 5)
button 350 408 4005 4006 1 0 5
endif
IF !(<tag0.page> == 0)
button 30 408 4014 4015 1 0 6
endif
Button 150 408 4026 4027 1 0 7
dhtmlgump 181 411 200 20 0 0 <def.bfont_white><def.dlg_text_wipe_t>
[dialog d_page button]
on=1 4
tag.pages=<Eval <argn1>+<tag0.page>-1>
//sysmessage @03b2 Tweaking: <serv.gmpage.<tag.pages>.account> //test if script have bad section
sdialog d_page_tweak
on=5
tag0.page += 4
IF <tag0.page> > <serv.gmpages>
tag.page=<serv.gmpages>
endif
sdialog d_page
on=6
tag.page -= 4
IF <tag0.page> < 0
tag0.page=0
endif
sdialog d_page
on=7
sdialog d_page_wipe
[DIALOG d_page_tweak]
190,40
NOMOVE
page 0
resizepic 31 20 3600 370 472
dhtmlgump 45 33 340 20 0 0 <def.bfont_white><def.center><def.dlg_text_titlet>
dhtmlgump 130 100 248 100 1 1 <STREAT <serv.gmpage.<tag.pages>.reason>>
dtext 80 100 1152 <def.dlg_text_reason>
dtext 80 210 1152 <def.dlg_text_delete>
dtext 80 233 1152 <def.dlg_text_go_p_p>
dtext 80 256 1152 <def.dlg_text_go_p_o>
gumppictiled 89 329 290 109 3004
dtext 80 303 1152 <def.dlg_text_pre_re>
button 48 209 4005 4006 1 0 1
button 48 232 4005 4006 1 0 2
button 48 255 4005 4006 1 0 3
//dtext 80 278 1152 <def.dlg_text_handle>
//button 48 278 4005 4006 1 0 6
button 48 302 4005 4006 1 0 4
dtext 80 450 1152 <def.dlg_text_pag_ls>
button 48 449 4011 4002 1 0 5
dtextentry 92 332 283 102 0 1
[DIALOG d_page_tweak button]
ON=0
tag.page=
tag.pages=
pag
ON=1
try gmpage.<eval <tag0.pages>>.handle
try gmpage.<eval <tag0.pages>>.d
tag.page=
sysmessage @<def.msg_text_Color> <def.msg_text_page_del>
ON=2
go <uid.<STRARG <serv.gmpage.<eval <tag0.pages>>.reason>>.p>
tag.page=
ON=3
GO <serv.gmpage.<eval <tag0.pages>>.p>
tag.page=
ON=4
try serv.account.<serv.gmpage.<eval <tag0.pages>>.account>.tag.resposta = <argtxt[1]>
try serv.account.<serv.gmpage.<eval <tag0.pages>>.account>.tag.gmpage = <serv.gmpage.<eval <tag0.pages>>.reason>
try serv.account.<serv.gmpage.<eval <tag0.pages>>.account>.tag.responsavel = <name><def.br><def.br><def.bfont_black><def.dlg_text_ti_ela> <def.bfont_red><timeformat 1,<eval <serv.gmpage.<eval <tag0.pages>>.time>>>
trysrc <STRARG <serv.gmpage.<eval <tag0.pages>>.reason>> sdialog d_recebe_page
F_LOGIN_page <serv.gmpage.<eval <tag0.pages>>.account>
IF (<def.delete_after_msg>)
try gmpage.<eval <tag0.page>>.handle
try gmpage.<eval <tag0.page>>.d
endif
sysmessage @<def.msg_text_Color> <def.msg_text_msg_sent> <qval (<def.delete_after_msg>) ? <def.msg_text_and_dele> :>
tag.pages=
ON=5
tag.page=
tag.pages=
pag
//on=6
[function ispage]
IF !(STRCMP("<serv.gmpage.<eval <args>>.status>","0"))
return "0"
else
return "1"
endif
[FUNCTION find_page]
FOR 0 <eval <serv.clients>-1>
IF (<serv.CLIENT.<LOCAL._FOR>>)
IF (STRMATCH("<args>","<serv.client.<eval <local._for>>.name>"))
OBJ=<serv.client.<eval <local._for>>.uid>
ENDIF
ENDIF
ENDFOR
IF !(<OBJ> == 00)
IF (<OBJ.ISONLINE>)
trysrc <OBJ> sdialog d_recebe_page
ENDIF
obj=0
ENDIF
[function alphablack]
gumppictiled <argv[0]> <argv[1]> 2624 <argv[2]> <argv[3]>
checkertrans <argv[0]> <argv[1]> <argv[2]> <argv[3]>
[DIALOG d_recebe_page]
20,20
NOMOVE
page 0
resizepic 15 15 3600 100 84
gumppictiled 26 26 22 60 3504
gumppictiled 27 27 20 58 2624
button 27 28 2002 2002 1 0 1
dhtmlgump 48 45 80 20 0 0 <def.bfont_white><def.dlg_text_mi_dlg><def.bfonte>
[DIALOG d_recebe_page button]
ON=1
sdialog d_ler_page_recebida
[DIALOG d_ler_page_recebida]
0,0
NOMOVE
NOCLOSE
page 0
resizepic 82 122 3600 606 203
dhtmlgump 99 141 571 138 1 1 <def.bfont_red><src.name><def.bfont_black>, <def.dlg_text_your_p> <def.bfont_blue><STREAT <src.account.tag.gmpage>><def.bfont_black><def.br> <def.dlg_text_was_as> <def.bfont_red><src.account.tag.resposta><def.br><def.br><def.bfont_black><def.dlg_text_by_who> <def.bfont_red><src.account.tag.responsavel>
button 347 295 247 248 1 0 1
[DIALOG d_ler_page_recebida button]
ON=1
src.account.tag.resposta=
src.account.tag.gmpage=
src.account.tag.responsavel=
F_LOGIN_page_del <src.account>
src.sysmessage @<def.msg_text_Color> <def.msg_text_page_del>
[FUNCTION F_LOGIN_page]
FOR 0 <EVAL <SERV.ACCOUNT.<ARGS>.CHARS>-1>
local.uid=<SERV.ACCOUNT.<ARGS>.CHAR.<EVAL <LOCAL._FOR>>.UID>
try uid.<local.uid>.events +e_page
ENDFOR
[events e_page]
on=@login
IF !(STRMATCH("<account.tag0.resposta>","0"))
sdialog d_recebe_page
endif
[FUNCTION F_LOGIN_page_del]
FOR 0 <EVAL <SERV.ACCOUNT.<ARGS>.CHARS>-1>
local.uid=<SERV.ACCOUNT.<ARGS>.CHAR.<EVAL <LOCAL._FOR>>.UID>
try uid.<local.uid>.events -e_page
ENDFOR
[FUNCTION TIMEFORMAT]
IF (<ARGN2> > 86400)
LOCAL.TIME <EVAL <ARGN2>/86400>d <EVAL <EVAL <ARGN2>%86400>/3600>h <EVAL <EVAL <EVAL <ARGN2>%86400>%3600>/60>m <EVAL <EVAL <EVAL <ARGN2>%86400>%3600>%60>s
ELSEIF (<ARGN2> > 3600)
LOCAL.TIME <EVAL <ARGN2>/3600>h <EVAL <EVAL <ARGN2>%3600>/60>m <EVAL <EVAL <ARGN2>%3600>%60>s
ELSEIF (<ARGN2> > 60)
LOCAL.TIME <EVAL <ARGN2>/60>m <EVAL <ARGN2>%60>s
ELSE
LOCAL.TIME <ARGN2>s
ENDIF
RETURN <LOCAL.TIME>
[DIALOG d_page_wipe]
250,250
NOMOVE
page 0
resizepic 0 0 3600 273 138
dhtmlgump 5 7 263 100 1 1 <def.dlg_text_wipe_p>
button 205 109 247 248 1 0 1
button 141 109 241 241 1 0 2
[DIALOG d_page_wipe text]
<def.dlg_text_wipe_p>
[DIALOG d_page_wipe button]
ON=1 //OKAY - delete
FOR 0 <eval <serv.gmpages>-1>
try gmpage.<local._for>.handle
try gmpage.<local._for>.d
ENDFOR
sysmessage @<def.msg_text_Color> <def.dlg_text_del_al>
ON=2 //CANCEL
src.pag
[function f_player_page]
sDIALOG d_page_send
[DIALOG d_page_send]
0,0
page 0
resizepic 79 136 3600 581 168
gumppictiled 91 169 554 121 9354
dtext 95 142 1152 <def.dlg_text_descri>
dtextentry 98 175 540 108 0 0
button 326 296 247 248 1 0 1
[DIALOG d_page_send button]
ON=0
helppage
ON=1
if (strmatch('<argtxt[0]>',''))
f_player_page
src.sysmessage Bos mesaj yollayamazsiniz
return 1
endif
gmpage add <uid> <argtxt[0]>
Sadece help menusunde page yerine
" src.f_player_page " yazmaniz yeterli..
