Runebook

'Uur
2015-01-25 18:35
0 Yorumlar
1552 Görüntüleme
[ITEMDEF I_FS]

ID=I_SPELLBOOK

TYPE=T_SPELLBOOK

VALUE=3000

WEIGHT=0.1

NAME=SPELLBOOK

//RESOURCES=64 I_SCROLL_BLANK

SKILLMAKE=INSCRIPTION 100.0, MAGERY 100.0



ON=@CREATE 

ATTR=ATTR_MAGIC|ATTR_NEWBIE //MAGICAL AND NEWBIE 

MORE=04FFFFFFFF //1-4 CIRCLES 

MORE2=04FFFFFFFF // 5-8 CIRCLES

COLOR 0



ON=@CLICK

MESSAGE @07A1,,1 FULL SPELLBOOK

RETURN 1



[DEFNAME RUNEAYAR]

RUNE_MAXSARJ 50



[ITEMDEF 01F14]

DEFNAME=I_RUNE_MARKER

TYPE=T_RUNE

FLIP=1

VALUE=62

WEIGHT=2.5

RESOURCES=1 I_INGOT_GOLD,1 I_SCROLL_MARK

SKILLMAKE=TINKERING 90.0,MAGERY 90.0,T_TINKER_TOOLS

CATEGORY=PROVISIONS - ALCHEMY & MAGIC

SUBSECTION=MAGICAL ITEMS

DESCRIPTION=RECALL RUNE

DUPELIST=01F15,01F16,01F17

ON=@CREATE

   MORE1=50



[ITEMDEF 01F15]

DUPEITEM=01F14

[ITEMDEF 01F16]

DUPEITEM=01F14

[ITEMDEF 01F17]

DUPEITEM=01F14



[ITEMDEF 022C5]

DEFNAME=I_RUNEBOOK

TYPE=T_RUNE

NAME=Runebook

RESOURCES=8 I_SCROLL_BLANK, 1 I_SCROLL_GATE_TRAVEL, 1 I_SCROLL_RECALL

SKILLMAKE=INSCRIPTION 75.0, MAGERY 70.0



ON=@CREATE

TAG.SARJ=8

COLOR=0972

ATTR=04



ON=@CLIENTTOOLTIP

IF !<ISEMPTY <TAG.NAME>>

SRC.ADDCLILOC 1042971,<TAG0.NAME>

ENDIF



ON=@DROPON_SELF

IF <ARGO.BASEID>==I_SCROLL_RECALL

DIALOGCLOSE D_RUNEBOOK_DIALOG

LOCAL.NEEDED=<EVAL <DEF.RUNE_MAXSARJ>+-<TAG0.SARJ>>

IF <ARGO.AMOUNT>><LOCAL.NEEDED>

ARGO.AMOUNT = <EVAL <ARGO.AMOUNT>+-<LOCAL.NEEDED>>

SRC.SYSMESSAGE @88,,1 <EVAL <LOCAL.NEEDED>> kadar runebook şarj edildi.

TAG.SARJ=<DEF.RUNE_MAXSARJ>

RETURN 1

ELSE

SRC.SYSMESSAGE @88,,1 <EVAL <ARGO.AMOUNT>> kadar runebook şarj edildi.

TAG.SARJ=<EVAL <TAG0.SARJ>+<ARGO.AMOUNT>>

ARGO.REMOVE

RETURN 1

ENDIF

ELIF <ARGO.BASEID>==I_RUNE_MARKER

DIALOGCLOSE D_RUNEBOOK_DIALOG

IF <ARGO.MOREP>

ADD_RUNE <ARGO.UID>

RETURN 1

ELSE

SRC.SYSMESSAGE @34,,1 Bu rune işaretlenemeiş.

RETURN 1

ENDIF

ENDIF



ON=@DCLICK

TAG.PAGE=

SRC.SOUND 85

DIALOGCLOSE D_RUNEBOOK_DIALOG

DIALOG D_RUNEBOOK_DIALOG

RETURN 1



ON=@TARGON_ITEM

IF (<SRC.TARG.BASEID> == I_RUNE_MARKER)

ADD_RUNE <SRC.TARG.UID>

RETURN 1

ELSE

SRC.SYSMESSAGE @38,,1 Sadece işaretlenmiş rune ekleyebilirsiniz.

RETURN 1

ENDIF



[FUNCTION ADD_RUNE]

OBJ=<ARGV[0]>

LOCAL.FREE_SPACE=0

IF !(<OBJ.DMOREP>)

SRC.SYSMESSAGE @38,,1 Bu rune işaretlenmemiş.

RETURN 1

ENDIF

FOR 16 1

IF <ISEMPTY <TAG.LOCAL<EVAL <LOCAL._FOR>>>>

LOCAL.FREE_SPACE=<EVAL <LOCAL._FOR>>

ENDIF

ENDFOR

IF <LOCAL.FREE_SPACE>

TRY TAG.LOCAL<EVAL <LOCAL.FREE_SPACE>>_NAME = <OBJ.NAME>

TRY TAG.LOCAL<EVAL <LOCAL.FREE_SPACE>> = <OBJ.MOREP>

TRY TAG.LOCAL<EVAL <LOCAL.FREE_SPACE>>_COLOR = <OBJ.COLOR>

SRC.SYSMESSAGE @,,1 <OBJ.NAME> runebooka işaretlendi

SOUND 87

OBJ.REMOVE

	DIALOG D_RUNEBOOK_DIALOG

ELSE

SRC.SYSMESSAGE @34,,1 Runebook da yeteri kadar yer yok.

ENDIF



[DIALOG D_RUNEBOOK_DIALOG]

50,50

PAGE 0

GUMPPIC 0 0 2200





GUMPPIC 29 46 57

GUMPPIC 49 46 58

GUMPPIC 65 46 58

GUMPPIC 81 46 58

GUMPPIC 97 46 58

GUMPPIC 113 46 58

GUMPPIC 129 46 59



GUMPPIC 189 46 57

GUMPPIC 209 46 58

GUMPPIC 225 46 58

GUMPPIC 241 46 58

GUMPPIC 257 46 58

GUMPPIC 273 46 58

GUMPPIC 289 46 59





DCROPPEDTEXT 215 10 115 20 0481 <NAME>

BUTTON 200 13 2103 2104 1 0 1003

DTEXT 215 25 0481 Şarj: <DTAG0.SARJ>



PAGE 1

FOR A 1 8

BUTTON 30 <EVAL (<DLOCAL.A>*15)+50> 2103 2104 1 0 <DLOCAL.A>

IF (<TAG0.LOCAL<DLOCAL.A>>)

DTEXT 45 <EVAL (<DLOCAL.A>*15)+47> <TAG0.LOCAL<DLOCAL.A>_COLOR> <TAG.LOCAL<DLOCAL.A>_NAME>

ELSE

DTEXT 45 <EVAL (<DLOCAL.A>*15)+47> 0754 Boş

ENDIF

ENDFOR



FOR B 1 8

BUTTON 190 <EVAL (<DLOCAL.B>*15)+50> 2103 2104 1 0 <EVAL <DLOCAL.B>+8>

IF (<TAG0.LOCAL<EVAL <DLOCAL.B>+8>>)

DTEXT 205 <EVAL (<DLOCAL.B>*15)+47> <TAG0.LOCAL<EVAL <DLOCAL.B>+8>_COLOR> <TAG.LOCAL<EVAL <DLOCAL.B>+8>_NAME>

ELSE

DTEXT 205 <EVAL (<DLOCAL.B>*15)+47> 0754 Boş

ENDIF

ENDFOR



PAGE 2





button 296 5 2236 2236 1 0 501





button 23 5 2235 2235 1 0 500



if (<tag0.local<src.dctag0.rune>>)

DTEXt 215 65  <TAG.LOCAL<SRC.DCTAG0.RUNE>_COLOR> <TAG.LOCAL<SRC.DCTAG0.RUNE>_NAME>

BUTTON 200 68 2103 2104 1 0 1002



BUTTON 30 63 2103 2104 1 0 999

DTEXT 45 60 0481 Recall



BUTTON 30 78 2103 2104 1 0 1000

DTEXT 45 75 0481 Gate Travel



BUTTON 30 93 2103 2104 1 0 1001

DTEXT 45 90 0481 Sacred Journey



BUTTON 35 163 2437 2438 1 0 <EVAL <SRC.DCTAG0.RUNE>+100>

DTEXT 50 160 0455 Rune Çıkar



DTEXT 200 83 0481 Bilgi: //<F_KOORDI <f_moonsep 1,<TAG.LOCAL<SRC.DCTAG0.RUNE>>>,<f_moonsep 2,<TAG.LOCAL<SRC.DCTAG0.RUNE>>>>

DTEXT 200 163 0481 <SEXTANTP <TAG.LOCAL<SRC.DCTAG0.RUNE>>>

else



DTEXT 205 83 0845 BOŞ

endif



[DIALOG D_RUNEBOOK_DIALOG BUTTON]

ON 1 16

IF (<TAG0.LOCAL<DARGN>>)

SRC.CTAG.RUNE <DARGN>

	DIALOG D_RUNEBOOK_DIALOG,2

ELSE

TARGET @,,1 EKLEYECEĞINIZ RUNEYI SEÇINIZ.

ENDIF



ON=101 119

LOCAL.RUNE <EVAL <DARGN>-100>

IF (<TAG0.LOCAL<DLOCAL.RUNE>>)

SRC.NEWITEM I_RUNE_MARKER

SRC.ACT.MOREP <TAG.LOCAL<DLOCAL.RUNE>>

SRC.ACT.NAME <TAG.LOCAL<DLOCAL.RUNE>_NAME>

SRC.ACT.COLOR <TAG.LOCAL<DLOCAL.RUNE>_COLOR>

SRC.ACT.BOUNCE

TAG0.LOCAL<DLOCAL.RUNE>

TAG0.LOCAL<DLOCAL.RUNE>_NAME

ELSE

SRC.SYSMESSAGE @,,1 Bu slot boş

ENDIF



on 501

local.pager <src.dctag0.rune>

IF (<tag0.local<EVAL <DLOCAL.PAGER>+1>>)

if (<dlocal.pager> == 18)

	dialog d_runebook_dialog

return 1

ELif (<dlocal.pager> > 0)

src.ctag.rune +=1

	DIALOG D_RUNEBOOK_DIALOG,2

return 1

endif

ELSE

	dialog d_runebook_dialog

ENDIF



ON 500

local.pager <src.dctag0.rune>

if (<dlocal.pager> == 1)

	DIALOGCLOSE D_RUNEBOOK_DIALOG

	dialog d_runebook_dialog

return 1

endif

if (<dlocal.pager> > 1)

src.ctag.rune -=1

	DIALOG D_RUNEBOOK_DIALOG,2

return 1

endif







ON 999

IF (<SRC.FLAGS> & STATF_DEAD)

SRC.SYSMESSAGE @,,1 Bu durumdayken kullanamazsınız.

RETURN 1

ENDIF

IF (<TAG0.SARJ> >= 1) && !(<SRC.F_SKILL_R 32>))

SRC.CTAG.RUNEBOOK=<UID>

SRC.RUNEBOOK_RECALL <TAG.LOCAL<SRC.DCTAG0.RUNE>>

RETURN 1

ENDIF

IF (<SRC.F_SKILL_S 32>) || (<SRC.ISGM>)

	IF (<SRC.MANA> >= <SERV.SPELL.32.MANAUSE>) || (<SRC.ISGM>)

		IF (<SRC.F_SKILL_R 32>) || (<SRC.ISGM>)

		SRC.CTAG.RUNEBOOK=<UID>

		SRC.RUNEBOOK_RECALL <TAG.LOCAL<SRC.DCTAG0.RUNE>>

		ELSE

		SRC.SYSMESSAGE @,,1 Yeterli reagent yok.

		ENDIF

	ELSE

	SRC.SYSMESSAGE @,,1 Yeterli mananız yok.

	ENDIF

ELSE

SRC.SYSMESSAGE @,,1 Yeterli skilliniz yok.

ENDIF



ON 1000

IF (<SRC.FLAGS> & STATF_DEAD)

SRC.SYSMESSAGE @,,1 Bu durumdayken kullanamazsınız.

RETURN 1

ENDIF

IF (<SRC.F_SKILL_S 52>) || (<SRC.ISGM>)

	IF (<SRC.MANA> >= <SERV.SPELL.52.MANAUSE>) || (<SRC.ISGM>)

		IF (<SRC.F_SKILL_R 52>) || (<SRC.ISGM>)

		SRC.RUNEBOOK_GATETRAVEL <TAG.LOCAL<SRC.DCTAG0.RUNE>>

		ELSE

		SRC.SYSMESSAGE @,,1 Yeterli reagent yok.

		ENDIF

	ELSE

	SRC.SYSMESSAGE @,,1 Yeterli mananız yok.

	ENDIF

ELSE

SRC.SYSMESSAGE @,,1 Yeterli skilliniz yok.

ENDIF

ON 1001

IF (<SRC.FLAGS> & STATF_DEAD)

SRC.SYSMESSAGE @,,1 Bu durumdayken kullanamazsınız.

RETURN 1

ENDIF

IF (<SRC.F_SKILL_S 210>) || (<SRC.ISGM>)

	IF (<SRC.TITHING> >= <SERV.SPELL.210.MANAUSE>) || (<SRC.ISGM>)

	SRC.RUNEBOOK_SACRED <TAG.LOCAL<SRC.DCTAG0.RUNE>>

	ELSE

	SRC.SYSMESSAGE @,,1 Yeterli tithing yok.

	ENDIF

ELSE

SRC.SYSMESSAGE @,,1 Yeterli skilliniz yok.

ENDIF



ON 1002

SRC.CTAG.isim 2

src.CTAG.isim_2 <uid>

PROMPTCONSOLE F_ISIM 

src.sysmessage @,,1 Bölgenin ismini belirleyin





ON 1003

SRC.CTAG.isim 1

src.CTAG.isim_2 <uid>

PROMPTCONSOLE F_ISIM

src.sysmessage @,,1 Kitabın ismini belirleyin.





[FUNCTION F_SKILL_R]

IF (<RESTEST <SERV.SPELL.<ARGV0>.RESOURCES>>)

RETURN 1

ELSE

RETURN 0

ENDIF



[FUNCTION F_SKILL_S]

IF <<SERV.SKILL.<STREAT <SERV.SPELL.<ARGV0>.SKILLREQ>>.KEY>> >= <STRARG <SERV.SPELL.<ARGV[0]>.SKILLREQ>>

RETURN 1

ELSE

RETURN 0

ENDIF





[ITEMDEF I_RECALLGATE_MEMORY]

ID=I_MEMORY

TYPE=T_EQ_SCRIPT

NAME=RECALL/GATE MEMORY



ON=@CREATE

ATTR=020

MORE=100



ON=@EQUIP

TYPE=T_RUNE



ON=@SPELLEFFECT

IF <MORE2>

REF1=<MORE2>

IF (<REF1.TAG0.SARJ> >= 1) && !(<SRC.F_SKILL_R 32>)

REF1.TAG.SARJ=<EVAL <REF1.TAG0.SARJ>+-1>

ENDIF

ELIF <COLOR>

IF <SERV.REAGENTSREQUIRED>

IF !<SERV.REAGENTLOSSFAIL>

SRC.CONSUME <SERV.SPELL.<COLOR>.RESOURCES>

ENDIF

ENDIF

ENDIF

REMOVE

RETURN 1



ON=@TIMER

REMOVE

RETURN 1



[ITEMDEF I_RECALLGATE_MEMORY_2]

ID=I_MEMORY

TYPE=T_EQ_SCRIPT

NAME=RECALL/GATE MEMORY



ON=@CREATE

ATTR=020

MORE=100



ON=@EQUIP

TYPE=T_RUNE





ON=@SPELLEFFECT

IF <MORE2>

REF1=<MORE2>

IF (<REF1.TAG0.SARJ> >= 1) && (<SRC.TITHING> < 15)

REF1.TAG.SARJ=<EVAL <REF1.TAG0.SARJ>+-1>

ENDIF

ELIF <COLOR> == 210

SRC.GO <MOREP>

ENDIF

ENDIF

ENDIF

REMOVE

RETURN 1



ON=@TIMER

REMOVE

RETURN 1





[FUNCTION RUNEBOOK_RECALL]

SERV.NEWITEM I_RECALLGATE_MEMORY

EVENTS +E_RUNEBOOK_CHARGE_CAST

REF1=<NEW.UID>

REF1.MOREP <ARGS>

REF1.TIMER=<EVAL (<SERV.SPELL.32.CAST_TIME>/10)+15>

REF1.COLOR 32

REF1.MORE2 <CTAG0.RUNEBOOK>

EQUIP <REF1.UID>

ACT = <REF1.UID>

ACTPRV = <REF1.UID>

ACTARG1 = 32

ACTION = 25

SRC.CONSUME <SERV.SPELL.32.RESOURCES>



[FUNCTION RUNEBOOK_SACRED]

SERV.NEWITEM I_RECALLGATE_MEMORY_2

EVENTS +E_RUNEBOOK_CHARGE_CAST

REF1=<NEW.UID>

REF1.MOREP <ARGS>

REF1.TIMER=<EVAL (<SERV.SPELL.210.CAST_TIME>/10)+15>

REF1.COLOR 210

REF1.MORE2 <CTAG0.RUNEBOOK>

EQUIP <REF1.UID>

ACT = <REF1.UID>

ACTPRV = <REF1.UID>

ACTARG1 = 210

ACTION = 51

SRC.TITHING -= <SERV.SPELL.210.MANAUSE>



[FUNCTION RUNEBOOK_GATETRAVEL]

CONSUME I_RECALLGATE_MEMORY

SERV.NEWITEM=I_RECALLGATE_MEMORY

REF1=<NEW.UID>

REF1.TIMER=<EVAL (<SERV.SPELL.52.CAST_TIME>/10)+15>

REF1.MOREP=<ARGS>

EQUIP <REF1.UID>

ACTPRV = <UID>

REF1.COLOR=52

CONSUME I_RECALLGATE_SPELLBOOK

SERV.NEWITEM=I_RECALLGATE_SPELLBOOK

REF2=<NEW.UID>

REF2.TIMER=<EVAL (<SERV.SPELL.52.CAST_TIME>/10)+15>

EQUIP <REF2.UID>

ACTPRV = <REF2.UID>

ACT = <REF1.UID>

ACTARG1 = 52

ACTION = 25

SRC.CONSUME <SERV.SPELL.52.RESOURCES>



[EVENTS E_RUNEBOOK_CHARGE_CAST]

ON=@SPELLSELECT

RETURN 6



ON=@SPELLCAST

ARGN2=1

EVENTS -E_RUNEBOOK_CHARGE_CAST



[ITEMDEF I_RECALLGATE_SPELLBOOK]

ID=I_MEMORY

TYPE=T_EQ_SCRIPT

NAME=RECALL/GATE SPELLBOOK



ON=@CREATE

ATTR=024



ON=@EQUIP

TYPE=T_SPELLBOOK



ON=@TIMER

REMOVE

RETURN 1



[function f_isim]

ref1 <src.ctag0.isim_2>

if (<isempty <argv0>>)

src.sysmessage @,,1 Boş bırakamazsınız.

try uid.<ref1>.dialog d_runebook_dialog

return 1

ELIF (<eval STRLEN(<argv0>)> >= 15)

src.sysmessage @,,1 İsim çok uzun

try uid.<ref1>.dialog d_runebook_dialog

elif (<ref1.topobj> != <src>)

src.sysmessage @,,1 Çantanızda olması gerek

return 1

else

if (<src.dctag0.isim> == 1)

ref1.name <argv0>

try uid.<ref1>.dialog d_runebook_dialog

elif <src.dctag0.isim> == 2)

ref1.tag.local<src.dctag0.rune>_name <argv0>

try uid.<ref1>.dialog d_runebook_dialog,2

endif

endif



[EOF]



Chivalry - Sacred Journey eklidir.



Kullanımı basit runebook.
Değerlendirmeler

Total votes: 0
Runebook

Değerlendirmeler

Üye Ol veya Giriş Yap

Yorumlar (0)

Ultima Online Karakter Yapılandırma Aracı Bölümü Açıldı!

Resmi UO, Oyuncuları İkiye Böldü: Web Client Yeterli mi?

Ultima Online, ClassicUO ile Resmi İşbirliğine Gidiyor

Centred#

CentrED+ 7.9

Distance(uzaklık) Sorgusu Hakkında

UoFiddler

UoFiddler ile Map Kopyalama
