Üye ol    Giriş
  1. Forumlar
  2. Oyunlar
  3. Ultima Online
  4. Sphere Scripting
  5. Moongatemi daha çok kısaltabilecek olan varsa sevinirim...

Moongatemi daha çok kısaltabilecek olan varsa sevinirim...

xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
Bu moongateyi kısalta bilirseniz sevinirim...

//***************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2009
// TARİH: 03.07.2009
// SAAT : 17:54
// KONU : Işınlanma Kapısı Versiyon v 01 (Moongate Versiyon 4)
//***************************************
VERSION:0.56b

[Defname isinlanmakapisi]
gate_1=Britain moongate		// Britain Moongate
gate_2=2728,2133		// Bucaneers Den Moongate
gate_3=2497,1123,5		// Cove Moongate
gate_4=5351,4025,47		// Delucia Moongate
gate_5=Jhelom moongate		// Jhelom Moongate
gate_6=Magincia moongate	// Magincia Moongate
gate_7=Minoc-Vesper moongate	// Minoc Moongate
gate_8=Moonglow moongate	// Moonglow Moongate
gate_9=3520,1106,20		// Njuhelm Moongate
gate_10=3704,2724,23		// Occlo Moongate
gate_11=2772,3518		// Serpents Hold Moongate
gate_12=Skara Brae moongate	// Skara Brae Moongate
gate_13=Trinsic moongate	// Trinsic Moongate
gate_14=Minoc-Vesper Moongate	// Vesper Moongate
gate_15=Yew moongate		// Yew Moongate

[Dialog d_moongate_V4]
-297,-126
Move
resizepic 297 125 2620 250 480
dtext 322 136 47 Moongate V4
button 316 573 4006 4007 1 0 0
button 316 173 4006 4007 1 0 1
button 316 198 4006 4007 1 0 2
button 316 223 4006 4007 1 0 3
button 316 248 4006 4007 1 0 4
button 316 273 4006 4007 1 0 5
button 316 298 4006 4007 1 0 6
button 316 323 4006 4007 1 0 7
button 316 348 4006 4007 1 0 8
button 316 373 4006 4007 1 0 9
button 316 398 4006 4007 1 0 10
button 316 423 4006 4007 1 0 11
button 316 448 4006 4007 1 0 12
button 316 473 4006 4007 1 0 13
button 316 498 4006 4007 1 0 14
button 316 523 4006 4007 1 0 15
dtext 350 175 920 Britain
dtext 350 200 920 Bucaneers Den
dtext 350 225 920 Cove
dtext 350 250 920 Delucia
dtext 350 275 920 Jhelom
dtext 350 300 920 Magincia
dtext 350 325 920 Minoc
dtext 350 350 920 Moonglow
dtext 350 375 920 Njuhelm
dtext 350 400 920 Occlo
dtext 350 425 920 Serpents Hold
dtext 350 450 920 Skara Brae
dtext 350 475 920 Trinsic
dtext 350 500 920 Vesper
dtext 350 525 920 Yew
dtext 350 575 920 Iptal

[Dialog d_moongate_V4 TEXT]

[Dialog d_moongate_V4 BUTTON]
On=0
src.findid.i_tektiklama.remove
return 1

On=1 15
IF ( <eval <distance>> < 3 )
src.tag.git=<def.gate_<dargn>>
src.f_git
return 1
else
src.hata Moongate'yi kullanabilmek icin yakin olmalisiniz.
return 1
endif

[Function f_git]
if (<src.findid.i_rune_poison>)
src.hata Uzerinizde zehir varken moongate kullanamazsiniz.
return 1
elseif (<src.hits> < <src.str>)
src.hata Yaraliylen moongate kullanamazsiniz.
return 1
ELSE
src.go <src.tag.git>
src.findid.i_tektiklama.remove
return 1
endif

[Itemdef i_moongate_v4]
Defname=i_moongate_v4
Id=i_moongate_gray
Name=Moongate
Type=t_normal

On=@Create
Color=00
Attr=Attr_static

On=@Click
message @75 [ <serv.name> ]
message @55 ( <region.name> )
message @95 <name>
return 1

On=@Dclick
if (<distance> < 3)
	if (<src.findid.i_tektiklama>)
	src.hata Moongate'yi sadece bir kere acabilirsiniz.
	return 1
	else
	sdialog d_moongate_v4
	src.newitem i_tektiklama
	src.act.bounce
	return 1
	endif
else
src.hata Moongate'yi kullanabilmek icin daha yakin olmalisiniz.
return 1
endif

On=@Step
if (<distance> < 3)
	if (<src.findid.i_tektiklama>)
	src.hata Moongate'yi sadece bir kere acabilirsiniz.
	return 1
	else
	sdialog d_moongate_v4
	src.newitem i_tektiklama
	src.act.bounce
	return 1
	endif
else
src.hata Moongate'yi kullanabilmek icin daha yakin olmalisiniz.
return 1
endif

[itemdef i_tektiklama]
Id=i_gold
Name=Tek Tiklama

On=@Create
AttR=attr_invis|attr_decay
[EOF]

Bu ardada src.hata functionunu ve renkleri göndereyide sorun olmasın

bu sphere_new_functions.scp
//*************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2009
// TARİH: 05.07.2009
// SAAT : 01:04
// KONU : Yeni Fonksiyonlar
//*************************************
Version:0.56b

[Function hata]
src.sysmessage @026 <args>
return 1

[Function np]
src.sysmessage @75 <args>
return 1

[Function duyuru]
serv.allclients sysmessage @048 <args>
return 1

[Function serv.hata]
serv.allclients sysmessage @026 <args>
return 1

[Function soru]
src.sysmessage @055 <args>
return 1

[Function tekraryap]
src.makeitem=<src.tag.craft>
return 1

[Function yapim]
src.makeitem <args>
src.tag.craft <args>
return 1

buda sphere_new_defs.scp
//************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2009
// TARİH: 03.07.2009
// SAAT : 21:53
// KONU : Sphere New Defnames
//************************************
VERSION:0.56b

[Defname Renkler]
Beyaz            047e
Kirmizi          066d
Sari             0501
Turuncu          054d
Mor              04fa
Yesil            048f
Mavi             04f2
Pembe            04fc
Kahverengi       0612
Gri              0763
Lacivert         0454
Siyah            0001
Ozel             0508
Ozel2            0494

[EOF]

üff amma fazlaymış buda gates.scp

//************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2009
// TARİH: 03.07.2009
// SAAT : 21:53
// KONU : Renkli Moongate
//************************************
VERSION:0.56b

//Yellow Moongate

[Itemdef i_moongate_yellow]
Defname=i_moongate_yellow
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=sari

//Gray Moongate

[Itemdef i_moongate_gray]
Defname=i_moongate_gray
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=gri

//Green Moongate

[Itemdef i_moongate_green]
Defname=i_moongate_green
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=yesil

//Purple Moongate

[Itemdef i_moongate_purple]
Defname=i_moongate_purple
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=mor

//Orange Moongate

[Itemdef i_moongate_orange]
Defname=i_moongate_orange
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=turuncu

//White Moongate

[Itemdef i_moongate_white]
Defname=i_moongate_white
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=beyaz

//Pink Moongate

[Itemdef i_moongate_pink]
Defname=i_moongate_pink
Id=i_moongate_red
Name=Moongate
Type=t_telepad

On=@create
Color=pembe

[EOF]
  • 2009-07-05 13:55
  • #1
Basic
Basic
Expert
4
naabtın sen :D bak nemesisin bi moongate scripti var scriptlerin içinde optimize edilmiş falan diye ararsan çıkar.

o scriptte var. yazan yeri local. yaparsan çok tatlı bişey oluyo. Tek sorunu var kullanması orda.
  • 2009-07-05 15:29
  • #2
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
yok istemiyorum onu ben çok karışık çıkıamıyorum sen sen son 3 scp ye odaklanma onlar moongate ile bağımsız :D onlar genel yani src.sysmessage @026 yerine src.hata gibi :P her scp de kullanılıyor onlar :D
  • 2009-07-05 15:56
  • #3
Basic
Basic
Expert
4
ben bunu kısaltacam sonra nemesisinkinin aynısı olcak sen yine içinden çıkamıyorum diycen
  • 2009-07-05 16:15
  • #4
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
Basic sayesinde bu hale getirdik

//***************************************
// YAZAR: xwerswoodx
// YAPIM: Hamit Devecioğlu (c)2003-2009
// TARİH: 03.07.2009
// SAAT : 17:54
// KONU : Işınlanma Kapısı Versiyon v 01 (Moongate Versiyon 4)
//***************************************
VERSION:0.56b

[Defname isinlanmakapisi]
gatetoplam=15
gate_1=1337,1997,5		// Britain Moongate
location_1=Britain
gate_2=2729,2133		// Bucaneers Den Moongate
location_2=Bucaneers Den
gate_3=2481,1122,5		// Cove Moongate
location_3=Cove
gate_4=5352,4025,47		// Delucia Moongate
location_4=Delucia
gate_5=1500,3772,5		// Jhelom Moongate
location_5=Jhelom
gate_6=Magincia moongate	// Magincia Moongate
location_6=Magincia
gate_7=Minoc-Vesper moongate	// Minoc Moongate
location_7=Minoc
gate_8=Moonglow moongate	// Moonglow Moongate
location_8=Moonglow
gate_9=3521,1106,20		// Njuhelm Moongate
location_9=Njuhelm
gate_10=3705,2724,23		// Occlo Moongate
location_10=Occlo
gate_11=2773,3518		// Serpents Hold Moongate
location_11=Serpents Hold
gate_12=Skara Brae moongate	// Skara Brae Moongate
location_12=Skara Brae
gate_13=Trinsic moongate	// Trinsic Moongate
location_13=Trinsic
gate_14=Minoc-Vesper Moongate	// Vesper Moongate
location_14=Vesper
gate_15=Yew moongate		// Yew Moongate
location_15=Yew

[Dialog d_moongate_V4]
-297,-126
Move
resizepic 297 125 2620 250 480
//resizepic 297 125 3500 250 480
dtext 322 136 47 Moongate V4
dtext 350 575 920 Iptal
button 316 573 4006 4007 1 0 0

local.x 173
for 1 15
button 316 <eval <local.x>> 4006 4007 1 0 <dlocal._for>
local.x +=25
endfor

local.z 175
for 1 15
dtext 350 <dlocal.z> 920 <def.location_<dlocal._for>>
local.z +=25
endfor

[Dialog d_moongate_V4 TEXT]

[Dialog d_moongate_V4 BUTTON]
On=0
src.findid.i_tektiklama.remove
return 1

On=1 15
IF ( <eval <distance>> < 3 )
	if (<src.findid.i_rune_poison>)
	src.hata Uzerinizde zehir varken moongate kullanamazsiniz.
	return 1
	elseif (<src.hits> < <src.str>)
	src.hata Yaraliylen moongate kullanamazsiniz.
	return 1
	ELSE
	src.go <def.gate_<dargn>>
	src.np <def.location_<dargn>> Sehrine Hos Geldiniz.
	src.findid.i_tektiklama.remove
	return 1
	endif
else
src.hata Moongate'yi kullanabilmek icin yakin olmalisiniz.
src.findid.i_tektiklama.remove
return 1
endif

[Itemdef i_moongate_v4]
Defname=i_moongate_v4
Id=i_moongate_gray
Name=Moongate
Type=t_normal

On=@Create
Color=00
Attr=Attr_static

On=@Click
message @75 [ <serv.name> ]
message @55 ( <region.name> )
message @95 <name>
return 1

On=@Dclick
if (<distance> < 3)
src.moongate
return 1
else
src.hata Moongate'yi kullanabilmek icin daha yakin olmalisiniz.
return 1
endif

On=@Step
Dclick
src.move 1
return 1

[Function moongate]
if (<src.findid.i_rune_poison>)
src.hata Uzerinizde zehir varken moongate kullanamazsiniz.
return 1
elseif (<src.hits> < <src.str>)
src.hata Yaraliylen moongate kullanamazsiniz.
return 1
elseif (<src.findid.i_tektiklama>)
src.hata Sadece bir kere acabilirsiniz.
return 1
else
sdialog d_moongate_v4
src.newitem i_tektiklama
src.act.bounce
return 1
endif

[itemdef i_tektiklama]
Id=i_gold
Name=Tek Tiklama

On=@Create
Attr=attr_invis|attr_decay
[EOF]

hadi yokmu arttıran pardon azaltan :P
  • 2009-07-05 18:12
  • #5
Slothere
Slothere
Master
59.2997
Böyle daha tatlı oldu sanırım.


[Defname isinlanmakapisi]
gate1 1336,1997,5
gate2 2702,692,5
gate3 3564,2140,34
gate4 4467,1283,5
gate5 1498,3772,5
gate6 771,751,5
gate7 1828,2948,-20
gate8 643,2067,5

[Dialog d_moongate_V4]
0,0

resizepic 297 125 2620 250 250
dtext 322 136 47 Moongate V4

for 1 8
  button 316 <eval (<local._for> * 20) + 170> 4006 4007 1 0 <dlocal._for>
  dtext 355 <eval (<local._for> * 20) + 170> 920 <serv.map(<def.gate<dlocal._for>>,0).region.name>
endfor

[Dialog d_moongate_V4 BUTTON]
On=1 8
if (<distance <src>> > 3)
  src.sysmessage moongate'e yeterince yakin deilsin.
elif (<src.hits> < <src.maxhits>) || (<src.flags> & statf_poisoned)
  src.sysmessage yarali veya zehirlisin.
else
  src.go <def.gate<dargn>>
  src.sysmessage <serv.map(<def.gate<dargn>>,0).region.name>'e hosgeldiniz.
endif
return 1

[Itemdef i_moongate_v4]
Id=i_moongate_gray
Name=Moongate
Type=t_normal

On=@Create
Color=00
Attr=Attr_static

On=@Click
message @75 [ <serv.name> ]
message @55 ( <region.name> )
message @95 <name>
return 1

On=@Dclick
if (<distance <src>> > 3)
  src.sysmessage uzaktasin.
elif (<src.hits> < <src.maxhits>) || (<src.flags> & statf_poisoned)
  src.sysmessage yarali veya zehirlisin.
else
    sdialog d_moongate
endif
return 1

On=@Step
dclick
return 1

[EOF]
  • 2009-07-06 02:43
  • #6
xwerswoodx üyesi avatar
xwerswoodx
Expert
5.4
Sabırla bekliyorum :D:D sen anladın :D
  • 2009-07-06 04:22
  • #7

Üye Ol veya Giriş Yap

Bu forum başlığına mesaj atmak istiyorsanız hemen üye olun veya giriş yapın.

Discord ile Bağlan
Twitch ile Bağlan
Steam ile Bağlan
Google ile Bağlan