Üye ol    Giriş
  1. UO Scriptleri
  2. Sphere Scripts
  3. Items
  4. Runebook
Slothere

Runebook

  • Slothere
  • 2008-09-14 12:30
  • 0
  • 1513 
// * writer : Slothere (Runebook System)

// * date: 27 haziran 2008 (Güncelleme: 30.06.2008)

// * version: 056b+



[ITEMDEF i_runebook]

NAME = runebook

ID = i_spellbook

TYPE = t_script

VALUE = 1550

WEIGHT = 1.5



SKILLMAKE=INSCRIPTION 100.0, MAGERY 70.0

RESOURCES=50 i_scroll_blank, 3 i_scroll_recall, 5 i_scroll_gate_travel



ON=@CREATE

COLOR = 0845

ATTR = Attr_Newbie

tag.charge = 3

tag.runeisim =



ON=@CLICK

message @1153 <qval (!<isempty <tag.runeisim>>)? <name> [<tag.runeisim>]:<name>>

return 1



ON=@DCLICK

//IF (<src.isplayer>) && !(<src.isgm>)

//src.sys_error bir sureligine bakimda.

//return 1

//ENDIF

//IF (<src.isevent.e_hapiste>)

//src.sys_error Jailde kullanamazsiniz.

//return 1

//ENDIF

IF (<src.flags>&statf_dead) || (<src.flags>&04)

src.sys_error Su anki halinizle kullanamazsiniz.

return 1

ELIF (<region.flags>&region_flag_ship)

src.sys_error Gemi icerisinde kullanamazsiniz.

return 1

ELIF (<src.action> == id(skill_magery)) || (<src.action> == skill_magery)

src.sys_error Buyu yaparken kullanamazsiniz.

return 1

ELIF (<src.isevent.e_recall>)

return 1

ELIF (<src.tag0.kullanamaz>)

return 1

ENDIF

sdialog d_runebook

return 1



ON=@DROPON_SELF

ref2 = <argo>

IF (<ref2.baseid> == i_rune_marker)

IF (<ref2.morep>)

ref1 = <ref2.uid>

local.bosalan 0

FOR s 14 1

IF (<isempty <tag.rune.<dlocal.s>>>)

local.bosalan = <dlocal.s>

ENDIF

ENDFOR

IF (<local.bosalan>)

try tag.rune.<dlocal.bosalan> = <ref1.name>

try tag.lokasyon.<dlocal.bosalan> = <ref1.morep>

src.sys_normal <ref1.name> isimli rune kitaba eklendi.

sound 85

ref1.remove

//src.sayu <dlocal.bosalan>

ELSE

src.sys_error Kitapta bos yer kalmamis.

ENDIF

return 1

ELSE

src.sys_error Bu rune bos.

return 1

ENDIF

ENDIF

IF (<ref2.baseid> == i_scroll_recall)

tag.charge = <eval (<tag.charge>+<ref2.amount>)>

ref2.remove

src.sys_normal Kitaba <ref2.amount> adet sarj eklendi.

return 1

ENDIF



[Dialog d_runebook]

0,0

Nomove



PAGE 0



gumppic 200 150 2200

gumppic 230 300 57

FOR 1 7

gumppic <eval (<local._for>*16)+230> 300 58

ENDFOR

gumppic 400 300 57

FOR 1 6

gumppic <eval (<local._for>*16)+400> 300 58

ENDFOR



button 230 320 55 56 1 0 500

dcroppedtext 255 318 100 20 0456 Isim: <tag.runeisim>

dtext 400 320 0456 Sarj: <dtag.charge>



FOR sl 1 7

IF !(<isempty <tag.rune.<dlocal.sl>>>)

dhtmlgump 252 <eval (<local.sl>*18)+145> 105 20 0 0 <tag.rune.<dlocal.sl>>

button 238 <eval (<local.sl>*18)+150> 2103 2104 1 0 <eval <local.sl>+50>

button 353 <eval (<local.sl>*18)+150> 2103 2104 1 0 <eval <local.sl>+100>

button 363 <eval (<local.sl>*18)+150> 2103 2104 1 0 <eval <local.sl>+200>

button 228 <eval (<local.sl>*18)+150> 2103 2104 1 0 <dlocal.sl>

ENDIF

ENDFOR



FOR slt 8 14

IF !(<isempty <tag.rune.<dlocal.slt>>>)

dhtmlgump 405 <eval (<local.slt>*18)+20> 100 20 0 0 <tag.rune.<dlocal.slt>>

button 383 <eval (<local.slt>*18)+25> 2103 2104 1 0 <dlocal.slt>

button 393 <eval (<local.slt>*18)+25> 2103 2104 1 0 <eval <local.slt>+50>

button 511 <eval (<local.slt>*18)+25> 2103 2104 1 0 <eval <local.slt>+100>

button 520 <eval (<local.slt>*18)+25> 2103 2104 1 0 <eval <local.slt>+200>

ENDIF

ENDFOR



[dialog d_runebook button]

on = 1 14

IF (<src.flags>&statf_dead) || (<src.flags>&04)

return 1

ENDIF

if (<src.mana> < 15)

src.sound=92

src.sys_error Yeterli mananiz yok.

return 1

endif

if (<dtag0.charge> > 0

src.mana -=15

tag.charge -=1

src.anim 16

src.events +e_recall

src.sltnomove 30

src.timerf 3,recall <tag.lokasyon.<dargn>>

src.tag.recall = 1

src.sayua 0481,6,6,0 Kal Ort Por

ELSEIF (<src.magery> < 25.0)

src.sys_error Reagent ile kullanim icin magery skilliniz yetersiz. (Gereken: 25.0)

return 1

ELSEIF (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_mandrake_root>) && (<src.restest 1 i_reag_blood_moss>)

src.events +e_recall

src.sltnomove 30

src.timerf 3,recall <tag.lokasyon.<dargn>>

src.consume 1 i_reag_black_pearl

src.consume 1 i_reag_mandrake_root

src.consume 1 i_reag_blood_moss

src.mana -=15

src.anim 16

src.tag.recall = 1

src.sayua 0481,6,6,0 Kal Ort Por

ELSE

src.sys_error Uzerinizde kitabi kullanicak kadar sarj veya reagent bulunmuyor.

return 1

ENDIF



on = 51 64

IF (<src.flags>&statf_dead) || (<src.flags>&04)

return 1

ENDIF

IF (<src.magery> < 70.0)

src.sys_error Magery skilliniz yetersiz. (Gereken: 70.0)

return 1

endif

if (<src.mana>< 40)

src.sound=92

src.sys_error Yeterli mananiz yok.

return 1

endif

IF (<dtag0.charge> > 0)

src.mana -=40

tag.charge -=1

src.events +e_recall

src.sltnomove 50

src.timerf 5,runegate <tag.lokasyon.<eval (<argn>)-50>>

src.anim 16

src.tag.recall = 1

src.sayua 0481,6,6,0 Vas Rel Por

ELIF (<src.restest 1 i_reag_black_pearl>) && (<src.restest 1 i_reag_mandrake_root>) && (<src.restest 1 i_reag_sulfur_ash>)

src.events +e_recall

src.sltnomove 30

src.timerf 3,runegate <tag.lokasyon.<eval (<argn>)-50>>

src.consume 1 i_reag_black_pearl

src.consume 1 i_reag_mandrake_root

src.consume 1 i_reag_sulfur_ash

src.mana -=40

src.anim 16

src.tag.recall = 1

src.sayua 0481,6,6,0 Vas Rel Por

ELSE

src.sys_error Uzerinizde kitabi kullanicak kadar sarj veya reagent bulunmuyor.

RETURN 1

ENDIF



on = 101 114

src.sys_normal <eval (<argn>)-100>. siradaki <tag.rune.<eval (<argn>)-100>> isimli rune'u cikarttiniz.

serv.newitem i_rune_marker

new.morep <tag.lokasyon.<eval (<argn>)-100>>

new.name <tag.rune.<eval (<argn>)-100>>

new.cont <src.uid>

try tag.lokasyon.<eval (<argn>)-100> =

try tag.rune.<eval (<argn>)-100> =

try tag.region.<eval (<argn>)-100> =

return 1



on = 201 214

src.tag.uid = <uid>

src.tag.sira = <eval (<argn>)-200>

sdialog d_rnamechange

return 1



on = 500

src.ctag.runebook = <uid>

sdialog d_namechange

return 1





[dialog d_namechange]

0,0



PAGE 0

resizepic 250 90 5120 250 120

resizepic 260 100 3000 230 100

alphablack 260 100 230 100

resizepic 280 130 3000 200 20

dtext 280 110 0456 Kitabin yeni ismi ne olsun?

button 280 150 4006 4007 1 0 1

dtext 315 150 0456 Tamam

dtextentry 285 127 130 20 150 0

dtext 415 150 0456 Sifirla

button 380 150 4006 4007 1 0 2



[dialog d_namechange button]

on = 1

obj = <src.ctag0.runebook>

IF (<isempty <argtxt[0]>>)

src.sys_error Kitap ismini bos birakamazsiniz..

return 1

ELIF (strlen(<argtxt[0]>) > 15)

src.sys_error 15 karakterden uzun olamaz.

return 1

ENDIF

obj.tag.runeisim <argtxt[0]>

src.sys_normal Kitabin ismi <argtxt[0]> olarak degistirildi.

return 1



on = 2

obj.tag.runeisim =

src.sys_normal Kitabin ismi sifirlandi.

return 1



[dialog d_rnamechange]

0,0



PAGE 0

resizepic 250 90 5120 250 120

resizepic 260 100 3000 230 100

resizepic 280 130 3000 200 20

dtext 280 110 0456 Rune'un ismi ne olsun.?

button 280 150 4006 4007 1 0 1

dtext 315 150 0456 Tamam

dtextentry 285 127 130 20 150 0

dtext 415 150 0456 Sifirla

button 380 150 4006 4007 1 0 2



[dialog d_rnamechange button]

on = 1

obJ = <src.tag.uid>

src.tag.uid =

IF (<isempty <argtxt[0]>>)

src.sys_error Rune ismini bos birakamazsiniz.

return 1

ELIF (strlen(<argtxt[0]>) > 20)

src.sys_error 20 karakterden uzun olamaz.

return 1

ENDIF

IF (<isempty <obj.tag.region.<eval (<src.tag.sira>)>>>)

obj.tag.region.<eval (<src.tag0.sira>)> = <obj.tag.rune.<eval (<src.tag.sira>)>>

obj.tag.rune.<eval (<src.tag.sira>)> = <argtxt[0]>

src.sys_normal Rune'un ismi <argtxt[0]> olarak degistirildi.

src.tag.sira =

else

obj.tag.rune.<eval (<src.tag.sira>)> <argtxt[0]>

src.sys_normal Rune'un ismi <argtxt[0]> olarak degistirildi.

src.tag.sira =

ENDIF



on = 2

obj = <src.tag.uid>

src.tag.uid =

IF !(<isempty <obj.tag.region.<eval (<src.tag.sira>)>>>)

obj.tag.rune.<eval (<src.tag.sira>)> = <obj.tag.region.<eval (<src.tag.sira>)>>

obj.tag.region.<eval (<src.tag.sira>)> =

src.sys_normal Rune'un ismi sifirlandi.

src.tag.sira =

ENDIF



[function sltnomove]

IF (<tag0.nomovetill> < <eval <tag0.nomovetill>+<argn>>)

tag.nomovetill <eval <serv.time>+<argn>>

ENDIF



[events e_recall]

on=@logout

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

src.tag.nomovetill =

src.tag.recall =

events -e_recall

effect 3,i_fx_smoke_small,30,36,0

sys_normal The spell fizzles

sound 92



on=@Skillstart

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

src.tag.nomovetill =

src.tag.recall =

skill fail

events -e_recall

effect 3,i_fx_smoke_small,30,36,0

sys_normal The spell fizzles

sound 92



ON=@Gethit

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

src.tag.nomovetill =

src.tag.recall =

events -e_recall

effect 3,i_fx_smoke_small,30,36,0

sys_normal The spell fizzles

sound 92



On=@Death

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

src.tag.nomovetill =

src.tag.recall =

src.events -e_recall

src.effect 3,i_fx_smoke_small,30,36,0

src.sys_normal The spell fizzles

src.sound 92



on=@UserWarMode

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

src.tag.nomovetill =

src.tag.recall =

src.events -e_recall

src.tag.recall =

src.effect 3,i_fx_smoke_small,30,36,0

src.sys_normal The spell fizzles

src.sound 92



[function recall]

IF (<flags>&statf_dead)

return 1

ENDIF

IF (<tag0.recall>)

src.go <args>

src.events -e_recall

src.sound 254

src.tag.recall =

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

return 1

ENDIF



[function runegate]

IF (<flags>&statf_dead)

return 1

ENDIF

IF (<tag0.recall>)

serv.newitem i_gate_rune

new.morep <strarg <args>>,<strarg <streat <args>>>,<strarg <streat <streat <args>>>>,<strarg <streat <streat <streat <args>>>>>

new.attr attr_static|attr_decay

new.p <src.p>

serv.newitem i_gate_rune

new.morep <src.p>

new.attr attr_static|attr_decay

new.p <args>

src.tag.recall =

src.events -e_recall

src.tag.kullanamaz 1

src.timerf 3,src.tag.kullanamaz =

return 1

ENDIF



[ITEMDEF i_gate_rune]

ID = i_moongate_blue

NAME = rune gate

TYPE = t_moongate



ON=@CREATE

COLOR = 0455

TIMER = 30



ON=@CLICK

message @<qval (<serv.map(<morex>,<morey>,<morez>,<morem>).region.guarded>)? 02:025>,1,1 (<serv.map(<morex>,<morey>,<morez>,<morem>).region.name>)

return 1



ON=@STEP

sdialog d_gatetravel2

return 1



on=@dclick

sdialog d_gatetravel2

return 1



on=@timer

remove

return 1



[dialog d_gatetravel2]

0,0



PAGE 0

resizepic 150 70 5120 250 150

resizepic 160 80 3000 230 130

dcroppedtext 165 190 200 20 <qval (<serv.map(<morex>,<morey>,<morez>,<morem>).region.guarded>)? 02:025> (<serv.map(<morex>,<morey>,<morez>,<morem>).region.name>)

dcroppedtext 200 90 200 20 1153 Gitmek istiyor musunuz?

button 200 130 4006 4007 1 0 1

dtext 235 130 1153 Evet

button 290 130 4006 4007 1 0 2

dtext 325 130 1153 Hayir



[dialog d_gatetravel2 button]

on = 2

return 1



on = 1

IF (<distance> > 2) || !(<canseelos>)

src.sys_normal Gate'e uzaktasiniz..

return 1

ENDIF

src.go <morep>

src.update

return 1



[EOF]

Değerlendirmeler

0 0

Total votes: 0

Üye Ol veya Giriş Yap

Bu içeriğe yorum atmak istiyorsanız hemen üye olun veya giriş yapın.

Discord ile Bağlan
Twitch ile Bağlan
Steam ile Bağlan
Google ile Bağlan

Yorumlar (0)

Henüz yorum yapılmamış
Sadece kayıtlı kullanıcılar yeni yorum yapabilir.


Ultima-Strike Discord
Benzer Sayfalar