selamun aleyküm arkadaşlar, Çok ugraştım yapamadım ve forumlarada baktım taming sorununu düzeltemedim sorun şudur; mesela ahmetle mehmet shireye tame basıyor ahmeti kabul ediyor shire ve biniyor inince veya ölünce shire boşta kalıyor shire mehmetide kabul etmişti ve mehmet biniyor bu sorunu nasıl düzeltebilirim. [ve yell geçiyor mehmetin kabul ettigi de ahmetin kabul ettigide iki kere yell geçiyor scp]
yardımlarınızı bekliyorum arkadaşlar..
tşk ederim..
[ITEMDEF i_staff_taming]
ID=i_staff_gnarled
NAME=taming staff
TYPE=t_weapon_mace_staff
VALUE=290
TWOHANDS=Y
LAYER=2
WEIGHT=10
DAM=5,10
On=@Create
color 0454
attr 04
more2 0
timer -1
hitpoints 5
on=@click
message @0 <name>
attr 04
return 1
On=@DClick
if (<topobj.uid> != <src.uid>)
src.sysmessage @95,,1 Bunu kullanabilmeniz icin uzerinizde olmali.
elseif (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @95,,1 Gizlenmis durumdayken bunu kullanamazsiniz.
elseif (<src.targ.region.defname> == a_townZoo)
src.sysmessage @95,,1 Bu bolgede taming yasaktir.
elseif (<timer> == -1)
equip
attr 04
target @95,,1 Hangi hayvani evcillestirmek istiyorsunuz?
endif
return 1
On=@UnEquip
more2 0
timer -1
link -1
src.events -e_taming_f
On=@Timer
cont.tag.animalaway=0
cont.tag.hayvanx=<link.p.x>
cont.tag.hayvany=<link.p.y>
cont.distcheck
if (0<cont.tag.animalaway>)
cont.events -e_taming_f
more2 0
//cont.say taz ownz!
return 1
endif
if (<link.memoryfindtype.memory_ispawned.link.uid>)
if (<link.distance <link.memoryfindtype.memory_ispawned.link.uid>> > 3)
cont.sysmessage @56,,1 Bu hayvan yuvasindan uzakta..
cont.events -e_taming_f
link -1
return 1
endif
endif
if (<cont.flags>&statf_hidden) || (<cont.flags>&statf_invisible)
cont.sysmessage @56,,1 Gizlenmis durumdayken evcillestirme yapamazsiniz...
cont.events -e_taming_f
action -1
link -1
return 1
endif
if (<more2> < 6)
dorand 10
cont.sayua 666,0,0,trk Gel <link.name>, gel..
cont.sayua 666,0,0,trk Sana zarar vermeyecegim <link.name>..
cont.sayua 666,0,0,trk Sakin ol, <link.name>.
cont.sayua 666,0,0,trk Her zaman senin gibi bir <link.name> sahibi olmak istemistim..
cont.sayua 666,0,0,trk Cok tatlisin, <link.name>.
cont.sayua 666,0,0,trk Gel bir tanem, gel canim..
cont.sayua 666,0,0,trk Seni incitmeyecegim, <link.name>.
cont.sayua 666,0,0,trk Arkadasin olmak istiyorum.
cont.sayua 666,0,0,trk Gel <cont.sex babana/annene>, <link.name>.
cont.sayua 666,0,0,trk Gel <link.name>, gel <cont.sex babana/annene>.
enddo
dorand 2
cont.anim 17
cont.anim 19
enddo
timer 2
more2 (<more2> + 1)
return 1
endif
more2 0
if !(<link.npc> == 1)
cont.sysmessage @95,,1 Bunu evcillestiremezsiniz.
return 1
endif
if (rand(100) < 75)
if (<link.memoryfindtype.memory_ispawned>)
link.memoryfindtype.memory_ispawned.remove
endif
link.food 50
link.karma -50
link.memorydel <cont.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <cont.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
CONT.events -e_taming_f
cont.sysmessage @07a1,,1 <link.name> sizi sahibi olarak kabul etti.
serv.allclients sysmessage @038,,1 <link.name>, <cont.name> tarafindan <region.name> civarlarinda ehcillestirilmistir..
if ((<cont.skilllock[35]> == 0) && (<cont.skilltotal> < 800.0))
if (<cont.taming> < 30.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 50.0)
if (rand(1) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 75.0)
if (rand(4) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 100.0)
if (rand(8) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.tag0.override.skillcap_35> > 100.0)
if (<cont.taming> < <cont.tag0.override.skillcap_35>)
if (rand(3)==1)
cont.taming (<cont.taming> +1)
endif
endif
endif
endif
if ((<cont.skilllock[2]> == 0) && (<cont.skilltotal> < 800.0))
if (<cont.animallore> < 30.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 50.0)
if (rand(1) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 75.0)
if (rand(8) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 100.0)
if (rand(16) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.tag0.override.skillcap_2> > 100.0)
if (<cont.animallore> < <cont.tag0.override.skillcap_2>)
if (rand(3)==1)
cont.animallore (<cont.animallore> +1)
endif
endif
endif
endif
link.tag.tamer <cont.uid>
link -1
return 1
else
cont.sysmessage @38,6,1,1 Hayvani evcillestirmeyi basaramadiniz.
link -1
return 1
endif
return 1
On=@TargOn_Char
if !(<src.targ.region.defname> == a_townZoo)
if ((<src.targ.npc> == 1) && (<src.targ.id> != c_pv))
if !(<src.targ.canseelos>)
src.sysmessage @69,,1 Hayvana ulasamiyorsunuz.
elseif (<src.targ.distance> > 3)
src.sysmessage @1100,,1 Hayvana yeterince yakin degilsiniz.
elseif (<src.targ.memoryfindtype.memory_ipet>)
if (<src.targ.memoryfindtype.(memory_ipet|memory_guard).link> == <src.uid>)
src.sysmessage @07a1,,1 <src.targ.name> zaten size ait.
src.targ.flags <src.targ.flags>&statf_pet
else
src.sysmessage @95,,1 <src.targ.name> bir baskasina ait.
endif
elseif (<src.targ.memoryfindtype.memory_fight>)
src.sysmessage @1100,,1 Hayvan su an musait degil.
elseif (<src.targ.memoryfindtype.memory_war_targ.link> == <src.uid>)
src.sysmessage @95,,1 Hayvan su an size cok kizgin.
elseif (<src.targ.findid.i_rune_summon_creature>)
src.sysmessage @95,,1 Buyu ile yaratilmis hayvanlari evcillestirmezsiniz
elseif (0<src.targ.tag.tamer> == 0<src.uid>) // tamerlar elele bug-free dunyaya
src.sysmessage @95,,1 Hayvan artik sizi umursamiyor.
elseif (<src.taming> < <src.targ.taming>)
src.anim 19
src.sysmessage @95,,1 <src.targ.name> icin taming skilliniz yeterli degil. (gerekli skill: <src.targ.taming>)
elseif (<src.animallore> < <src.targ.animallore>)
src.anim 19
src.sysmessage @95,,1 <src.targ.name> icin animal lore skilliniz yeterli degil. (gerekli skill: <src.targ.animallore>)
else // tame etmeye ba$la...
link <src.targ.uid>
src.anim 19
timer 2
src.events +e_taming_f
endif
else
src.sysmessage @95,,1 Bunu evcillestiremezsiniz.
endif
else
src.sysmessage @95,,1 Bu bolgede taming yasaktir.
endif
return 1
On=@TargOn_Item
return 1
[EVENTS e_taming_f]
ON=@Hittry
IF (rand(2) =1)
SYSMESSAGE @95,,1 Konsantrasyonunuzu kaybettiniz, evcillestiremiyorsunuz.
//findlayer(2).skill fail
//findlayer(2).action - 1
EVENTS= -e_taming_f
findlayer(2).more2 0
findlayer(2).timer -1
findlayer(2).link -1
ENDIF
ON=@Death
findlayer(2).unequip
EVENTS= -e_taming_f
ON=@spelleffect
IF (rand(2) =1)
IF (<argn> == 1) || (<argn> == 3) || (<argn> == 5) || (<argn> == 8) || (<argn> == 12) || (<argn> == 18) || (<argn> == 20) || (<argn> == 27) || (<argn> == 30) || (<argn> == 31) || (<argn> == 37) || (<argn> == 38) || (<argn> == 39) || (<argn> == 42) || (<argn> == 43) || (<argn> == 46) || (<argn> == 47) || (<argn> == 49) || (<argn> == 51) || (<argn> == 53) || (<argn> == 55) || (<argn> == 57)
SYSMESSAGE @95,,1 Konsantrasyonunuzu kaybettiniz, evcillestiremiyorsunuz.
//src.findlayer(2).skill fail
//src.findlayer(2).action - 1
EVENTS= -e_taming_f
src.findlayer(2).more2 0
src.findlayer(2).timer -1
src.findlayer(2).link -1
ENDIF
ENDIF
[Itemdef i_hede]
name hodo
id i_handr_1
type t_eq_script
ON=@Equip
timer 0
ON=@Unequip
var.uzaklik <link.distance>
var.canseelos <link.canseelos>
ON=@Timer
attr attr_decay
remove
[Function kontroluzaklik]
newitem i_hede
act.link <argn>
act.cont <serial>
act.timer 0
[FUNCTION skillliste]
forchars 65100
if !(<npc>)
if (<account.plevel>==1)
if (<skilltotal> > 8000)
src.sysmessage <name>:<account> <skilltotal>
endif
endif
endif
end
forcharsidle 65100
if !(<npc>)
if (<account.plevel>==1)
if (<skilltotal> > 8000)
src.sysmessage <name>:<account> <skilltotal>
endif
endif
endif
end
[ITEMDEF i_staff_dragon]
ID=i_staff_gnarled
NAME=dragon taming staff
TYPE=t_weapon_mace_staff
VALUE=50
TWOHANDS=Y
LAYER=2
WEIGHT=10
DAM=5,10
FLIP=1
On=@Create
color 025
morez 05
more2 0
attr 04
hitpoints 5
On=@Click
if (<morex> > 0)
message [<eval <morez>> charges]
endif
On=@DClick
if (<morez> < 1)
src.sysmessage @0482 Staff kullanilamayacak derecede kadar eskimis...
return 1
endif
if (<src.taming> != 100.0)
src.sysmessage @0482 Bu staff'i kullanacak kadar bilgili degilsiniz.
return 1
endif
if (<more2> == 0)
target Hangi dragonu ehlillestirmek istiyorsunuz?
endif
return 1
On=@UnEquip
timer -1
On=@Timer
if (<more2> < 9)
if (<link.distance> > 3)
cont.sysmessage @0482 Dragona yeterince yakin degilsiniz.
return 1
elseif (<link.memoryfindtype.memory_ipet>)
cont.sysmessage @0482 <src.targ.name>, ugraslariniz sirasinda, baska biri tarafindan ehlilestirildi.
return 1
endif
dorand 10
cont.sayu Gel <link.name>, gel...
cont.sayu Sana zarar vermeyecegim <link.name>...
cont.sayu Sakin ol, <link.name>.
cont.sayu Her zaman senin gibi bir <link.name> sahibi olmak istemistim...
cont.sayu Cok tatlisin, <link.name>.
cont.sayu Gel bir tanem, gel canim..
cont.sayu Seni incitmeyecegim, <link.name>.
cont.sayu Arkadasin olmak istiyorum.
cont.sayu Gel <cont.sex babana/annene>, <link.name>.
cont.sayu Gel <link.name>, gel <cont.sex babana/annene>.
enddo
dorand 2
cont.anim 17
cont.anim 19
enddo
timer 2
more2 (<more2> + 1)
return 1
endif
more2 0
if (rand(100) < 75)
if <link.memoryfindtype.memory_ispawned>
link.memoryfindtype.memory_ispawned.remove
endif
link.karma 2500
link.memoryfindtype.memory_speak.color (memory_ipet|memory_guard)
link.memoryfindtype.(memory_ipet|memory_guard).name <cont.name>
link.memoryfindtype.(memory_ipet|memory_guard).link <cont.uid>
link.memoryfindtype.(memory_ipet|memory_guard).timer -1
link.flags <link.flags> & 08000000
cont.sysmessage @07a1,,1 <link.name> sizi sahibi olarak kabul etti.
morez (<morez> - 1)
link 04fffffff
else
cont.sysmessage @027 Hayvani ehlillestirmeyi basaramadiniz.
link 04fffffff
endif
return 1
On=@TargOn_Char
if (<src.targ.flags> == 024000000)
src.sysmessage @0482 Buyu ile yaratilmis hayvanlari ehlilestiremezsiniz.
src.action -1
return 1
endif
if !(<src.targ.region.defname> == a_townZoo)
if (<src.targ.npc> == 13)
if (<src.targ.distance> > 4)
src.sysmessage Hayvana yeterince yakin degilsiniz.
return 1
elseif (<src.targ.memoryfindtype.memory_ipet>)
src.sysmessage <src.targ.name> zaten ehlillestirilmis.
return 1
else
link <src.targ.uid>
src.anim 19
dorand 10
cont.sayu Gel <link.name>, gel <cont.sex babana/annene>...
cont.sayu Sana zarar vermeyecegim, <link.name>
cont.sayu Seni incitmeyecegim.
cont.sayu Her zaman senin gibi bir <link.name> aramistim.
cont.sayu Ne kadar sirinsin, <link.name>..
cont.sayu Neden bana oyle bakiyorsun, <link.name>?
cont.sayu Bana oyle bakma, <link.name>..
cont.sayu Seni yasadigim surece sevecegim, <link.name>.
cont.sayu Gel <cont.sex babana/annene>, <link.name>.
cont.sayu Gel <cont.sex babana/annene>.
enddo
timer 2
return 1
endif
else
src.sysmessage Bunu ehlillestiremezsiniz.
return 1
endif
else
src.sysmessage Bu bolgede taming yasaktir.
return 1
endif
On=@TargOn_Item
return 1
[function memorydel] // memory silen loop
if (0<args>
if (<findid.i_memory.link> == <args>
findid.i_memory.remove
memorydel <args>
endif
endif
[EOF]
