[Comment Küfür Sistemi]
Açıklama: Oyuncular .kufur yazıp çıkan target i şikayet etmek istedikleri oyuncuya tıkladıklarında 1 dakikalık kayıt a girer.
Kayıt altında olduğunu küfür eden oyuncu farkedemez.1 dakika sonunda bütün yetkililerin görüceği bir alt yazı geçer.
Not: Altta verdiğim kısım sphere_speech.scp de speak_player a eklenicek.
Yazar: KeLL
Tarih: 30 Haziran 2008- Saat: 18.17
UzunluK:commentlerle birlikte 151 satır
////// speak_player a eklenicek /////
///ON=*
///if (<src.findid.i_kufurkayit>)
///src.tag0.nededi .=" <args>."
///endif
[function kufursistemikur]
db.connect
db.execute "create table kufur_sys (id int unsigned not null auto_increment primary key,kufuredenuid text,sikayetedenuid text,tarih text,kufurcuismi text,sikayetciismi text,konusmaicerik text)";
sys_ok Küfür sistemi kuruldu
[plevel 1]
kufur
[function kufur]
if (<account.plevel> > 1)
ctag.dialogindex 0
sdialog d_kufurayar
else
targetf f_kufur
sysmessagek Yetkililere bildirmek istediğiniz player ı seçiniz.
endif
[function f_kufur]
obj=<argo>
if <obj.uid> == <src.uid>
sysmessagek Kendinizi şikayet edemezsiniz.
elif <obj.restest 1 i_kufurkayit>
sysmessagek Kişi zaten kayıt altında.
elif <obj.isplayer>
newitem i_kufurkayit
new.tag0.tarih <serv.rtime>
new.tag0.sikayeteden <uid>
new.tag0.sikayetedenisim <name>
new.cont <obj.uid>
obj.tag0.nededi -
endif
[itemdef i_kufurkayit]
id i_memory
name kayitci
layer layer_special
TYPE=t_eq_script
on=@create
attr attr_decay|attr_invis|attr_newbie
timer 60
on=@timer
db.connect
db.execute "insert into kufur_sys VALUES (NULL, '<addslashes <cont.uid>>', '<addslashes <tag0.sikayeteden>>', '<addslashes <tag0.tarih>>', '<addslashes <cont.name>>', '<addslashes <tag0.sikayetedenisim>>', '<addslashes <cont.tag0.nededi>>');"
obj=<uid.<tag0.sikayeteden>>
obj.sys_ok Ettiğiniz şikayet yetkililere iletilmek üzere veritabanına kaydedildi.
serv.allclients kufurduyur <obj.name> İsimli kişi, <cont.name> isimli kişinin küfür ettiğini ihbar etti.
remove
return 1
[function kufurduyur]
if (<account.plevel> > 1)
sys_er <args>
endif
[dialog d_kufurayar]
0,0
nomove
resizepic 0 0 3500 400 650
dhtmlgump 90 *10 300 30 0 0 <def.BFONT_SIZE7> <def.BFONT_RED> <serv.name> UO Küfür Menüsü
dhtmlgump 50 *25 300 30 0 0 <def.BFONT_lblue> Şikayetçi
dhtmlgump 150 *0 300 30 0 0 <def.BFONT_lblue> Küfürbaz
dhtmlgump 250 *0 300 30 0 0 <def.BFONT_lblue> Tarih
db.connect
db.query "select * from kufur_sys order by tarih desc limit <eval <ctag.dialogindex>>,<eval <ctag.dialogindex>+25>";
for x 0 25
if <db.row.<dlocal.x>.kufuredenuid>
local.y ((<dlocal.x>*20)+55)
button 20 <eval <local.y>+3> 2511 2510 1 0 <eval <db.row.<dlocal.x>.id>+10>
dhtmlgump 50 <dlocal.y> 300 30 0 0 <addslashes <db.row.<dlocal.x>.sikayetciismi>>
dhtmlgump 150 <dlocal.y> 300 30 0 0 <addslashes <db.row.<dlocal.x>.kufurcuismi>>
dhtmlgump 250 <dlocal.y> 300 30 0 0 <addslashes <db.row.<dlocal.x>.tarih>>
endif
endfor
button 20 570 2511 2510 1 0 1
button 20 600 2511 2510 1 0 2
dhtmlgump 40 570 550 30 0 0 <def.BFONT_lred> İleri
dhtmlgump 40 600 580 30 0 0 <def.BFONT_lred> Geri
[dialog d_kufurayar BUTTON]
on=1
ctag.dialogindex += 25
sdialog d_kufurayar
on=2
if <ctag.dialogindex> > 0
ctag.dialogindex -= 25
endif
sdialog d_kufurayar
return 1
on=3 99999999
ctag.kufurid <eval (<argn1>-10)>
ctag.dialogindex 0
sdialog d_kufurayrinti
return 1
[dialog d_kufurayrinti]
0,0
nomove
noclose
resizepic 0 0 3500 400 400
db.query "select * from kufur_sys where id = '<eval <ctag.kufurid>>' limit 1"
dhtmlgump 90 *10 300 30 0 0 <def.BFONT_SIZE7> <def.BFONT_RED> Şikayet Detayları
dhtmlgump 50 *25 300 30 0 0 <def.BFONT_lblue> Şikayetçi: <def.bfont_lred> <addslashes <db.row.0.sikayetciismi>>
dhtmlgump 50 *25 300 30 0 0 <def.BFONT_lblue> Küfürbaz: <def.bfont_lred> <addslashes <db.row.0.kufurcuismi>>
dhtmlgump 50 *25 300 30 0 0 <def.BFONT_lblue> Tarih: <def.bfont_lred> <addslashes <db.row.0.tarih>>
dhtmlgump 50 *25 300 30 0 0 <def.BFONT_lblue> Kayıt altına alınan konuşma:
dhtmlgump 50 *35 300 60 1 1 <db.row.0.konusmaicerik>
button 50 *80 2511 2510 1 0 1
dhtmlgump 70 *0 300 30 0 0 <def.BFONT_lred> Şikayetçiyi cezalandır.
button 50 *20 2511 2510 1 0 2
dhtmlgump 70 *0 300 30 0 0 <def.BFONT_lred> Küfürbazı cezalandır.
button 50 *20 2511 2510 1 0 3
dhtmlgump 70 *0 300 30 0 0 <def.BFONT_lred> Şikayeti sil.
[dialog d_kufurayrinti button]
on=1 3
db.connect
if (<argn> == 1)
obj=<uid.<db.row.0.sikayetedenuid>>
obj.tag.sucu Hatalı Şikayet
elif (<argn> == 2)
obj=<uid.<db.row.0.kufuredenuid>>
obj.tag.sucu Küfür / Hakaret
elif <argn> == 3
db.execute "delete from kufur_sys where id='<ctag0.kufurid>';"
return 1
endif
obj.go jail
obj.events e_hapis
obj.tag0.otohapis +=1
newitem i_jailcik
new.timer <eval <obj.tag0.otohapis>*7200>
new.cont <obj.uid>
db.execute "delete from kufur_sys where id='<ctag0.kufurid>';"
ctag0.kufurid=
sdialog d_kufurayar
0 Total votes: 0
Yorumlar (0)