Arda eventsini fix scriptine eklemelisiniz.
[function basharfbuyuk]
return <strtoupper <strsub 0 1 <args>>><strtolower <strsub 1 99 <args>>>
[events arda]
on=@itemPickUp_Pack
if (<act.tag0.attr_04> == 1)
act.attr = <act.attr>|04
endif
if strmatch('<act.topobj.baseid>','c_vendor_player')
if strmatch('<act.baseid>','i_spellbook') || strmatch('<act.type>','t_deed') || strmatch('<act.baseid>','i_runebook')
act.attr 04
endif
if strmatch('<act.topobj.owner>','<src.uid>')
if (<act.tag0.fiyat> > 0)
act.tag0.fiyat 0
src.sys_error Eşyanızın fiyatı sıfırlandı.
endif
endif
endif
on=@itemdclick
if strmatch('<act.topobj.baseid>','c_vendor_player')
if strmatch('<act.type>','t_container')
act.open
return 1
elseif strmatch('<act.type>','t_book') && !strmatch('<act.topobj.tag0.owner>','<src>') && !(<src.isgm>)
return 1
endif
endif
on=@itemclick
if strmatch('<act.topobj.baseid>','c_vendor_player')
if (<act.tag0.fiyat> > 0)
act.msg_normal [<bolukayir <act.dtag0.fiyat>> Altın]
else
act.msg_error [Satılamaz]
endif
endif
[itemdef i_pv]
id i_memory
name vendor ana kontroller
type t_eq_script
on=@create
timer 604800
attr attr_newbie|attr_decay
On=@Timer
ref1 <cont.tag0.owner>
cont.owner.tag.vendor=
ref1.sys_error Vendorunuz süresi dolduğu için silinmiştir.
topobj.findlayer.21.cont <ref1.findlayer.29>
cont.remove
remove
return 1
[ITEMDEF i_deed_pv]
name House Vendor Deed
id i_deed
value 109000
On=@Create
color 0455
attr 04
on=@click
message @1153,,1 Vendor belgesi
return 1
on=@dclick
newnpc c_vendor_player
new.p <src.p>
ref1 <new.uid>
new.food 999
new.tag0.p <new.p>
new.tag0.owner <src.uid>
src.tag0.vendor <new.uid>
new.memorydel <src.uid>
newitem i_memory
new.attr 04
new.more1 04
new.more2 <serv.time>
new.morep <ref1.p>
new.color memory_ipet
new.timer -1
new.link <src.uid>
new.cont <ref1.uid>
ref1.flags <ref1.flags>&statf_pet
ref1.update
src.sys_trk Vendorunuz kuruldu.İyi oyunlar.
remove
return 1
//// KURULUM OLAYLARI BURDAN ///
[chardef c_vendor_player]
name #names_humanmale the Player Vendor
id c_man
can mt_equip|mt_nonmover
hiredaywage 52
desires i_gold
tevents e_player_vendor
On=@Create
NPC=brain_vendor
allskills 1000
archery
tactics
swordsmanship
fencing
macefighting
wrestling
hiding
stealth
str 9500
dex 25
int 25
color colors_skin
speechcolor 0481
food 990
npc 1
invul 1
itemnewbie random_male_hair
color colors_hair
itemnewbie random_facial_hair
color match_hair
item i_robe
color colors_all
item i_boots_calf
color colors_all
item i_torch_lit
morey -1
itemnewbie i_backpack
itemnewbie i_bankbox
color 0384
timer 900
attr 014
itemnewbie i_pv
On=@Death
return 1
On=@GetHit
return 1
on=@hittry
RETURN 1
ON=@Attack
RETURN 1
ON=@UserWarMode
flags &= ~statf_war
RETURN 1
on=@spelleffect
RETURN 1
ON=@CallGuards
RETURN 1
ON=@EnvironChange
flags &= ~statf_invisible
[dialog d_evvendorpanel]
250,50
noclose
nomove
page 1
makebg 50,50,200,100
ref1 <tag0.owner>
dhtmlgump 100 80 155 17 0 0 <def.bfont_lgreen>Satın Al
button 80 80 2714 2715 1 0 1
dhtmlgump 100 100 155 17 0 0 <def.bfont_lred>Çıkış
button 80 100 2714 2715 1 0 0
page 2
makebg 50,50,200,120
dhtmlgump 70 70 155 17 0 0 <def.bfont_white>Eşyanın adı: <def.bfont_lgreen><name>
dhtmlgump 70 90 155 17 0 0 <def.bfont_white>Fiyat: <def.bfont_lgreen><bolukayir <dtag0.fiyat>> Altın
button 90 110 2714 2715 1 0 2
dhtmlgump 110 110 155 17 0 0 <def.bfont_white>Satın Al
button 90 130 2714 2715 1 0 3
dhtmlgump 110 130 155 17 0 0 <def.bfont_lred>Geri
[dialog d_evvendorpanel button]
on 0
src.ctag0.alisveris 0
on=1
targetf f_evvendorbuy
src.ctag0.alisveris 0
on=2
if (<src.gold> < <dtag0.fiyat>)
src.sys_error Yeterli altınınız yok.
elif (<tag0.fiyat> < 1)
src.sys_error Bu eşya satılık değil.
elif !strmatch('<topobj.baseid>','c_vendor_player')
src.sys_error Alamazsınız
else
src.sys_error <bolukayir <dtag0.fiyat>> karşılığında <name> aldınız, eşyanız çantanızdadır.
src.gold -= <dtag0.fiyat>
topobj.tag0.hasilat += <dtag0.fiyat>
cont <src.findlayer.21.uid>
src.ctag0.alisveris 0
endif
return 1
src.ctag0.alisveris 0
sdialog d_evvendorpanel 1
on=3
sdialog d_evvendorpanel 1
[function f_evvendorbuy]
///if strmatch('<argo.topobj.tag0.owner>','<src.uid>')
////src.sys_error Siz bu vendorun sahibisiniz.
if !(<argo.topobj.findlayer(21).findcont(0)>)
src.sys_error Şu an satılık eşya yok.
elif (<src.gold> < <argo.tag0.fiyat>)
src.sys_error <bolukayir <argo.dtag0.fiyat>> altınınız yok.
elif (<argo.tag0.fiyat> < 1)
src.sys_error Bu eşya satılık değil.
elif !strmatch('<argo.topobj.baseid>','c_vendor_player')
src.sys_error Bu eşya vendorda değil.
else
argo.sdialog d_evvendorpanel 2
src.ctag0.alisveris 1
endif
return 1
[dialog d_evvendor]
250,50
nomove
page 1
////makebg 50,50,200,110
makebg 50,50,200,<qval (<tag0.owner> = <src.uid>) ? 140 : 110>
ref1 <tag0.owner>
dhtmlgump 70 60 185 40 0 0 <def.bfont_white>Alışveriş yapmak istediğiniz biçimi seçin.
dhtmlgump 100 100 155 17 0 0 <def.bfont_lgreen>Klasik Vendor
button 80 100 2714 2715 1 0 1
dhtmlgump 100 120 155 17 0 0 <def.bfont_lgreen>Liste Biçimi
button 80 120 2714 2715 1 0 2
if strmatch('<src.uid>','<tag0.owner>')
dhtmlgump 100 140 155 17 0 0 <def.bfont_lred>Vendor Ayarları
button 80 140 2714 2715 1 0 3
endif
page 2
makebg 50,50,200,140
dhtmlgump 100 70 155 17 0 0 <def.bfont_lgreen>Fiyat ver
button 80 70 2714 2715 1 0 4
dhtmlgump 100 90 155 17 0 0 <def.bfont_lgreen>Kendin gibi giydir
button 80 90 2714 2715 1 0 5
dhtmlgump 100 110 155 17 0 0 <def.bfont_lgreen>Hasılat
button 80 110 2714 2715 1 0 6
dhtmlgump 100 130 155 17 0 0 <def.bfont_lgreen>Süresinizi uzat
button 80 130 2714 2715 1 0 9
dhtmlgump 100 150 155 17 0 0 <def.bfont_lgreen>Vendoru Kaldır
button 80 150 2714 2715 1 0 10
page 3
makebg 50,50,200,80
resizepic 85 70 3000 122 28
dtextentry 87 70 146 17 1153 1 <dtag0.fiyat>
button 60 75 2714 2715 1 0 7
dhtmlgump 110 100 155 17 0 0 <def.bfont_white>Fiyat belirle
page 4
makebg 50,50,200,100
dhtmlgump 65 65 155 17 0 0 <def.bfont_white><dtag0.hasilat> altınınız var.
resizepic 85 100 3000 122 28
dtextentry 87 100 146 17 1153 2 <dtag0.hasilat>
button 60 105 2714 2715 1 0 8
page 5
makebg 50,50,250,100
dhtmlgump 65 65 220 40 0 0 <def.bfont_lgreen><kalansure <findid.i_pv.timer>> <def.bfont_white>daha hizmet edecek.
dhtmlgump 95 105 220 40 0 0 <def.bfont_white>1 günlük uzat.(30k)
button 75 105 2714 2715 1 0 11
page 6
makebg 50,50,270,120
dhtmlgump 65 65 250 40 0 0 <def.bfont_lgreen>Vendoru sildiğinizde çantasındaki itemler bankanıza aktarılacaktır. Emin misiniz?
dhtmlgump 95 115 220 40 0 0 <def.bfont_white>Evet
button 75 115 2714 2715 1 0 12
dhtmlgump 95 135 220 40 0 0 <def.bfont_lred>Hayır
button 75 135 2714 2715 1 0 0
[dialog d_evvendor button]
on 1
if strmatch('<src.uid>','<tag0.owner>')
say_error Satılacak eşyaları buraya koyabilirsiniz.
sdialog d_evvendorpanel 1
src.ctag0.alisveris 1
face <src.uid>
pack
elif (<src.flags>&statf_dead)
src.sysh_error Şuanki durumunuda bu işlemi gerçekleştiremezsiniz.
elif !(<canseelos>) && (<distance> > 4)
src.sysh_error Vendora ulaşamıyorsunuz.
elif !(<findlayer(21).findcont(0)>)
say_error Şuan satılık malım yok.Lütfen daha sonra tekrar geliniz.
else
src.sys_error İyi alışverişler.
sdialog d_evvendorpanel 1
src.ctag0.alisveris 1
face <src.uid>
pack
endif
return 1
on 2
if (<src.flags>&statf_dead)
src.sysh_error Şuanki durumunuda bu işlemi gerçekleştiremezsiniz.
elif !(<canseelos>) && (<distance> > 4)
src.sysh_error Vendora ulaşamıyorsunuz.
elif !(<findlayer(21).findcont(0)>)
say_error Şuan satılık malım yok.Lütfen daha sonra tekrar geliniz.
else
src.sys_error İyi alışverişler.
src.ctag0.pack <findlayer.21.uid>
src.ctag0.dialogindex 1
sdialog d_evvendorlistesi
src.ctag0.alisveris 1
face <src.uid>
endif
return 1
on=3
if !strmatch('<src.uid>','<tag0.owner>')
sys_error Vendorun sahibi değilsiniz.
else
sdialog d_evvendor 2
pack
endif
return 1
on=4
targetf f_evvendorfiyat
src.sys_normal Fiyatlandırmak istediğiniz eşyayı seçin
on=5
for 24
if !(<dlocal._for> == 21) && !(<dlocal._for> == 2) && !(<dlocal._for> == 1)
findlayer.<dlocal._for>.remove
newitem <src.findlayer.<dlocal._for>.baseid>
new.color <src.findlayer.<dlocal._for>.color>
equip <new>
endif
endfor
on=6
sdialog d_evvendor 4
on=7
if !(<isnumeric <argtxt[1]>>)
src.sys_error Yanlızca rakam yazabilirsiniz.
elif (<strsub 0 1 <argtxt[1]>> == 0)
src.sys_error İlk rakamı sıfır yazamazsınız.
elif (strlen(<argtxt[1]>) > 7)
src.sys_error Fiyatı en fazla 9.999.999 yapabilirsiniz.
elif !strmatch('<topobj.tag0.owner>','<src.uid>')
src.sys_error Bu vendorun sahibi değilsiniz
else
tag0.fiyat <dargtxt[1]>
src.sys_normal <name>: <bolukayir <dargtxt[1]>> altın olarak belirlendi.
endif
return 1
on=8
if !(<isnumeric <argtxt[2]>>)
src.sys_error Yanlızca rakam yazabilirsiniz.
elif (<strsub 0 1 <argtxt[2]>> == 0)
src.sys_error İlk rakamı sıfır yazamazsınız.
elif (strlen(<argtxt[2]>) > 7)
src.sys_error En fazla 9.999.999 altın çekebilirsiniz.
elif !strmatch('<topobj.tag0.owner>','<src.uid>')
src.sys_error Bu vendorun sahibi değilsiniz
else
tag0.hasilat -= <dargtxt[2]>
src.gold += <dargtxt[2]>
src.sys_normal <bolukayir <argtxt[2]>> altın bankanıza aktarılmıştır.
endif
return 1
on=9
sdialog d_evvendor 5
on=10
sdialog d_evvendor 6
on=11
if (<src.gold> < 30000)
src.sys_error 30k altınınız yok.
else
src.gold -= 30000
findid.i_pv.timer += 86400
src.sys_normal 30k karşılığında 1 gün daha eklendi. Toplamda <kalansure <findid.i_pv.timer>> daha hizmet edeceğim
endif
return 1
on=12
ref1 <tag0.owner>
serv.newitem i_backpack,1,<ref1.findlayer.29>
forcont <findlayer(layer_pack)> 0
cont <new>
endfor
remove
[dialog d_evvendorlistesi]
250,50
nomove
page 1
makebg 50,50,300,240
dhtmlgump 145 30 220 40 0 0 <def.bfont_white>Vendor (<owner.name>)
local.x 70
ref1 <src.ctag0.pack>
for a <src.ctag0.dialogindex> <eval <src.ctag0.dialogindex>+6>
IF !(<ref1.findcont.<eval <dlocal.a>-1>> == 0)
ref2 <ref1.findcont.<eval <dlocal.a>-1>>
local.x +=20
dhtmlgump 110 <dlocal.x> 220 40 0 0 <def.bfont_white><ref2.amount> adet <ref2.name> <qval (<ref2.tag0.fiyat> < 1)?<def.bfont_lred>Satılık Değil:<def.bfont_lgreen><bolukayir <ref2.dtag0.fiyat>> Altın>
if (<ref2.tag0.fiyat> > 0)
button 90 <dlocal.x> 2714 2715 1 0 <dlocal.a>
endif
if strmatch('<ref2.type>','t_container')
if (<ref2.rescount> > 0)
BUTTON 70 <dlocal.x> 2117 2118 1 0 <eval <dlocal.a>+10000>
endif
endif
endif
endfor
BUTTON 305 253 9903 9905 1 0 77777
BUTTON 70 253 9909 9911 1 0 77778
page 2
ref1 <src.ctag0.buyingitem>
if strmatch('<ref1.type>','t_container')
makebg 50,50,300,220
else
makebg 50,50,300,180
endif
dhtmlgump 85 60 220 40 0 0 <def.bfont_lred><basharfbuyuk <ref1.name>><def.bfont_white> eşyasını satın almak istiyor musunuz?
resizepic 75 100 5054 100 100
tilepichue 85 120 <ref1.id> <ref1.dcolor>
if <ref1.isweapon> || <ref1.isarmor> || <ref1.type>==t_clothing
dhtmlgump 180 100 155 17 0 0 <def.bfont_lred>Hasar: <def.bfont_white><muldiv <ref1.maxhits>,<ref1.hits>,100>% eski
endif
if <ref1.isweapon>
dhtmlgump 180 120 155 17 0 0 <def.bfont_lred>Dam: <def.bfont_white><ref1.dam>
endif
if <ref1.isarmor> || <ref1.type>==t_clothing
dhtmlgump 180 120 155 17 0 0 <def.bfont_lred>Armor: <def.bfont_white><ref1.armor>
endif
if (<ref1.amount> > 1)
dhtmlgump 180 120 155 17 0 0 <def.bfont_lred>Adet: <def.bfont_white><ref1.amount>
endif
if strmatch('<ref1.type>','t_container')
local.items=<def.bfont_lred>İçindekiler:<def.br><def.bfont_white>
forcont <ref1.uid> 0
local.items .=<amount> <name><def.br>
endfor
dhtmlgump 70 200 270 60 0 1 <local.items>
endif
makebg 350,50,100,60
dhtmlgump 380 60 155 17 0 0 <def.bfont_lgreen>Satın Al
button 360 60 2714 2715 1 0 99999
dhtmlgump 380 80 155 17 0 0 <def.bfont_lred>Çıkış
button 360 80 2714 2715 1 0 0
[dialog d_evvendorlistesi button]
on=0
src.ctag0.alisveris 0
on 99999
ref1 <src.ctag0.buyingitem>
if (<src.gold> < <ref1.dtag0.fiyat>)
src.sys_error Yeterli altınınız yok.
elif (<ref1.tag0.fiyat> < 1)
src.sys_error Bu eşya satılık değil.
elif !strmatch('<ref1.topobj.baseid>','c_vendor_player')
src.sys_error Alamazsınız
else
src.sys_error <bolukayir <ref1.dtag0.fiyat>> karşılığında <ref1.name> aldınız, eşyanız çantanızdadır.
src.gold -= <ref1.dtag0.fiyat>
ref1.topobj.tag0.hasilat += <ref1.dtag0.fiyat>
ref1.cont <src.findlayer.21.uid>
src.ctag0.alisveris 0
endif
return 1
src.ctag0.alisveris 0
sdialog d_evvendorlistesi 1
on 1 9999
ref1 <src.ctag0.pack>
src.ctag0.buyingitem <ref1.findcont.<eval <argn>-1>.uid>
sdialog d_evvendorlistesi 2
ON = 10001 20000
ref1 <src.ctag0.pack>
src.ctag0.pack <ref1.findcont.<eval <dargn>-10001>.uid>
src.ctag0.dialogindex 1
sdialog d_evvendorlistesi
src.say <ref1.findcont.<eval <dargn>-10001>.name>
ON = 77777
SRC.CTAG0.dialogindex +=7
SDIALOG d_evvendorlistesi
ON = 77778
IF (<SRC.dCTAG0.dialogindex> > 1)
SRC.CTAG.dialogindex -=7
ENDIF
SDIALOG d_evvendorlistesi
[function asd]
ref1 <src.ctag0.pack>
say <ref1.findcont.<args>.name>
[function f_evvendorfiyat]
if !strmatch('<argo.topobj.baseid>','c_vendor_player')
src.sys_error Sadece vendordaki itemlere fiyat verebilirsiniz.
elif !strmatch('<argo.topobj.tag0.owner>','<src.uid>')
src.sys_error Bu vendorun sahibi değilsiniz.
else
argo.sdialog d_evvendor 3
endif
return 1
[events e_player_vendor]
on=@dclick
src.ctag0.vendoruid <uid>
ref1 <tag0.owner>
if strmatch('<tag0.owner>','<src.uid>')
sayua <eval 07a1> 0 0 1 Hoşgeldiniz Efendim.
endif
if !(<src.ctag0.alisveris> == 1)
sdialog d_evvendor
endif
if !(<memoryfindtype.memory_ipet>)
memorydel <src.uid>
newitem i_memory
new.attr 04
new.more1 04
new.more2 <serv.time>
new.morep <p>
new.color memory_ipet
new.timer -1
new.link <tag0.owner>
new.cont <uid>
flags <flags>&statf_pet
endif
return 1
on=@click
ref1 <tag0.owner>
if !strmatch('<tag0.p>','<p>')
p <tag0.p>
update
endif
if !(<memoryfindtype.memory_ipet>)
memorydel <src.uid>
newitem i_memory
new.attr 04
new.more1 04
new.more2 <serv.time>
new.morep <p>
new.color memory_ipet
new.timer -1
new.link <tag0.owner>
new.cont <uid>
flags <flags>&statf_pet
endif
message @1153 [<ref1.name>]
message @666 <name>
return 1
on=@spell_effect
return 1
on=@gethit
if (<findid.i_rune_poison>)
findid.i_rune_poison.remove
endif
return 1
On=@Attack
return 1
On=@Hit
return 1
On=@HitTry
return 1
On=@Death
hits <str>
return 1
0
Total votes: 0
Yorumlar (0)