Üye ol    Giriş
  1. UO Scriptleri
  2. Sphere Scripts
  3. Items
  4. 24 Sayfalık Runebook
FreeMan

24 Sayfalık Runebook

  • FreeMan
  • 2016-09-14 00:37
  • 0
  • 386 
////////////// 

//By Freeman//

//03.05.2015//

//////////////

[ITEMDEF i_rbook]

DEFNAME=i_spellbook_runebook

ID=I_SPELLBOOK

NAME=Runebook

TYPE=t_NORMAL

RESOURCES=1 i_spellbook,24 i_scroll_recall,24 i_scroll_gate_travel,48 i_scroll_blank

SKILLMAKE=Anatomy 99.0,Evaluatingintel 99.0,Inscription 99.0,Magery 99.0

VALUE=6000

WEIGHT=1.5

ON=@CREATE

COLOR=1195

ATTR=Attr_Newbie

TAG.CHARGES.MAX=100

TAG.CHARGES=5

ON=@CLICK

message @188 Nevbie

message @1153 <name>

message @1283 [Page 24]

return 1

ON=@DCLICK

IF ( <CONT> != <SRC.FINDLAYER.21> )

src.SYSMESSAGE @,3,1 Runebook çantanızdayken kullanabilirsiniz!

RETURN 1

ENDIF

IF (STRMATCH("*jail*","<region.name>"))

SRC.SYSMESSAGE @,3,1 Runebook'u hapiste kullanamazsınız!

RETURN 1

ENDIF

IF <src.tag0.controlling>>0)

src.sysmessage @,3,1 Üst üste tıklayamazsınız, 10 saniye bekleyin!

return 1

else

src.tag.controlling 1

src.timerf 10 , src.tag.controlling//Üstüste tıklama olayının önüne geçmek için saniye bazında timerf ayarlı kendinize göre ayarlayabilirsiniz!

endif

IF <SRC.TAG0.Recalling>

RETURN 1

ENDIF

TAG.PAGE=

if (<region.safe == 1>)

src.sysmessage Safe alanda Runebook kullanamazsınız.

return 1

endif

SRC.DIALOGCLOSE D_RBOOK

SDIALOG D_RBOOK

src.sound 85

RETURN 1

ON=@DROPON_SELF

IF <ARGO.BASEID>==i_scroll_recall

DIALOGCLOSE D_RBOOK

LOCAL.NEEDED=<EVAL <TAG0.Charges.Max>+-<TAG0.Charges>>

IF <ARGO.AMOUNT>><LOCAL.NEEDED>

ARGO.AMOUNT = <EVAL <ARGO.AMOUNT>+-<LOCAL.NEEDED>>

SRC.SYSMESSAGE @,3,1 Kitaba <EVAL <LOCAL.NEEDED>> adet şarj eklendi.

TAG.Charges=<TAG0.Charges.Max>

RETURN 1

ELSE

SRC.SYSMESSAGE @,3,1 Kitaba <EVAL <ARGO.AMOUNT>> adet şarj eklendi.

TAG.Charges=<EVAL <TAG0.Charges>+<ARGO.AMOUNT>>

ARGO.REMOVE

RETURN 1

ENDIF

ELIF <ARGO.BASEID>==i_rune_marker

DIALOGCLOSE D_RBOOK

IF <ARGO.MOREP>

ADD_RUNE <ARGO.UID>

RETURN 1

ELSE

SRC.SYSMESSAGE @,3,1 Rune mark işlemi başarılı.

RETURN 1

ENDIF

ENDIF

ON=@SPELLEFFECT

MORE1=100

IF ((<ARGN>==32) || (<ARGN>==52))

IF !<TAG0.rbook.Location.<EVAL <TAG0.rbook.Default>>>

SRC.SYSMESSAGE @,3,1 Bu kitap varsayılan bir konuma sahip değil!

RETURN 1

ELSE

MOREP=<TAG0.rbook.Location.<EVAL <TAG0.rbook.Default>>>

ENDIF

ENDIF

IF <ARGN>==45

SRC.SYSMESSAGE @,3,1 Bunu marklayamazsınız!

RETURN 1

ENDIF

[FUNCTION ADD_RUNE]

OBJ=<ARGV[0]>

LOCAL.Free_Space=0

FOR 24 1

IF <ISEMPTY <TAG.rbook.<EVAL <LOCAL._FOR>>>>

LOCAL.Free_Space=<EVAL <LOCAL._FOR>>

ENDIF

ENDFOR

IF <LOCAL.Free_Space>

TRY TAG.rbook.<EVAL <LOCAL.Free_Space>> = <OBJ.NAME>

TRY TAG.rbook.Location.<EVAL <LOCAL.Free_Space>> = <OBJ.MOREP>

SRC.SYSMESSAGE @,3,1 <OBJ.NAME> isimli alan kitaba eklendi.

SOUND 87

OBJ.REMOVE

ELSE

SRC.SYSMESSAGE @,3,1 Kitapta boş alan kalmamış! 

ENDIF

[FUNCTION REMOVE_RUNE]

SERV.NEWITEM=i_rune_marker

NEW.MORE1=100

NEW.NAME=<TAG.rbook.<EVAL <ARGV[0]>>>

NEW.MOREP=<TAG.rbook.Location.<EVAL <ARGV[0]>>>

NEW.BOUNCE

TRY TAG.rbook.<EVAL <ARGV[0]>>=

TRY TAG.rbook.Location.<EVAL <ARGV[0]>>=

IF <ARGV[0]><24

FOR <EVAL <ARGV[0]>+1> 24

IF !<ISEMPTY <TAG.rbook.<EVAL <LOCAL._FOR>>>>

TRY TAG.rbook.<EVAL <LOCAL._FOR>+-1>=<TAG.rbook.<EVAL <LOCAL._FOR>>>

TRY TAG.rbook.Location.<EVAL <LOCAL._FOR>+-1>=<TAG.rbook.Location.<EVAL <LOCAL._FOR>>>

TRY TAG.rbook.<EVAL <LOCAL._FOR>>=

TRY TAG.rbook.Location.<EVAL <LOCAL._FOR>>=

ENDIF

ENDFOR

ENDIF

[DIALOG D_RBOOK]

50, 50

PAGE 0

gumppic 100 10 2202

for 1 12

gumppictiled 130 <eval (<dlocal._for>*14)+35> 130 2 4 <dlocal._for>//GUMP

endfor

for 13 24

gumppictiled 290 <eval (<dlocal._for>*14)-133> 130 2 4 <dlocal._for>//GUMP

endfor

DOSWITCH <EVAL <EVAL <TAG0.PAGE>+1>/2>

button 394 14 2236 2236 1 0 501

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 500

button 394 14 2236 2236 1 0 503

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 501

button 394 14 2236 2236 1 0 505

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 503

button 394 14 2236 2236 1 0 507

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 505

button 394 14 2236 2236 1 0 509

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 507

button 394 14 2236 2236 1 0 511

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 509

button 394 14 2236 2236 1 0 513

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 511

button 394 14 2236 2236 1 0 515

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 513

button 394 14 2236 2236 1 0 517

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 515

button 394 14 2236 2236 1 0 519

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 517

button 394 14 2236 2236 1 0 521

END

BEGIN

src.sound 85

button 123 15 2235 2235 1 0 519

button 394 14 2236 2236 1 0 523

END

button 123 15 2235 2235 1 0 521

ENDDO

src.sound 85

dtext 160 16 0481 Max Şarj: 

dtext 225 16 188 [<EVAL <TAG0.Charges.Max>>]

dtext 294 16 0481 Kalan Şarj: 

dtext 365 16 61 [<EVAL <TAG0.Charges>>]

IF !<TAG0.PAGE>

LOCAL.Y=40

FOR 1 12

IF !<ISEMPTY <TAG.rbook.<EVAL <LOCAL._FOR>>>>

button 130 <LOCAL.Y> 2361 2362 1 0 <LOCAL._FOR>

dcroppedtext 145 <EVAL <LOCAL.Y>+-5> 120 18 175 <TAG.rbook.<EVAL <LOCAL._FOR>>>

ELSE

button 130 <LOCAL.Y> 2361 2362 1 0 1000

dcroppedtext 145 <EVAL <LOCAL.Y>+-5> 120 18 1925

ENDIF

LOCAL.Y += 14

ENDFOR

LOCAL.Y=40

FOR 13 24

IF !<ISEMPTY <TAG.rbook.<EVAL <LOCAL._FOR>>>>

button 290 <LOCAL.Y> 2361 2362 1 0 <LOCAL._FOR>

dcroppedtext 305 <EVAL <LOCAL.Y>+-5> 120 18 175 <TAG.rbook.<EVAL <LOCAL._FOR>>>

ELSE

button 290 <LOCAL.Y> 2361 2362 1 0 1000

dcroppedtext 305 <EVAL <LOCAL.Y>+-5> 120 18 1925

ENDIF

LOCAL.Y += 14

ENDFOR

ELSE

/////////////////Section One///////////////////

IF <ISEMPTY <TAG.rbook.<EVAL <TAG0.PAGE>>>>

button 130 52 2361 2362 1 0 1000

dcroppedtext 143 47 120 18 1925

ELSE

button 130 52 2361 2362 1 0 <TAG0.PAGE>

dcroppedtext 143 47 120 18 175 <TAG.rbook.<EVAL <TAG0.PAGE>>>

button 185 137 2360 2361 1 0 <EVAL <TAG0.PAGE>+100>

dtext 160 118 38 Rune Çıkar

dtext 140 188 1925 Recall

dtext 212 188 1925 Gate

button 135 146 2271 2271 1 0 <EVAL <TAG0.PAGE>+200>

button 205 146 2291 2291 1 0 <EVAL <TAG0.PAGE>+300>

ENDIF

/////////////////Section Two///////////////////

IF <ISEMPTY <TAG.rbook.<EVAL <TAG0.PAGE>+1>>>

button 290 52 2361 2362 1 0 1000

dcroppedtext 303 47 120 18 1925

ELSE

button 290 52 2361 2362 1 0 <EVAL <TAG0.PAGE>+1>

dcroppedtext 303 47 120 18 175 <TAG.rbook.<EVAL <TAG0.PAGE>+1>>

button 345 137 2360 2361 1 0 <EVAL <TAG0.PAGE>+101>

dtext 320 118 38 Rune Çıkar

dtext 300 188 1925 Recall

dtext 372 188 1925 Gate

button 295 146 2271 2271 1 0 <EVAL <TAG0.PAGE>+201>

button 365 146 2291 2291 1 0 <EVAL <TAG0.PAGE>+301>

ENDIF

[DIALOG D_RBOOK BUTTON] 

ON=601 623

TAG.rbook.Default=<EVAL <ARGN>+-600>

SRC.SysMESSAGE @,3,1 Yeni konum ayarla!

TAG.PAGE=

DIALOGCLOSE D_RBOOK

DIALOG D_RBOOK

ON=500

TAG.PAGE=

DIALOGCLOSE D_RBOOK

DIALOG D_RBOOK

ON=501 523

TAG.PAGE=<EVAL <ARGN>+-500>

DIALOGCLOSE D_RBOOK

DIALOG D_RBOOK

ON=0

src.sound 85

ON=1 24

FORCHARS 100

    FORCHARMEMORYTYPE memory_war_targ

        IF <LINK.UID>==<SRC.UID>

            IF <CONT.CANSEELOS <LINK.UID>>

                SRC.sysmessage @,3,1 Savaş modunda bu eylemi gerçekleştiremezsiniz!

                Return 1

            ENDIF

        ENDIF

    ENDFOR

ENDFOR

IF <SRC.FLAGS>==<SRC.FLAGS>|02

SRC.SYSMESSAGE @,3,1 Ölüler bu işlemi yapamazlar.

ENDIF

IF <SRC.FLAGS>==<SRC.FLAGS>|04

SRC.SYSMESSAGE @,3,1 Kilitli durumdayken bu eylemi yapamazsınız!

ENDIF

IF <TAG0.Charges>>0

IF !<SRC.TAG0.Recalling>

SRC.TAG.Recalling=<UID>

SRC.rbook_Recall <TAG0.rbook.Location.<ARGN>>

ELSE

SRC.SYSMESSAGE @,3,1 Yeteri kadar Şarjınız bulunmuyor!

ENDIF

ELSE

SRC.SYSMESSAGE @,3,1 Kitabınızda yeteri kadar Şarj yok!

ENDIF

ON=101 124

REMOVE_RUNE <EVAL <ARGN>+-100>

ON=201 224

FORCHARS 100

    FORCHARMEMORYTYPE memory_war_targ

        IF <LINK.UID>==<SRC.UID>

            IF <CONT.CANSEELOS <LINK.UID>>

                SRC.sysmessage @,3,1 Savaş modunda bu eylemi gerçekleştiremezsiniz!

                Return 1

            ENDIF

        ENDIF

    ENDFOR

ENDFOR

LOCAL.Rune=<EVAL <ARGN>+-200>

IF <SRC.FLAGS>==<SRC.FLAGS>|02

SRC.SYSMESSAGE @,3,1 Ölüler bu işlemi yapamazlar.

ENDIF

IF <SRC.FLAGS>==<SRC.FLAGS>|04

SRC.SYSMESSAGE @,3,1 Kilitli durumdayken bu eylemi yapamazsınız!

ENDIF

IF <SRC.RESTEST <SERV.SPELL.32.RESOURCES>>

IF !<SRC.TAG0.Recalling>

SRC.TAG.Recalling=<UID>

SRC.rbook_Recall_Reags <TAG0.rbook.Location.<EVAL <LOCAL.Rune>>>

ELSE

SRC.SYSMESSAGE @,3,1 Çantanızda yeteri kadar malzemeniz bulunmuyor!

ENDIF

ELSE

SRC.SYSMESSAGE @,3,1 Gerekli olan malzemeleriniz yetersiz.

ENDIF

ON=301 324

FORCHARS 100

    FORCHARMEMORYTYPE memory_war_targ

        IF <LINK.UID>==<SRC.UID>

            IF <CONT.CANSEELOS <LINK.UID>>

                SRC.sysmessage @,3,1 Savaş modunda bu eylemi gerçekleştiremezsiniz!

                Return 1

            ENDIF

        ENDIF

    ENDFOR

ENDFOR

LOCAL.Rune=<EVAL <ARGN>+-300>

IF <SRC.FLAGS>==<SRC.FLAGS>|02

SRC.SYSMESSAGE @,3,1 Ölüler Recall olamazlar.

ENDIF

IF <SRC.FLAGS>==<SRC.FLAGS>|04

SRC.SYSMESSAGE @,3,1 Kilitli durumdayken bu eylemi yapamazsınız!

ENDIF

IF <SRC.RESTEST <SERV.SPELL.52.RESOURCES>>

IF !<SRC.TAG0.Recalling>

SRC.TAG.Recalling=<UID>

SRC.rbook_Gate_Reags <TAG0.rbook.Location.<EVAL <LOCAL.Rune>>>

ELSE

SRC.SYSMESSAGE @,3,1 Çantanızda yeteri kadar malzemeniz bulunmuyor!

ENDIF

ELSE

SRC.SYSMESSAGE @,3,1 Gerekli olan malzemeleriniz yetersiz.

ENDIF

[function rbook_Recall]

if (<magery><400)

src.SYSMESSAGE @,3,1 Magery skiliniz yetersiz! Gerekli magery 40 olmalıdır.

SRC.TAG.RECALLING 0

return 1

endif

if (<mana><12)

src.SYSMESSAGE @,3,1 Mananız yetersiz, minimum Mana 12 olmalı!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

return 1

endif

IF <SRC.REGION.FLAGS>&0E

SRC.SYSMESSAGE @,3,1 Bu alanda Recall olamazsınız!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

RETURN 1

ENDIF

if (<src.hits><1)

SRC.SYSMESSAGE @,3,1 Ölüler Recall olamazlar.

SRC.TAG.RECALLING 0

return 1

endif

//if (<findtype.t_armor.cont.uid> == <uid>)

//f_fizzle

        //SRC.SYSMESSAGE @,3,1 Üzerinizde armor varken Runebook kullanamazsınız.//dilerseniz devreye koyabilirsiniz

//SRC.TAG.RECALLING 0

//return 1

//endif

if ((<flags>&statf_freeze) || (<flags>&statf_stone)

f_fizzle

SRC.SYSMESSAGE @,3,1 Şuan bu işlemi yapamazsınız!

SRC.TAG.RECALLING 0

return 1

endif

src.action -1

EVENTS +e_rbook_recall

say Kal Ort Por

flags |= statf_freeze

anim 17

local.casttime=<eval <serv.spell.32.cast_time>-<tag0.fastercast>>

if (<local.casttime><20)

TIMERF 2,rbook_Recall_Finish <ARGS>

else

TIMERF <eval <local.casttime>/10>,rbook_Recall_Finish <ARGS>

endif

[function rbook_Recall_Reags]

if (<magery><400)

src.SYSMESSAGE @,3,1 Magery skiliniz yetersiz! Gerekli magery 40 olmalıdır.

SRC.TAG.RECALLING 0

return 1

endif

if (<mana><12)

src.sysMESSAGE @,3,1 Mananız yetersiz, minimum Mana 12 olmalı!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

return 1

endif

IF <SRC.REGION.FLAGS>&0E

SRC.SYSMESSAGE @,3,1 Safe alanda bu işlemi yapamazsınız!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

RETURN 1

ENDIF

if (<src.hits><1)

SRC.SYSMESSAGE @,3,1 Ölüler Recall olamazlar.

SRC.TAG.RECALLING 0

return 1

endif

//if (<findtype.t_armor.cont.uid> == <uid>)

//f_fizzle

        //SRC.SYSMESSAGE @,3,1 Üzerinizde armor varken Runebook kullanamazsınız.//dilerseniz devreye koyabilirsiniz.

//SRC.TAG.RECALLING 0

//return 1

//endif

if ((<flags>&statf_freeze) || (<flags>&statf_stone)

f_fizzle

SRC.SYSMESSAGE @,3,1 Şuan bu işlemi yapamazsınız! 

SRC.TAG.RECALLING 0

return 1

endif

src.action -1

EVENTS +e_rbook_recall

say Kal Ort Por

flags |= statf_freeze

anim 17

local.casttime=<eval <serv.spell.32.cast_time>-<tag0.fastercast>>

if (<local.casttime><20)

TIMERF 2,rbook_Recall_Finish_Reags <ARGS>

else

TIMERF <eval <local.casttime>/10>,rbook_Recall_Finish <ARGS>

endif

[function rbook_Gate_Reags]

if (<magery><700)

src.SYSMESSAGE @,3,1 Magery skiliniz yetersiz! Gerekli Magery 70 olmalıdır.

SRC.TAG.RECALLING 0

return 1

endif

if (<mana><40)

src.SYSMESSAGE @,3,1 Mananız yetersiz! Gerekli mana 40 olmalıdır.

SRC.TAG.RECALLING 0

SRC.SOUND 0108

return 1

endif

IF <SRC.REGION.FLAGS>&0E

SRC.SYSMESSAGE @,3,1 Bu alanda bu eylemi yapamazsın.

SRC.TAG.RECALLING 0

SRC.SOUND 0108

RETURN 1

ENDIF

if (<src.hits><1)

SRC.SYSMESSAGE @,3,1 Ölüler bu eylemi yapamazlar.

SRC.TAG.RECALLING 0

return 1

endif

//if (<findtype.t_armor.cont.uid> == <uid>)

//f_fizzle

       // SRC.SYSMESSAGE @,3,1 Üzerinizde armor varken Runebook kullanamazsınız.//dilerseniz devreye koyabilirsiniz.

//SRC.TAG.RECALLING 0

//return 1

//endif

if ((<flags>&statf_freeze) || (<flags>&statf_stone)

f_fizzle

        SRC.SYSMESSAGE @,3,1 Kilitli durumdayken bu eylemi yapamazsınız.

SRC.TAG.RECALLING 0

return 1

endif

src.action -1

EVENTS +e_rbook_recall

say Vas Rel Por

flags |= statf_freeze

ANIM 17

local.casttime=<eval <serv.spell.52.cast_time>-<tag0.fastercast>>

if (<local.casttime><30)

TIMERF 3,rbook_moongate <ARGS>

else

TIMERF <eval <local.casttime>/10>,rbook_moongate <ARGS>

endif

[EVENTS e_rbook_recall]

ON=@GETHIT

flags &= ~statf_freeze

EVENTS -e_rbook_recall

TAG.Recalling=

Sound 92

EFFECT 3,i_fx_smoke_small,30,36,0

MESSAGE @,3,1 The spell fizzles.

ON=@USERWARMODE

flags &= ~statf_freeze

EVENTS -e_rbook_recall

TAG.Recalling=

Sound 92

EFFECT 3,i_fx_smoke_small,30,36,0

MESSAGE @,3,1 The spell fizzles.

ON=@SPELLCAST

flags &= ~statf_freeze

EVENTS -e_rbook_recall

TAG.Recalling=

Sound 92

EFFECT 3,i_fx_smoke_small,30,36,0

MESSAGE @,3,1 The spell fizzles.

[function rbook_Recall_Finish]

if (<mana>>11)

mana -= 12

flags &= ~statf_freeze

EVENTS -e_rbook_recall

IF <SRC.TAG0.Recalling>

OBJ=<SRC.TAG0.Recalling>

SRC.TAG.Recalling=

OBJ.TAG.CHARGES = <EVAL <OBJ.TAG0.Charges>+-1>

SRC.SOUND snd_spell_recall

SRC.GO <ARGS>

ENDIF

else

src.SYSMESSAGE @,3,1 Mananız yetersiz, minimum Mana 12 olmalı!

SRC.TAG.RECALLING 0

flags &= ~statf_freeze

SRC.SOUND 0108

endif

[function rbook_Recall_Finish_Reags]

if (<mana>>11)

mana -= 12

flags &= ~statf_freeze

EVENTS -e_rbook_recall

IF <SRC.TAG0.Recalling>

SRC.TAG.Recalling=

OBJ.TAG.Charges = <EVAL <OBJ.TAG0.Charges>+-1>

SRC.CONSUME <SERV.SPELL.32.RESOURCES>

SRC.SOUND snd_spell_recall

SRC.GO <ARGS>

ENDIF

else

src.SYSMESSAGE @,3,1 Mananız yetersiz, minimum Mana 12 olmalı!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

flags &= ~statf_freeze

endif

[function rbook_moongate]

if (<mana>>39)

mana -= 40

flags &= ~statf_freeze

EVENTS -e_rbook_recall

IF <SRC.TAG0.Recalling>

SRC.TAG.Recalling=

SRC.CONSUME <SERV.SPELL.52.RESOURCES>

SRC.SOUND snd_spell_gate_travel

SERV.NEWITEM=i_moongate_new

NEW.NAME moongate

NEW.COLOR=021

NEW.EVENTS +e_rbook_moongate

NEW.ATTR=04032

NEW.TIMER=30

NEW.MOREP=<ARGS>

NEW.P=<SRC.P>

SERV.NEWITEM=i_moongate_new

NEW.NAME moongate

NEW.COLOR=021

NEW.EVENTS +e_rbook_moongate

NEW.ATTR=04032

NEW.TIMER=30

NEW.MOREP=<SRC.P>

NEW.P=<ARGS>

ENDIF

else

src.SYSMESSAGE @,3,1 Mananız yetersiz, minimum Mana 40 olmalı!

SRC.TAG.RECALLING 0

SRC.SOUND 0108

flags &= ~statf_freeze

endif

[ITEMDEF e_rbook_moongate]

ON=@DCLICK

sdialog d_rbook_moongate

return 1

ON=@STEP

sdialog d_rbook_moongate

return 1

ON=@TIMER

REMOVE

RETURN 1

new.morep <strarg <args>>,<strarg <streat <args>>>,<strarg <streat <streat <args>>>>,<strarg <streat <streat <streat <args>>>>>

ON=@CLICK

message @1283 (<serv.map(<morex>, <morey>, <morez>, <morem>).region.name>)

message @63 (<p>)

return 1

[dialog d_rbook_moongate]

200,65

nomove

PAGE 0

gumppictiled 150 90 270 110 3004

gumppictiled 160 100 250 90 87

dtext 165 100 1283 <serv.map(<morex>, <morey>, <morez>, <morem>).region.name>

dtext 170 127 0fef Bölgesine gitmek istediğine eminmisiniz?

button 162 152 4006 4007 1 0 1

dtext 162 172 0fef Evet

button 378 152 4018 4019 1 0 2

dtext 378 172 1193 Hayır

[dialog d_rbook_moongate button]

on = 2

return 1

on = 1

IF (<distance> > 2) || !(<canseelos>)

src.SYSMESSAGE Gate'e çok uzaktasınız..

return 1

ENDIF

src.go <morep>

src.update

return 1

[EOF]

Değerlendirmeler

0 0

Total votes: 0

Üye Ol veya Giriş Yap

Bu içeriğe yorum atmak istiyorsanız hemen üye olun veya giriş yapın.

Discord ile Bağlan
Twitch ile Bağlan
Steam ile Bağlan
Google ile Bağlan

Yorumlar (0)

Henüz yorum yapılmamış
Sadece kayıtlı kullanıcılar yeni yorum yapabilir.


Ultima-Strike Discord
Benzer Sayfalar