Üye ol    Giriş
  1. UO Scriptleri
  2. Sphere Scripts
  3. Items
  4. Player Vendor
berkancık

Player Vendor

  • berkancık
  • 2008-10-24 22:31
  • 0
  • 1106 
[chardef c_pv]

defname c_pv

name #names_humanmale the Player Vendor

id c_man_nomove

can mt_equip|mt_nonmover

hiredaywage 52

desires i_gold



tspeech s_pv

tevents e_pv



On=@Create

str 9500

dex 0

int 25

invul 1

color colors_skin

speechcolor 0481

food 990

npc 1



itemnewbie random_male_hair

color colors_hair

itemnewbie random_facial_hair

color match_hair

item i_robe

color colors_all

itemnewbie i_backpack

itemnewbie i_bankbox

color 0384

timer 900

attr 014

//itemnewbie i_pv

//timer 10000



on=@death

say @03c1,6,1,1 Uzgunum , ben ölmüyorum !

hits=<str>

return 1



[speech s_pv]

On=*all go*

ON=*go*

return 1



On=fiyat *

//src.sysmessage @025,1,1 Fiyat verme sistemi şuan bakımdadır..

//return 1

//say <args>

	if (<src.uid> == <uid.<uid.<tag.stone>.tag.owner>.uid>)

			if !(<findlayer(21).findcont(0)>)

				message @0481,1,1 Cantamda fiyatlandirilacak mal bulunmuyor.

			else

				src.tag.fiyatt <strsub 6 100 <args>>

				if !(<isnum <eval <src.tag.fiyatt>>>)

				src.sysmessage @0481,1,1 Fiyat olarak sadece rakam girebilirsiniz.

				return 1

				endif

				if (<src.tag.fiyatt> < 0)

				src.sysmessage @0481,1,1 Bu kadar dusuk bir fiyat giremezsiniz.

				return 1

				endif

				if (<src.tag.fiyatt> > 10000000)

				src.sysmessage @0481,1,1 Bu kadar yuksek bir fiyat giremezsiniz.

				return 1

				endif

				src.newitem i_pvf

				src.act.morex 1

				src.act.equip

			endif

	endif

	return 1



ON=satin al

if !(<findlayer(21).findcont(0)>)

src.sysmessage @0481,1,1 Satilik bir esyam yok.

return 1

endif

src.dialogclose d_pval

src.playervendordialog

src.newitem i_pvf

src.act.morex 2

src.act.tag.morey <uid>

src.act.equip



[itemdef i_pvf]

id i_memory

name vendor ana kontroller

type t_eq_script



on=@create

timer 300



on=@timer

remove

return 1



on=@equip

if (<morex>=1)

target @0481,1,1 <eval <topobj.tag.fiyatt>> olarak fiyatlandiracaginiz esyayi seciniz...

elseif (<morex>=2)

target @0481,1,1 Almak istediginiz esyayi seciniz.

endif



On=@TargOn_Item

if (<morex>=1)

if (<src.targ.tag0.pving>==0)

if ((<uid.<uid.<uid.<src.targ.uid>.topobj.uid>tag.stone>.tag.owner>==<src.uid>)&& !(strmatch('<uid.<src.targ.uid>.price>','')))

try uid.<src.targ.uid>.price <eval <topobj.tag.fiyatt>>

src.sysmessage @0481,1,1 <uid.<src.targ.uid>.name> <eval <topobj.tag.fiyatt>>gp olarak fiyatlandirildi...

else

src.sysmessage @0481,1,1 <uid.<src.targ.uid>.name> fiyatlandirilamaz...

endif

else

src.sysmessage @0481,1,1 Bu esya su anda satin aliniyor. . .

return 1

endif

target @0481,1,1 <eval <topobj.tag.fiyatt>> olarak fiyatlandiracaginiz itemi seciniz...

return 1

endif

if (<morex>=2)

src.tag.venal=<uid.<src.targ.uid>>

if !(<uid.<src.targ.uid>.topobj.uid>=<tag.morey>)

src.sysmessage <uid.<src.targ.uid>.topobj.uid>=<tag.morey>

src.sysmessage @0481,1,1 Bu esya bu vendorda satilmiyor.

return 1

endif

if !(0<uid.<src.targ.uid>.price> > 0)

src.sysmessage @0481,1,1 <uid.<src.targ.uid>.name> satilik degil.

return 1

endif

if (<uid.<uid.<uid.<src.targ.uid>.topobj.uid>tag.stone>.tag.owner>==<src.uid>)

src.sysmessage @0481,1,1 Vendor zaten size ait.

return 1

endif

if (<uid.<src.targ>.price> > <src.gp>)

src.sysmessage @0481,1,1 <uid.<src.targ.uid>.name> icin paraniz yetmiyor.

return 1

endif

if !(strmatch('<src.findid.i_memory.name>','Gump Memory'))

try uid.<src.targ.uid>.sdialog d_pval

try uid.<src.targ.uid>.tag0.pving=1

src.tag0.lastbuy=<src.targ.uid>

endif

return 1

endif





ON=@TARGON_CHAR

src.say abiiii!

if (<morex>=1)

target @0481,1,1 <morey> olarak fiyatlandiracaginiz itemi seciniz...

return 1

endif



[itemdef i_pvi]

id 1

name vendor item

type t_eq_script



on=@create

dispid i_rune_Marker

attr 010



On=@Timer

return 1





on=@dclick

if (0<tag.owner>=0<src.uid>)

target @0481,1,1 Tehsirde gorunmesini istediginiz itemin bir benzerini seciniz.

endif

return 1



on=@targon_item

if !(<uid.<src.targ.uid>.topobj.uid>=<src.uid>)

message @0481,1,1 Esya cantanizda olmali.

return 1

endif

dispid=<uid.<src.targ.uid>.dispid>

color=<uid.<src.targ.uid>.color>

name=<uid.<src.targ.uid>.name>

update

src.click

return 1



[itemdef i_vendor]

id i_grave_stone_4

name vendor hazirlik tasi

type t_eq_script



on=@create

attr=010

color=055



on=@dclick

if !(0<tag.pv>)

move 0 0 -1

serv.newitem i_pv

new.p <p>

new.color 065a

tag.pv <new.uid>

endif

remove 1

return 1



[itemdef i_pv]

id i_grave_stone_4

name Vendor Tasi

type t_eq_script



ON=@create

morex=2



On=@Timer

try uid.<tag.owner>.tag.vendorvar 0

try uid.<uid.<tag.vendor>.findlayer(21)>.attr 0

try uid.<uid.<tag.vendor>.findlayer(21)>.cont <uid.<tag.owner>.findlayer(29)>

try uid.<tag.owner>.gpdeposit <eval <tag.gold>>

tag.owner

tag.shopname=

try uid.<tag.vendor>.remove

tag.vendor

tag.gold

for 1 6

try uid.<tag.item<eval <local._for>>>.remove

end

return 1



on=@dclick

if (0<tag.owner>=0<src.uid>)

sdialog d_pv_kiralanmis

return 1

endif

if !(0<tag.vendor>)

sdialog d_pv_kirala

return 1

endif

return 1



on=@click

message @0481,1,1 <tag.street> #<eval <tag.no>>

if !(0<tag.owner>)

message @0481,1,1 Kiralik

else

message @0481,1,1 <tag.shopname> [<uid.<tag.owner>.name>]

endif

return 1



[dialog d_pval]

0 0

nomove

page 0

resizepic 0 0 5054 400 120

dtext 320 80 55 Satin Al

button 290 80 4029 4030 1 1 1

dtext 320 40 55 Iptal

button 290 40 4029 4030 2 1 2

dtext 50 80 55 Bakiye: <src.gp>gp

tilepic 20 20 <id>

dtext 110 10 55 <amount> <name>

dtext 110 30 55 (<price>gp)



[dialog d_pval button]

ON=1

src.targ <src.tag.venal>

if !(<price> > 0)

src.sysmessage @0481,1,1 Satilik degil.

return 1

endif

if !(<src.targ.uid>.topobj.uid>=<topobj.uid>)

src.sysmessage @0481,1,1 Esya vendorda degil.

return 1

endif

try uid.<uid.<uid.<src.targ.uid>.topobj.uid>tag.stone>.tag.gold = <eval (<uid.<uid.<uid.<src.targ.uid>.topobj.uid>tag.stone>.tag.gold>+<uid.<src.targ>.price>)>

src.gpconsume <uid.<src.targ>.price>

try uid.<src.targ.uid>.price 0

src.targ.tag0.pving=0

src.act <src.targ.uid>

src.act.bounce



on=2

src.targ.tag0.pving=0





[dialog d_pv_kiralanmis]

90 100

page 1

resizepic 0 0 5054 390 122

dtext 20 20 990 <tag.street> #<eval <tag.no>>

button 340 50 4029 4030 1 1 1

dtext 20 50 990 Dukkan adi:

resizepic 120 43 2620 200 35

dtextentry 127 50 180 20 990 1 <tag.shopname>

dtext 20 82 990 Tahsilat yap. (<eval <tag.gold>>gp)

button 340 82 4029 4030 1 1 2



[dialog d_pv_kiralanmis button]

ON=1

tag.shopname <argtxt[1]>

ON=2

src.gpdeposit <eval <tag.gold>>

tag.gold=0



[dialog d_pv_kirala]

90 100

page 1

resizepic 0 0 5054 390 122

dtext 20 20 990 <tag.street> #<eval <tag.no>>

button 340 50 4029 4030 1 1 1

dtext 20 50 990 1 Haftaligina kirala (125.000gp)



[dialog d_pv_kirala button]

ON=1

if !(0<tag.vendor>)

if (<src.gp> < 125000)

src.sysmessage @0481,1,1 Yeterli paraniz yok.

return 1

endif

if (<uid.<src.tag.vendorvar>.baseid>=i_pv)

src.sysmessage @0481,1,1 Zaten bir vendorunuz var.

return 1

endif

		src.gpconsume 125000

		timer 24*60*60*7

		tag.owner <src.uid>

		src.newnpc c_pv

		tag.vendor <src.act.uid>

		tag.gold=00

		if (<morex>=-2)

		move -1

		else

		move 1

		endif

		src.act.tag.stone <uid>

		src.act.tag.owner <src.uid>

		src.act.p <p>

		src.act.tag.p <p>

		src.act.tag.px <p.x>

		src.act.tag.py <p.y>

		src.act.tag.pz <p.z>

		src.act.tag.owner <src.uid>

		src.act.findlayer(29).more1 2500

		src.act.memorydel <src.uid>

		src.act.newitem i_memory

		src.act.act.attr 04

		src.act.act.more1 04

		src.act.act.more2 <serv.time>

		src.act.act.morep <src.act.p>

		src.act.act.color memory_ipet

		src.act.act.timer -1

		src.act.act.link <src.uid>

		src.act.act.cont <src.act.uid>

		src.act.flags <src.act.flags>&statf_pet

		if (<morex>=-2)

		src.act.flip

		src.act.flip

		src.act.flip

		endif

		src.act.update

		if (<morex>=-2)

		move 1

		else

		move -1

		endif

		serv.newitem i_table_wood_smooth_narrow_end

                new.color 065a

		new.attr 010

		new.p <p>

		new.move <morex> 1

		tag.item1=<new.uid>

		serv.newitem i_table_wood_smooth_narrow_ext

                new.color 065a

		new.attr 010

		new.p <p>

		new.move <morex> 0

		tag.item2=<new.uid>

		serv.newitem 0b6c

                new.color 065a

		new.attr 010

		new.p <p>

		new.move <morex> -1

		tag.item3=<new.uid>

		serv.newitem i_pvi

		new.attr 010

		new.p <p>

		new.move <morex> 1 6

		new.tag.owner=<src.uid>

		tag.item4=<new.uid>

		serv.newitem i_pvi

		new.attr 010

		new.p <p>

		new.move <morex> 0 6

		new.tag.owner=<src.uid>

		tag.item5=<new.uid>

		serv.newitem i_pvi

		new.attr 010

		new.p <p>

		new.move <morex> -1 6

		new.tag.owner=<src.uid>

		tag.item6=<new.uid>

		src.tag.vendorvar <uid>

		

		

else

src.sysmessage @0481,1,1 Bu dukkan baskasi tarafindan kiralanmis.

endif

return 1



[EVENTS vendoral]

on=@itemclick

	if (<act.topobj.baseid> == c_pv)

		if (strmatch('0<act.price>','0'))

			act.message @0481,1,1 [satilamaz]

		elseif (0<act.price> <= 0)

			act.message @0481,1,1 [satilik degil]

		else

			src.sysmessage @0481,1,1 <act.name> [<act.price> gp]

			if ((<act.type> == t_armor) || (<act.type> == t_armor_leather) || (<act.type> == t_shield) || (<act.type> == t_clothing) || (<act.type> == t_weapon_sword) || (<act.type> == t_weapon_fence) || (<act.type> == t_weapon_mace_staff) || (<act.type> == t_weapon_mace_smith) || (<act.type> == t_weapon_mace_pick) || (<act.type> == t_weapon_bow) || (<act.type> == t_weapon_xbow))

				if !(<eval ((<act.more1l> * 100) / <act.more1h>)> == 100)

						act.message @0481,1,1 [<act.price> gp] [%<eval (100 - ((<act.more1l> * 100) / <act.more1h>))> eski]

				else

					act.message @0481,1,1 [<act.price> gp]

				endif

			else

				act.message @0481,1,1 [<act.price> gp]

			endif

		endif

		if (<act.type> == t_container)

		//	act.message @0481,1,1 <act.typedef.name> [<act.rescount>,<eval ((<act.weight> / 10) - <act.typedef.weight>)>]

			return 1

		endif

	endif





[EVENTS e_pv]

on=@click

if !(<p.x>=<tag.px>)

go <tag.p>

endif

if !(<p.y>=<tag.py>)

go <tag.p>

endif

if !(0<uid.<tag.stone>.tag.owner>)

remove

return 1

endif

src.events +vendoral

message @0481,6,1 <uid.<tag.stone>.tag.street> #<eval <uid.<tag.stone>.tag.no>>

if (0<uid.<tag.stone>.tag.owner>)

	message @0481,6,1,1 <uid.<tag.stone>.tag.shopname> [<uid.<uid.<tag.stone>.tag.owner>.name>]

else

message @0481,6,1 KIRALIK

endif

return 1



on=@dclick

if (0<uid.<tag.stone>.tag.owner>)

pack

else

message @0481,1,1 KIRALIK

endif

return 1



On=@Hit

return 1



on=@HitTry



ON=@Gethit

return 1



ON=@spelleffect

return 1



[function playervendordialog]

src.newitem i_vendordialogkapat

new.equip

new.dclick

return 1



[itemdef i_vendordialogkapat]

name vendor dialogcu

id i_gold

type t_eq_script

weight 0

layer layer_special



On=@Create

attr attr_invis|attr_can_decay

timer 10



On=@Equip

timer 5

src.sysmessage @0481,1,1 5 saniye içinde onaylayınız...

return 1

	

on=@unequip

try uid.<cont.tag0.lastbuy>.tag0.pving=0

cont.dialogclose d_pval

return 1



On=@Timer

remove

return 1



[function f_fiyatdusur]

targetf fitaci



[function fitaci]

src.sysmessage <eval <argo.tag0.gold>>

Değerlendirmeler

0 0

Total votes: 0

Üye Ol veya Giriş Yap

Bu içeriğe yorum atmak istiyorsanız hemen üye olun veya giriş yapın.

Discord ile Bağlan
Twitch ile Bağlan
Steam ile Bağlan
Google ile Bağlan

Yorumlar (0)

Henüz yorum yapılmamış
Sadece kayıtlı kullanıcılar yeni yorum yapabilir.


Ultima-Strike Discord
Benzer Sayfalar