//////////Güncellendi By Michaell///////////////////////////////////////////////////
/////////Ultima-Strikenin Katkilariyla.www.ultima-strike.com///////////////////////
/////////Scplerle Ýlgili Sorunlar icin [email protected]////////////////////
/////////////////////////Michaell////////////////////////////////////////////////
///////////////Noxier(Ozgur)'e Yardimlari ve Destegi icin Cok Tesekkur Ederim.//
///////////////////////////////////////////////////////////////////////////////
[ITEMDEF i_deed_animal]
DEFNAME=i_deed_animal
NAME=pet trading contract
ID=i_deed
WEIGHT=20.0
TYPE=t_script
VALUE=50
CATEGORY=Custom Items
SUBSECTION=Deeds
DESCRIPTION=Animal Trading Contract
On=@Create
color 08ac
On=@Click
if (<more2>)
message @55 [<tag.trade>]
endif
message @96 [<name>]
return 1
On=@DClick
if (<topobj.uid> != <src.uid>)
src.sysmessage @033 Bunu kullanabilmeniz icin cantanizda olmali.
elseif (<more2>)
if (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @033 Gizlenmis durumdayken bunu kullanamazsiniz.
return 1
endif
try src.newnpc <tag.trade_id>
link <src.act.uid>
link.name <tag.trade_name>
link.karma <tag.trade_karma>
link.fame <tag.trade_fame>
link.str <tag.trade_str>
link.hits <tag.trade_str>
link.dex <tag.trade_dex>
link.int <tag.trade_int>
link.food <tag.trade_food>
link.color <color>
if (<link.color> == 0835)
link.color 0481
endif
link.oskin <link.color>
link.memorydel <src.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <src.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
link.update
link.anim 5
link.bark 3
remove
else
target
src.sysmessage @033 Kucultulecek hayvani secin.
endif
return 1
On=@TargOn_Item
smg Esyalari kucultemezsiniz
target
smg @033 Kucultulecek hayvani secin.
return 1
On=@TargOn_Char
if !(<src.targ.npc>)
src.sysmessage @033 Oyunculari kucultemezsiniz.
elseif !(<src.targ.ismypet>)
src.sysmessage @033 Bu hayvan size ait degil.
elseif (<src.targ.flags>&statf_stone) || (<src.targ.flags>&statf_freeze)
src.sysmessage @033 Hayvani su anki durumunda kucultemezsiniz.
elseif ((<src.targ.body> == c_man) || (<src.targ.body> == c_woman))
src.sysmessage @033 Sadece hayvanlari kucultebilirsiniz.
elseif (<src.targ.flags>&statf_invul) || (<src.targ.color> == 07fff)
src.sysmessage @033 Bu hayvani kucultemezsiniz.
elseif (<src.targ.memoryfindtype.memory_war_targ>)
src.sysmessage @033 Hayvan su anda cok kizgin.
elseif (<src.targ.findid.i_rune_summon_creature>)
src.sysmessage @033 Buyu ile yaratilmis hayvanlari kucultemezsiniz.
elseif ((<src.targ.id> == c_llama_pack) || (<src.targ.id> == c_horse_pack))
src.sysmessage @033 Pack hayvanlari kucultemezsiniz.
elseif (<src.targ.findid.i_rune_bless>) || (<src.targ.findid.i_rune_protection>) || (<src.targ.findid.i_rune_reactive_armor>) || (<src.targ.findid.i_rune_agility>) || (<src.targ.findid.i_rune_strength>)
src.sysmessage @033 Bu hayvanin uzerinde buyu var.
elseif (<src.targ.hits> < <src.targ.str>)
src.sysmessage @033 Bu hayvan yaralanmis.
elseif (<src.targ.findid.i_rune_poison>)
src.sysmessage @033 Bu hayvan zehirlenmis.
elseif !(<src.targ.canseelos>)
src.sysmessage @033 Hayvana ulasamiyorsunuz.
elseif (<src.targ.distance> > 3)
src.sysmessage @033 Hayvana yeterince yakin degilsiniz.
elseif (<src.targ.id> == c_m_golem_tinker1)
src.newitem i_pet_golem1
src.act.name <src.targ.name>
src.act.bounce
src.targ.remove
remove
elseif (<src.targ.id> == c_m_golem_tinker2)
src.newitem i_pet_golem2
src.act.name <src.targ.name>
src.act.bounce
src.targ.remove
remove
else
name filled pet trading contract
attr 00
more2 1
color <src.targ.color>
if (<color> == 0481)
color 0835
endif
tag.trade <src.targ.job>
tag.trade_id <src.targ.id>
tag.trade_name <src.targ.name>
tag.trade_str <src.targ.str>
tag.trade_dex <src.targ.dex>
tag.trade_int <src.targ.int>
tag.trade_karma <src.targ.karma>
tag.trade_fame <src.targ.fame>
tag.trade_food <src.targ.food>
src.targ.bark 2
src.targ.remove
src.sysmessage @055 <tag.trade>: kontrat haline getirildi.
endif
return 1
[ITEMDEF i_staff_taming] ///Tame Staff
ID=i_staff_gnarled
NAME=taming staff
TYPE=t_weapon_mace_staff
VALUE=254
TWOHANDS=Y
LAYER=2
WEIGHT=10
DAM=5,10
On=@Create
attr=04
color 2001
more2 0
timer -1
hitpoints 5
On=@DClick
Dispid=i_staff_gnarled
if (<topobj.uid> != <src.uid>)
src.sysmessage @33 Bunu kullanabilmeniz icin uzerinizde olmali.
elseif (<src.flags>&statf_hidden) || (<src.flags>&statf_invisible)
src.sysmessage @33 Gizlenmis durumdayken bunu kullanamazsiniz.
elseif (<src.targ.region.defname> == a_townZoo)
src.sysmessage @33 Bu bolgede taming yasaktir.
elseif (<timer> == -1)
target @55 Hangi hayvani ehlilestirmek istiyorsunuz?
endif
On=@UnEquip
more2 0
timer -1
link -1
On=@Timer
CONT.CHECKS <LINK.UID>
IF !(<VAR.SEE>)
CONT.sysmessage @33 Hayvan gorus alaninizdan cikti.
//cont.tag0.hayvangitti 01
more2 0
ELIF (<LINK.NPC> != brain_animal)
CONT.sysmessage @33 Bu Hayvani tame edemezsiniz.
more2 0
ELIF !(<LINK.TAMING>)
CONT.sysmessage @33 Bu Hayvani tame edemezsiniz.
more2 0
ELIF (<EVAL <CONT.TAMING>> < <LINK.TAMING>)
CONT.sysmessage @33 Bu hayvani tame edebilmek icin <act.taming> taming skilline ihtiyaciniz var!
more2 0
ELIF (<CONT.FLAGS> & (statf_dead|statf_freeze|statf_invisible|statf_sleeping|statf_polymorph|statf_stone|statf_hidden))
CONT.sysmessage @33 Su anki durumunuzda bu hayvani tame edemezsiniz.
more2 0
//cont.tag0.hayvangitti 01
ELIF (<LINK.MEMORYFINDTYPE.memory_ipet>)
CONT.sysmessage @33 Bu hayvan zaten tame edilmis.
more2 0
ELIF (<LINK.MEMORYFINDTYPE.memory_fight>)
CONT.sysmessage @33 Bu hayvan sinirli.
more2 0
ELIF (<VAR.DIST> > 5)
CONT.sysmessage @33 Hayvana yeterince yakin degilsiniz.
///cont.tag0.hayvangitti 01
LINK.TAG.LASTTAMER=0
more2 0
//ELIF (strmatch('<cont.tag0.hayvangitti>','01'))
//cont.tag0.hayvangitti 00
//link -1
//timer -1
//more2 0
//cont.sysmessage @33 Basarisiz Oldunuz...
//return 1
ELSE
if (<more2> < 6)
dorand 8
cont.say @0790 Gel <link.name>, gel..
cont.say @0790 Sana zarar vermeyecegim
cont.say @0790 Sakin ol, <link.name>.
cont.say @0790 Her zaman senin gibi bir <link.name> sahibi olmak istemistim..
cont.say @0790 Cok tatlisin, <link.name>.
cont.say @0790 Seni incitmeyecegim,
cont.say @0790 Arkadasin olmak istiyorum.
cont.say @0790 Gel <link.name>.
enddo
dorand 2
cont.anim 17
cont.anim 19
enddo
timer 2
more2 (<more2> + 1)
return 1
endif
more2 0
if !(<link.npc> == 1)
cont.sysmessage @33 Bunu ehlilestiremezsiniz.
return 1
endif
if (rand(100) < 75)
if (<link.memoryfindtype.memory_ispawned>)
link.memoryfindtype.memory_ispawned.remove
endif
link.karma -50
link.memorydel <cont.uid>
link.newitem i_memory
link.act.attr 04
link.act.more1 04
link.act.more2 <serv.time>
link.act.morep <link.p>
link.act.color memory_ipet
link.act.timer -1
link.act.link <cont.uid>
link.act.cont <link.uid>
link.flags <link.flags>&statf_pet
cont.sysmessage @55 uyari: <link.name> sizi sahibi olarak kabul etti.
if ((<cont.skilllock[35]> == 0) && (<cont.skilltotal> < 800.0))
if (<cont.taming> < 30.0)
if (rand(2) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 50.0)
if !(rand(4) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 80.0)
if !(rand(5) == 1)
cont.taming (<cont.taming> + 1)
endif
elseif (<cont.taming> < 100.0)
if (rand(6) == 1) // 24
cont.taming (<cont.taming> + 1)
endif
endif
endif
if ((<cont.skilllock[2]> == 0) && (<cont.skilltotal> < 800.0))
if (<cont.animallore> < 30.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 50.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 75.0)
if (rand(2) == 1)
cont.animallore (<cont.animallore> + 1)
endif
elseif (<cont.animallore> < 100.0)
if (rand(3) == 1)
cont.animallore (<cont.animallore> + 1)
endif
endif
endif
link.tag.tamer <cont.uid>
link -1
else
cont.sysmessage @33 Hayvani ehlillestirmeyi basaramadiniz.
link -1
endif
return 1
On=@TargOn_Char
if (<src.targ.id> == c_dummy) || (<src.targ.id> == c_heal_kas) || (<src.targ.id> == c_player_v) || (<src.targ.id> == c_tuccar) || (<src.targ.id> == c_spell_vendor) || (<src.targ.id> == c_whisper) || (<src.targ.id> == c_wizard)
src.sms Bunlari tame Edemezsiniz...
return 1
endif
if !(<src.targ.region.defname> == a_townZoo)
if ((<src.targ.npc> == 1) && (<src.targ.id> != c_player_v))
if !(<src.targ.canseelos>)
src.sysmessage @33 Hayvana ulasamiyorsunuz.
elseif (<src.targ.distance> > 3)
src.sysmessage @33 Hayvana yeterince yakin degilsiniz.
elseif (<src.targ.memoryfindtype.memory_ipet>)
if (<src.targ.memoryfindtype.(memory_ipet|memory_guard).link> == <src.uid>)
src.sysmessage @33 Hata:<src.targ.name> zaten size ait.
src.targ.flags <src.targ.flags>&statf_pet
else
src.sysmessage @33 Hata:<src.targ.name> bir baskasina ait.
endif
elseif (<src.targ.memoryfindtype.memory_fight>)
src.sysmessage @33 Hayvan su an musait degil.
more2 0
elseif (<src.targ.memoryfindtype.memory_war_targ.link> == <src.uid>)
src.sysmessage @33 Hayvan su an size cok kizgin.
more2 0
elseif (<src.targ.findid.i_rune_summon_creature>)
src.sysmessage @33 Buyu ile yaratilmis hayvanlari ehlilestiremezsiniz.
elseif (<src.targ.hits> < <src.targ.str>)
src.sysmessage @33 Bu Hayvan Yarali.
more2 0
elseif (0<src.targ.tag.tamer> == 0<src.uid>)
src.sysmessage @33 Hayvan artik sizi umursamiyor.
more2 0
elseif (<src.t.memoryfindtype.MEMORY_ISPAWNED.link.distance>>3)
src.sysmessage @33 Hayvan yuvasindan cok uzakta
more2 0
elseif (<src.taming> < <src.targ.taming>)
src.anim 19
src.sysmessage @33 Hata:<src.targ.name> icin taming skilliniz yeterli degil. (gerekli skill: <src.targ.taming>)
elseif (<src.animallore> < <src.targ.animallore>)
src.anim 19
src.sysmessage @33 Hata:<src.targ.name> icin animal lore skilliniz yeterli degil. (gerekli skill: <src.targ.animallore>)
else
link <src.targ.uid>
src.anim 19
timer 2
endif
else
src.sysmessage @33 Bunu ehlillestiremezsiniz.
endif
else
src.sysmessage @33 Bu bolgede taming yasaktir.
endif
return 1
On=@targon_item
src.sysmessage @33 Bu bir hayvan degil.
target
return 1
On=@targon_ground
src.sysmessage @33 Bu bir hayvan degil.
target
return 1
[FUNCTION checks]
NEWITEM i_checks
ACT.LINK <ARGN>
EQUIP <ACT.UID>
[ITEMDEF i_checks]
ID=i_memory
TYPE=t_eq_script
NAME=Checks
ON=@Equip
VAR.DIST <LINK.DISTANCE>
VAR.SEE <LINK.CanSeeLOS>
REMOVE
[function memorydel]
if (0<args>)
if (<findid.i_memory.link> == <args>)
findid.i_memory.remove
memorydel <args>
endif
endif
[EOF]
Buradanda MicheaL'a Sevgiler Gönderiyoruz :):)
