Sac sakal deed

• Aldarson
• 2009-07-25 10:36
• 0 Yorumlar
• 1723 Görüntüleme

[defname sacsakaluid]

sacuid1 i_hair_short

sacuid2 i_hair_long

sacuid3 i_hair_ponytail

sacuid4 i_hair_mohawk

sacuid5 i_hair_pageboy

sacuid6 i_hair_buns

sacuid7 i_hair_afro

sacuid8 i_hair_receding

sacuid9 i_hair_2_pigtails

sacuid10 i_hair_krisna



sactext1 Kisa

sactext2 Uzun

sactext3 At Kuyrugu

sactext4 Mohawk

sactext5 Pageboy

sactext6 Buns

sactext7 Afro

sactext8 Seyrek

sactext9 Cift Orgu

sactext10 Krisna

sactext11 Sac olmasin



sakaluid1 i_beard_short_med

sakaluid2 i_beard_long_med

sakaluid3 i_beard_short

sakaluid4 i_beard_long

sakaluid5 i_beard_mustache

sakaluid6 i_beard_vandyke

sakaluid7 i_beard_goatee



sakaltext1 Kisa + Biyik

sakaltext2 Uzun + Biyik

sakaltext3 Kisa

sakaltext4 Uzun

sakaltext5 Sadece biyik

sakaltext6 Vandyke

sakaltext7 Top sakal

sakaltext8 Sakal olmasin



[DIALOG D_HAIRSTYLE]

50,50

nomove

resizepic 60 40 5120 225 295

dtext 80 60 100 Yeni sac seklinizi seciniz.



local.b 91

for 1 11

dtext 105 <dlocal.b> 800 <def.sactext<dlocal._for>>

local.b +=20

endfor





local.x 90

for 1 11

button 74 <dlocal.x> 4007 4006 1 0 <dlocal._for>

local.x +=20

endfor

[DIALOG D_HAIRSTYLE BUTTON]

On=0

src.sysmessage @038a,0,1 Iptal ettiniz.

return 1



On 1 10

if !(<src.restest 1 i_deed_hair>)

src.sysmessage @038a,0,1 Yaninizda 1 adet hair deed yok.

return 1

else

src.consume 1 i_deed_hair

src.newitem <def.sacuid<argn>>

new.equip

new.attr 014

new.timer -1

endif



On 11

if !(<src.restest 1 i_deed_hair>)

src.sysmessage @038a,0,1 Yaninizda 1 adet hair deed yok.

return 1

else

src.findlayer(11).remove

src.consume 1 i_deed_hair

endif



[DIALOG D_BEARDSTYLE]

50,50

nomove

resizepic 60 40 5120 240 245

dtext 80 60 100 Yeni sakal seklinizi seciniz.



local.c 91

for 1 8

dtext 105 <dlocal.c> 800 <def.sakaltext<dlocal._for>>

local.c +=20

endfor



local.y 90

for 1 8

button 74 <dlocal.y> 4007 4006 1 0 <dlocal._for>

local.y +=20

endfor



[DIALOG D_BEARDSTYLE BUTTON]

On=0

src.sysmessage @038a,0,1 Iptal edildi.

return 1



On 1 7

if !(<src.restest 1 i_deed_beard>)

src.sysmessage @038a,0,1 Yaninizda 1 adet beard deed yok.

return 1

else

src.consume 1 i_deed_beard

src.newitem <def.sakaluid<argn>>

new.equip

new.attr 014

new.timer -1

endif



On=8

if !(<src.restest 1 i_deed_beard>)

src.sysmessage @038a,0,1 Yaninizda 1 adet beard deed yok.

return 1

else

src.consume 1 i_deed_beard

src.findlayer(16).remove

endif



[ITEMDEF i_deed_hair]

NAME=hair re-styling deed

ID=i_deed

WEIGHT=1

VALUE=4200

TYPE=t_script



On=@Create

COLOR=0901

ATTR = ATTR_NEWBIE



On=@DClick

if !(<topobj.uid> == <src.uid>)

src.sysmessage @038a,0,1 Cantanizda olmadan kullanamassiniz.

return 1

else

SDIALOG d_hairstyle

return 1

endif



[ITEMDEF i_deed_beard]

NAME=beard re-styling deed

ID=i_deed

WEIGHT=1

VALUE=2200

TYPE=t_script



On=@Create

COLOR=0901

ATTR = ATTR_NEWBIE



On=@DClick

IF !(<SRC.BODY> == c_man)

SRC.SYSMESSAGE @038a,0,1 Bunu kullanamazsiniz.

RETURN 1

Elseif !(<topobj.uid> == <src.uid>)

src.sysmessage @038a,0,1 Cantanizda olmadan kullanamassiniz.

RETURN 1

else

SDIALOG d_beardstyle

return 1

endif

Değerlendirmeler

Total votes: 0