[FUNCTION f_array]
local.temp = <argv[<eval <argv> - 1>]> -1
return <argv[<dlocal.temp>]>
[CHARDEF c_quester]
ID=c_man
NAME=#NAMES_HUMANMALE
CAN=MT_NONMOVER
ON=@Create
color=colors_skin
FLAGS=statf_invul
NPC=BRAIN_HUMAN
DEX=10
INT=10
STR=10
title The Quester
ON=@NPCRESTOCK
ITEMNEWBIE=i_lantern
ITEMNEWBIE=random_male_hair
COLOR=colors_hair
ITEMNEWBIE=random_facial_hair
COLOR=match_hair
ITEMNEWBIE=i_shirt_plain
COLOR=colors_all
ITEMNEWBIE=random_pants
COLOR=colors_all
ITEMNEWBIE=random_shoes
COLOR=colors_neutral
on=@click
msg_ok [Görev]
msg_ok <name>
return 1
on=@dclick
if (<distance> > 6)
msg_er Yaklaşınız.
return 1
endif
if !(<src.tag0.quest>)
dorand 5
say_norm Buyrun?
say_norm Evet?
say_norm Efendim?
say_norm Ne istemiştiniz?
say_norm Ne vardı?
enddo
sdialog d_quest 1
else
sdialog d_quest 3
endif
[function gorev]
if !(<src.tag0.quest>)
src.sys_er Şu anda görev yapmıyorsunuz.
else
sdialog d_quest 2
endif
[dialog d_quest]
50,50
resizepic 0 0 5120 270 250
resizepic 12 12 3000 250 230
dhtmlgump 60 25 200 250 0 0<def.BFONT_red><serv.name> Görev Menüsü
page 1
dhtmlgump 20 *50 230 55 0 0<def.BFONT_dgreen><src.name>, Benden görev almak istiyor musun ?
button 30 *60 2511 2510 1 0 1
dhtmlgump 40 *0 300 25 0 0<def.BFONT_dred> Evet, almak istiyorum!
button 30 *60 2511 2510 1 0 2
dhtmlgump 40 *0 300 25 0 0<def.BFONT_dred> Hayır, istemiyorum!
page 2
dhtmlgump 35 50 200 150 1 1<def.BFONT_dgreen>Bana <def.bfont_red><f_array <src.tag0.quest>,3><def.BFONT_dgreen> tane, <def.bfont_red><serv.chardef.<f_array <src.tag0.quest>,4>.name><def.BFONT_dgreen> yaratığından çıkan <def.bfont_red><serv.itemdef.<f_array <src.tag0.quest>,2>.name><def.BFONT_dgreen> getirmelisin.Bunun karşılığında ödülün <def.bfont_red><f_array <src.tag0.quest>,5><def.BFONT_dgreen> altın ve <def.bfont_red><f_array <src.tag0.quest>,6><def.BFONT_dgreen> tecrübe olucaktır.
page 3
if !(<src.restest <f_array <src.tag0.quest>,3> <f_array <src.tag0.quest>,2>>)
dhtmlgump 25 50 230 55 0 0<def.BFONT_dgreen>Çantanızda <src.rescount <f_array <src.tag0.quest>,2>>/<def.bfont_red><f_array <src.tag0.quest>,3><def.BFONT_dgreen> tane <serv.itemdef.<f_array <src.tag0.quest>,2>.name> var. <eval <f_array <src.tag0.quest>,3>-<src.rescount <f_array <src.tag0.quest>,2>>> tane daha getirirseniz görev biticektir.
else
dhtmlgump 25 50 230 55 0 0<def.BFONT_dgreen> Görevi bitirmek için butonu tıklayın.
button 15 50 2511 2510 1 0 3
endif
[dialog d_quest BUTTON]
on=2
tag0.quest=
dorand 5
say_ok Güle güle!
say_ok Hoşçakal!
say_ok Görüşürüz!
say_ok Görüşmek üzere!
say_ok Kendine iyi bak <src.name>!
enddo
on=1
f_quest
sdialog d_quest 2
on=3
if (<src.restest <f_array <src.tag0.quest>,3> <f_array <src.tag0.quest>,2>>)
src.consume <f_array <src.tag0.quest>,3> <f_array <src.tag0.quest>,2>
src.gold += <f_array <src.tag0.quest>,5>
src.tag0.exp += <f_array <src.tag0.quest>,6>
src.sys_ok <f_array <src.tag0.quest>,5> tane altın ve <f_array <src.tag0.quest>,6> tecrübe kazandınız.
events -e_quest
src.tag0.quest=
else
src.sys_er Gerekli eşyalarınız yok
return 1
endif
[function f_quest]
local.zorluk <R1,3>
local.item <f_array <def.items>,<R1,9>>
local.sayi <eval <dlocal.zorluk>*<R5,15>>
local.npc <f_array <def.npc<dlocal.zorluk>>,<R1,3>>
local.odulpara <eval <dlocal.zorluk>*<R5000,25000>>
local.odulexp <eval <dlocal.zorluk>*<R500,1500>>
src.tag0.quest <dlocal.zorluk>, <local.item>, <dlocal.sayi>, <local.npc>, <dlocal.odulpara>, <dlocal.odulexp>
src.events +e_quest
[events e_quest]
on=@kill
if strmatch('<argo.baseid>','<f_array <src.tag0.quest>,4>')
if (<R<f_array <src.tag0.quest>,1>> == 1)
newitem <f_array <src.tag0.quest>,2>
new.cont <argo>
endif
endif
[defname npc]
npc1 c_m_skeleton_knight, c_m_ophidian_knight,c_m_mummy, c_m_icefiend, c_m_stoneharpy
npc2 c_m_elem_snow, c_m_elem_blood, c_m_gargoyle_stone, c_m_ogre_lord, c_m_liche_lord
npc3 c_m_dragon_wyrm, c_m_balron, c_m_kraken, c_m_dragon_ice, c_m_dragon_crystal
items i_akuma_blood, i_akuma_head, i_akuma_hide, i_akuma_feather, i_power_kristal, i_wizard_ball, i_book_myst, i_map_myst, i_goldenkey
/// items ///
[typedef t_questitem]
on=@click
msg_ok <amount> <name>
return 1
on=@dclick
src.sys_ok Quest eşyasıdır.
return 1
[itemdef i_akuma_blood]
name Akuma's Blood
id i_reag_dragon_blood
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_akuma_head]
name Akuma's Head
id i_flesh_head
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_akuma_hide]
name Akuma's Hide
id i_hide
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_akuma_feather]
name Akuma's Feather
id i_feather
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_power_kristal]
name Power Crystal
id i_crystal_1
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_wizard_ball]
name Wizard's Ball
id i_crystal_ball
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_book_myst]
name the mysterious book
id i_book_sm
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_map_myst]
name the mysterious map
id i_map_rolled
tevents t_questitem
weight 0
on=@create
color 0455
[itemdef i_goldenkey]
name golden key
id i_key_copper
tevents t_questitem
weight 0
on=@create
color 0455
0 Total votes: 0
Yorumlar (0)